systemsettings/app/CMakeLists.txt

0001
0002 add_executable(systemsettings)
0003 ecm_add_qml_module(systemsettings URI org.kde.systemsettings GENERATE_PLUGIN_SOURCE)
0004
0005 target_sources(systemsettings PRIVATE
0006     main.cpp
0007     SettingsBase.cpp
0008     SettingsBase.h
0009     ToolTips/tooltipmanager.cpp
0010     ToolTips/tooltipmanager.h
0011     sidebar/SidebarMode.cpp
0012     sidebar/SidebarMode.h
0013     ${debug_SRCS}
0014 )
0015
0016 ecm_target_qml_sources(systemsettings SOURCES
0017     sidebar/qml/CategoriesPage.qml
0018     sidebar/qml/CategoryItem.qml
0019     sidebar/qml/HamburgerMenuButton.qml
0020     sidebar/qml/IntroPage.qml
0021     sidebar/qml/Main.qml
0022     sidebar/qml/SideBarItem.qml
0023     sidebar/qml/SubCategoryPage.qml
0024     RESOURCES
0025     sidebar/images/plasma-logo.svg
0026 )
0027
0028 qt_target_qml_sources(systemsettings RESOURCES systemsettingsui.rc PREFIX /kxmlgui5/systemsettings)
0029
0030 target_compile_definitions(systemsettings PRIVATE -DPROJECT_VERSION="${PROJECT_VERSION}")
0031 target_include_directories(systemsettings PRIVATE ToolTips sidebar)
0032
0033 target_link_libraries(systemsettings PRIVATE
0034     systemsettings_debug
0035     systemsettingsview
0036     KF6::Crash
0037     KF6::ItemViews
0038     KF6::ItemModels
0039     KF6::KCMUtils
0040     KF6::I18n
0041     KF6::IconThemes
0042     KF6::KIOWidgets
0043     KF6::Service
0044     KF6::WindowSystem
0045     KF6::XmlGui
0046     KF6::DBusAddons
0047     KF6::ConfigGui
0048     KF6::GuiAddons # UrlHanlder handles help:/ urls
0049     Qt::QuickWidgets
0050     Qt::Qml
0051     Qt::Quick
0052 )
0053
0054 install(TARGETS systemsettings ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
0055 install(PROGRAMS kdesystemsettings.desktop systemsettings.desktop DESTINATION ${KDE_INSTALL_APPDIR})
0056 install(DIRECTORY DESTINATION "${KDE_INSTALL_FULL_DATAROOTDIR}/kglobalaccel")
0057 install(
0058     CODE "execute_process(COMMAND \"${CMAKE_COMMAND}\" -E create_symlink \"${KDE_INSTALL_FULL_APPDIR}/systemsettings.desktop\" \"\$ENV{DESTDIR}${KDE_INSTALL_FULL_DATAROOTDIR}/kglobalaccel/systemsettings.desktop\")"
0059 )
0060 install(FILES org.kde.systemsettings.metainfo.xml DESTINATION ${KDE_INSTALL_METAINFODIR})
0061 install(FILES systemsettings.zsh RENAME _systemsettings DESTINATION ${KDE_INSTALL_ZSHAUTOCOMPLETEDIR})
0062
0063 ecm_finalize_qml_module(systemsettings)