plasma-workspace/startkde/CMakeLists.txt

0001 add_subdirectory(plasmaautostart)
0002 add_subdirectory(kcminit)
0003 add_subdirectory(waitforname)
0004
0005 if (CMAKE_SYSTEM_NAME STREQUAL "Linux")
0006     add_subdirectory(systemd)
0007 endif()
0008
0009 add_definitions(-DQT_NO_CAST_FROM_ASCII -DQT_NO_CAST_TO_ASCII)
0010 add_definitions(-DQT_NO_NARROWING_CONVERSIONS_IN_CONNECT)
0011
0012 qt_add_dbus_interface(
0013     startplasma_SRCS
0014     ${CMAKE_SOURCE_DIR}/ksplash/ksplashqml/org.kde.KSplash.xml
0015     ksplashinterface
0016 )
0017 ecm_qt_declare_logging_category(startplasma_SRCS HEADER debug.h IDENTIFIER PLASMA_STARTUP CATEGORY_NAME org.kde.startup)
0018
0019 add_library(startplasma OBJECT startplasma.cpp ${startplasma_SRCS})
0020 target_link_libraries(startplasma PUBLIC
0021     Qt::Core
0022     Qt::DBus
0023     KF5::ConfigCore
0024     KF5::Notifications
0025     KF5::Package
0026     ${PHONON_LIBRARIES}
0027     PW::KWorkspace
0028     lookandfeelmanager
0029 )
0030
0031 add_executable(startplasma-x11 ${START_PLASMA_COMMON_SRCS} startplasma-x11.cpp kcheckrunning/kcheckrunning.cpp)
0032 add_executable(startplasma-wayland ${START_PLASMA_COMMON_SRCS} startplasma-wayland.cpp)
0033
0034 target_link_libraries(startplasma-x11 PRIVATE
0035     startplasma
0036     X11::X11 # for kcheckrunning
0037 )
0038
0039 target_link_libraries(startplasma-wayland PRIVATE
0040     startplasma
0041 )
0042
0043 add_subdirectory(plasma-session)
0044 add_subdirectory(plasma-shutdown)
0045
0046 #FIXME: reconsider, looks fishy
0047 if(NOT CMAKE_INSTALL_PREFIX STREQUAL "/usr")
0048     set_property(SOURCE startplasma.cpp APPEND PROPERTY COMPILE_DEFINITIONS
0049         XCURSOR_PATH="${KDE_INSTALL_FULL_DATAROOTDIR}/icons:$XCURSOR_PATH:~/.icons:/usr/share/icons:/usr/share/pixmaps:/usr/X11R6/lib/X11/icons")
0050 endif()
0051
0052 configure_file(config-startplasma.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config-startplasma.h)
0053
0054 install(TARGETS startplasma-x11 ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
0055 install(TARGETS startplasma-wayland ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
0056 install(PROGRAMS plasma-sourceenv.sh DESTINATION ${KDE_INSTALL_LIBEXECDIR})
0057 install(PROGRAMS plasma-dbus-run-session-if-needed DESTINATION ${KDE_INSTALL_LIBEXECDIR})