plasma-workspace/krunner/CMakeLists.txt

0001 set(krunner_SRCS
0002     main.cpp
0003     view.cpp
0004     x11windowscreenrelativepositioner.cpp
0005     qml/krunner.qrc
0006 )
0007
0008 set(krunner_dbusAppXML dbus/org.kde.krunner.App.xml)
0009 qt_add_dbus_adaptor(krunner_SRCS ${krunner_dbusAppXML} view.h View)
0010 ecm_generate_dbus_service_file(
0011     NAME org.kde.krunner
0012     EXECUTABLE "${KDE_INSTALL_FULL_BINDIR}/krunner --daemon"
0013     SYSTEMD_SERVICE plasma-krunner.service
0014     DESTINATION ${KDE_INSTALL_DBUSSERVICEDIR}
0015 )
0016
0017 add_executable(krunner ${krunner_SRCS})
0018
0019 target_link_libraries(krunner
0020     Qt::Quick
0021     Qt::Widgets
0022     KF6::KIOGui
0023     KF6::I18n
0024     Plasma::PlasmaQuick
0025     Plasma::Activities
0026     KF6::DBusAddons
0027     KF6::Crash
0028     KF6::Runner
0029     PW::KWorkspace
0030     LayerShellQt::Interface
0031 )
0032 target_compile_definitions(krunner PRIVATE -DPROJECT_VERSION="${PROJECT_VERSION}")
0033
0034 install(TARGETS krunner ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
0035 install(FILES ${krunner_dbusAppXML} DESTINATION ${KDE_INSTALL_DBUSINTERFACEDIR} )
0036
0037 configure_file(org.kde.krunner.desktop.cmake ${CMAKE_CURRENT_BINARY_DIR}/org.kde.krunner.desktop @ONLY)
0038 install(PROGRAMS ${CMAKE_CURRENT_BINARY_DIR}/org.kde.krunner.desktop DESTINATION ${KDE_INSTALL_DATADIR}/kglobalaccel)
0039
0040 set(CMAKECONFIG_INSTALL_DIR "${KDE_INSTALL_CMAKEPACKAGEDIR}/KRunnerAppDBusInterface")
0041 configure_package_config_file(KRunnerAppDBusInterfaceConfig.cmake.in
0042     "${CMAKE_CURRENT_BINARY_DIR}/KRunnerAppDBusInterfaceConfig.cmake"
0043     PATH_VARS KDE_INSTALL_DBUSINTERFACEDIR
0044     INSTALL_DESTINATION ${CMAKECONFIG_INSTALL_DIR})
0045 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/KRunnerAppDBusInterfaceConfig.cmake
0046     DESTINATION ${CMAKECONFIG_INSTALL_DIR})
0047
0048 ecm_install_configured_files(
0049     INPUT plasma-krunner.service.in
0050     @ONLY
0051     DESTINATION ${KDE_INSTALL_SYSTEMDUSERUNITDIR}
0052 )
0053
0054 install(FILES completions/krunner.zsh RENAME _krunner DESTINATION ${KDE_INSTALL_ZSHAUTOCOMPLETEDIR})