codevis/cmake/AddTargetLibrary.cmake

0001 # AddTargetLibrary(
0002 #    LIBRARY_NAME lvtxxx
0003 #    SOURCES source1.cpp source2.cpp source3.cpp
0004 #    HEADERS source1.h source2.h source3.h
0005 #    QT_HEADERS [list of headers that should be preprocessed with moc]
0006 #    LIBRARIES -lmath -lthread
0007 #    DESIGNER_FORMS widget.ui
0008 #)
0009
0010 macro(AddTargetLibrary)
0011     set(booleanValueArgs "")
0012     set(oneValueArgs LIBRARY_NAME)
0013     set(multiValueArgs SOURCES HEADERS QT_HEADERS LIBRARIES DESIGNER_FORMS)
0014     cmake_parse_arguments(DTARGS "${booleanValueArgs}" "${oneValueArgs}" "${multiValueArgs}" ${ARGN})
0015
0016     include_directories(${PROJECT_SOURCE_DIR})
0017     include_directories(${CMAKE_CURRENT_SOURCE_DIR})
0018     include_directories(${CMAKE_CURRENT_BINARY_DIR})
0019
0020     # Build the Meta Object Compiler targets
0021     cmake_language(CALL
0022         qt${QT_MAJOR_VERSION}_wrap_cpp
0023         DTARGS_SOURCES ${DTARGS_QT_HEADERS} OPTIONS "--no-warnings" "--no-notes"
0024     )
0025
0026     if (BUILD_DESKTOP_APP)
0027         cmake_language(CALL
0028             qt${QT_MAJOR_VERSION}_wrap_ui
0029             DTARGS_SOURCES ${DTARGS_DESIGNER_FORMS}
0030         )
0031     endif()
0032
0033     add_library(${DTARGS_LIBRARY_NAME} SHARED ${DTARGS_SOURCES} ${DTARGS_HEADERS} ${DTARGS_QT_HEADERS})
0034     add_library(Codethink::${DTARGS_LIBRARY_NAME} ALIAS ${DTARGS_LIBRARY_NAME})
0035
0036     target_link_libraries(
0037         ${DTARGS_LIBRARY_NAME}
0038         ${DTARGS_LIBRARIES}
0039     )
0040     generate_export_header(${DTARGS_LIBRARY_NAME}
0041     BASE_NAME ${DTARGS_LIBRARY_NAME}
0042     )
0043
0044     target_include_directories(${DTARGS_LIBRARY_NAME}
0045     PUBLIC
0046         $<BUILD_INTERFACE:${CMAKE_CURRENT_BINARY_DIR}>
0047         $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}>
0048         $<INSTALL_INTERFACE:include/lakos/${DTARGS_LIBRARY_NAME}>
0049     )
0050
0051     if (NOT ${KDE_FRAMEWORKS_IS_OLD})
0052         install(TARGETS
0053             ${DTARGS_LIBRARY_NAME}
0054             DESTINATION ${KDE_INSTALL_TARGETS_DEFAULT_ARGS}
0055         )
0056     endif()
0057 endmacro()