plasma/wacomtablet/CMakeLists.txt

0001 cmake_minimum_required(VERSION 3.16)
0002
0003 set(PROJECT_VERSION "6.0.80")
0004 project(wacomtablet VERSION ${PROJECT_VERSION})
0005
0006 set(PROJECT_DEP_VERSION "6.0.80")
0007 set(QT_MIN_VERSION "6.6.0")
0008 set(KF6_MIN_VERSION "5.240.0")
0009 set(KDE_COMPILERSETTINGS_LEVEL "5.82")
0010
0011 set(CMAKE_CXX_STANDARD 20)
0012 set(CMAKE_CXX_STANDARD_REQUIRED ON)
0013
0014 find_package(ECM ${KF6_MIN_VERSION} REQUIRED NO_MODULE)
0015 set(CMAKE_MODULE_PATH ${ECM_MODULE_PATH} ${CMAKE_SOURCE_DIR}/cmake/modules)
0016
0017 include(KDEInstallDirs)
0018 include(KDECMakeSettings)
0019 include(KDECompilerSettings NO_POLICY_SCOPE)
0020 include(KDEClangFormat)
0021 include(KDEGitCommitHooks)
0022 include(FeatureSummary)
0023 include(ECMOptionalAddSubdirectory)
0024 include(ECMInstallIcons)
0025 include(ECMSetupVersion)
0026 include(ECMQtDeclareLoggingCategory)
0027
0028 ecm_setup_version(${PROJECT_VERSION}
0029     VARIABLE_PREFIX WACOMTABLET
0030     VERSION_HEADER "${CMAKE_CURRENT_BINARY_DIR}/src/wacomtablet-version.h"
0031 )
0032
0033 find_package(Qt6 REQUIRED COMPONENTS Core Gui Widgets DBus Qml)
0034 find_package(KF6 REQUIRED COMPONENTS CoreAddons I18n GlobalAccel Config XmlGui WidgetsAddons WindowSystem Notifications DBusAddons DocTools KCMUtils KIO)
0035 find_package(XCB REQUIRED COMPONENTS XINPUT)
0036 find_package(X11 REQUIRED)
0037
0038 find_package(Plasma ${PROJECT_DEP_VERSION} REQUIRED)
0039 find_package(Plasma5Support REQUIRED)
0040
0041 find_package(PkgConfig REQUIRED)
0042 pkg_check_modules(LIBWACOM libwacom REQUIRED IMPORTED_TARGET)
0043 pkg_check_modules(XORGWACOM xorg-wacom REQUIRED IMPORTED_TARGET)
0044
0045 if(${LIBWACOM_VERSION} VERSION_LESS "0.29")
0046     message(STATUS "Button detection with libwacom requires version at least 0.29. Detected version is: " ${LIBWACOM_VERSION})
0047     add_definitions(-DLIBWACOM_EVDEV_MISSING)
0048 endif()
0049
0050 add_definitions(-DQT_STRICT_ITERATORS)
0051 add_definitions(-DQT_NO_CAST_FROM_ASCII)
0052 add_definitions(-DQT_NO_CAST_TO_ASCII)
0053 add_definitions(-DQT_USE_QSTRINGBUILDER)
0054
0055 add_subdirectory(src)
0056 add_subdirectory(data)
0057 add_subdirectory(images)
0058
0059 ki18n_install(po)
0060 if(KF6DocTools_FOUND)
0061     add_subdirectory(doc)
0062     kdoctools_install(po)
0063 endif()
0064
0065 ### Tests
0066 if(BUILD_TESTING)
0067   find_package(Qt6Test ${QT_MIN_VERSION} CONFIG REQUIRED)
0068   add_subdirectory(autotests)
0069 endif()
0070 ecm_qt_install_logging_categories(
0071         EXPORT WACOMTABLET
0072         FILE wacomtablet.categories
0073         DESTINATION ${KDE_INSTALL_LOGGINGCATEGORIESDIR}
0074         )
0075
0076 file(GLOB_RECURSE ALL_CLANG_FORMAT_SOURCE_FILES *.cpp *.h)
0077 kde_clang_format(${ALL_CLANG_FORMAT_SOURCE_FILES})
0078
0079 kde_configure_git_pre_commit_hook(CHECKS CLANG_FORMAT)
0080
0081 feature_summary(WHAT ALL INCLUDE_QUIET_PACKAGES FATAL_ON_MISSING_REQUIRED_PACKAGES)