plasma-workspace/libkmpris/CMakeLists.txt

0001 # SPDX-FileCopyrightText: 2023 Fushan Wen <qydwhotmail@gmail.com>
0002 # SPDX-License-Identifier: BSD-3-Clause
0003
0004 add_definitions(-DTRANSLATION_DOMAIN=\"libkmpris\")
0005
0006 set(libkmpris_SRCS
0007     mpris2sourcemodel.cpp
0008     mpris2filterproxymodel.cpp
0009     mpris2model.cpp
0010     multiplexer.cpp
0011     multiplexermodel.cpp
0012     playercontainer.cpp
0013 )
0014
0015 ecm_qt_declare_logging_category(libkmpris_SRCS HEADER libkmpris_debug.h
0016     IDENTIFIER MPRIS2
0017     CATEGORY_NAME kde.dataengine.mpris
0018     DEFAULT_SEVERITY Info)
0019
0020 set_source_files_properties(
0021    dbus/org.freedesktop.DBus.Properties.xml
0022    dbus/org.mpris.MediaPlayer2.Player.xml
0023    dbus/org.mpris.MediaPlayer2.xml
0024    PROPERTIES
0025    NO_NAMESPACE ON)
0026 qt_add_dbus_interface(libkmpris_SRCS dbus/org.freedesktop.DBus.Properties.xml dbusproperties)
0027 qt_add_dbus_interface(libkmpris_SRCS dbus/org.mpris.MediaPlayer2.Player.xml mprisplayer)
0028 qt_add_dbus_interface(libkmpris_SRCS dbus/org.mpris.MediaPlayer2.xml mprisroot)
0029
0030 add_library(kmpris SHARED ${libkmpris_SRCS})
0031 generate_export_header(kmpris)
0032 target_include_directories(kmpris PUBLIC ${CMAKE_CURRENT_SOURCE_DIR} ${CMAKE_CURRENT_BINARY_DIR})
0033 target_link_libraries(kmpris
0034     PUBLIC
0035         Qt::Core
0036         Qt::Qml
0037     PRIVATE
0038         Qt::DBus
0039         KF6::ConfigCore
0040         KF6::I18n
0041 )
0042 set_target_properties(kmpris PROPERTIES
0043                       VERSION ${PROJECT_VERSION}
0044                       SOVERSION ${PROJECT_VERSION_MAJOR})
0045
0046 ecm_add_qml_module(kmpris URI org.kde.plasma.private.mpris GENERATE_PLUGIN_SOURCE)
0047 ecm_finalize_qml_module(kmpris)
0048
0049 install(TARGETS kmpris ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
0050
0051 add_subdirectory(kded)
0052
0053 if(BUILD_TESTING)
0054 add_subdirectory(autotests)
0055 endif()