plasma-workspace/libkworkspace/CMakeLists.txt

0001
0002 configure_file(${CMAKE_CURRENT_SOURCE_DIR}/config-outputorder.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config-outputorder.h)
0003
0004 set(kworkspace_LIB_SRCS kdisplaymanager.cpp
0005     sessionmanagement.cpp
0006     sessionmanagementbackend.cpp
0007     autostartscriptdesktopfile.cpp
0008     kdisplaymanager.h
0009     kworkspace.h
0010     sessionmanagement.h
0011     sessionmanagementbackend.h
0012     autostartscriptdesktopfile.h
0013     login1_manager_interface.cpp
0014     login1_manager_interface.h
0015     defaultservice.cpp
0016     defaultservice.h
0017     defaultwallpaper.cpp
0018     defaultwallpaper.h
0019     outputorderwatcher.cpp
0020     outputorderwatcher.h
0021    )
0022
0023 add_definitions(-DTRANSLATION_DOMAIN=\"libkworkspace\")
0024
0025 qt_add_dbus_interface(kworkspace_LIB_SRCS ${KSCREENLOCKER_DBUS_INTERFACES_DIR}/kf6_org.freedesktop.ScreenSaver.xml screenlocker_interface )
0026 qt_add_dbus_interface(kworkspace_LIB_SRCS ${plasma-workspace_SOURCE_DIR}/ksmserver/org.kde.LogoutPrompt.xml logoutprompt_interface)
0027 qt_add_dbus_interface(kworkspace_LIB_SRCS ${plasma-workspace_SOURCE_DIR}/startkde/plasma-session/org.kde.Startup.xml startup_interface)
0028 qt_add_dbus_interface(kworkspace_LIB_SRCS ${plasma-workspace_SOURCE_DIR}/startkde/plasma-shutdown/org.kde.Shutdown.xml shutdown_interface)
0029
0030 set(ksmserver_xml ${plasma-workspace_SOURCE_DIR}/ksmserver/org.kde.KSMServerInterface.xml)
0031 qt_add_dbus_interface( kworkspace_LIB_SRCS ${ksmserver_xml} ksmserver_interface )
0032
0033 add_library(kworkspace ${kworkspace_LIB_SRCS})
0034 add_library(PW::KWorkspace ALIAS kworkspace)
0035 set_target_properties(kworkspace PROPERTIES
0036                              VERSION ${PROJECT_VERSION}
0037                              SOVERSION ${PROJECT_VERSION_MAJOR}
0038                              EXPORT_NAME KWorkspace
0039                              OUTPUT_NAME kworkspace6
0040                       )
0041
0042 generate_export_header(kworkspace)
0043 target_link_libraries(kworkspace
0044     PUBLIC
0045         Qt::Core
0046         KF6::CoreAddons
0047     PRIVATE
0048         Qt::DBus
0049         Qt::WaylandClient
0050         KF6::I18n
0051         KF6::WindowSystem
0052         KF6::ConfigCore
0053         KF6::Service
0054         KF6::Package
0055         Plasma::Plasma
0056 )
0057 target_include_directories(kworkspace PUBLIC "$<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}>"
0058                                       INTERFACE "$<INSTALL_INTERFACE:${KDE_INSTALL_INCLUDEDIR}/kworkspace6>" )
0059
0060 configure_file(config-libkworkspace.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config-libkworkspace.h)
0061
0062 if(HAVE_X11)
0063     target_link_libraries(kworkspace PRIVATE X11::Xau XCB::XCB XCB::RANDR Qt::GuiPrivate)
0064 endif()
0065
0066 write_basic_config_version_file(${CMAKE_CURRENT_BINARY_DIR}/LibKWorkspaceConfigVersion.cmake VERSION
0067                                      "${PROJECT_VERSION}" COMPATIBILITY AnyNewerVersion)
0068
0069
0070 ecm_qt_declare_logging_category(kworkspace
0071     HEADER libkworkspace_debug.h
0072     IDENTIFIER LIBKWORKSPACE_DEBUG
0073     CATEGORY_NAME org.kde.plasma.libkworkspace
0074     DESCRIPTION "lib kworkspace debug"
0075     EXPORT PLASMAWORKSPACE
0076 )
0077
0078 qt6_generate_wayland_protocol_client_sources(kworkspace FILES
0079     ${PLASMA_WAYLAND_PROTOCOLS_DIR}/kde-output-order-v1.xml
0080 )
0081
0082 install(TARGETS kworkspace EXPORT libkworkspaceLibraryTargets ${KDE_INSTALL_TARGETS_DEFAULT_ARGS} )
0083
0084 install( FILES kdisplaymanager.h
0085                kworkspace.h
0086                sessionmanagement.h
0087                autostartscriptdesktopfile.h
0088                outputorderwatcher.h
0089                ${CMAKE_CURRENT_BINARY_DIR}/config-libkworkspace.h
0090                ${CMAKE_CURRENT_BINARY_DIR}/kworkspace_export.h
0091          DESTINATION ${KDE_INSTALL_INCLUDEDIR}/kworkspace6 COMPONENT Devel )
0092
0093 set(CMAKECONFIG_INSTALL_DIR ${KDE_INSTALL_CMAKEPACKAGEDIR}/LibKWorkspace)
0094 configure_package_config_file(LibKWorkspaceConfig.cmake.in
0095     "${CMAKE_CURRENT_BINARY_DIR}/LibKWorkspaceConfig.cmake"
0096     INSTALL_DESTINATION ${CMAKECONFIG_INSTALL_DIR})
0097
0098 install(FILES
0099         ${CMAKE_CURRENT_BINARY_DIR}/LibKWorkspaceConfig.cmake
0100         ${CMAKE_CURRENT_BINARY_DIR}/LibKWorkspaceConfigVersion.cmake
0101         DESTINATION ${CMAKECONFIG_INSTALL_DIR})
0102
0103 install(EXPORT libkworkspaceLibraryTargets
0104         NAMESPACE PW::
0105         DESTINATION ${CMAKECONFIG_INSTALL_DIR}
0106         FILE LibKWorkspaceLibraryTargets.cmake )
0107
0108 if(BUILD_TESTING)
0109     add_subdirectory(tests)
0110 endif()