kcms/region_language/CMakeLists.txt

0001 #CMakeLists.txt
0002 # SPDX-License-Identifier: BSD-2-Clause
0003 # SPDX-FileCopyrightText: 2022 Han Young <hanyoung@protonmail.com>
0004
0005 # KI18N Translation Domain for this library
0006 add_definitions(-DTRANSLATION_DOMAIN=\"kcm_regionandlang\")
0007 ################## Set sources files #################
0008 set(kcm_regionandlang_example_SRCS
0009     exampleutility.cpp
0010 )
0011 add_library(kcm_regionandlang_example_static STATIC ${kcm_regionandlang_example_SRCS})
0012 set_property(TARGET kcm_regionandlang_example_static PROPERTY POSITION_INDEPENDENT_CODE ON)
0013 target_link_libraries(kcm_regionandlang_example_static
0014     KF5::I18n
0015     KF5::CoreAddons
0016 )
0017 set(kcm_regionandlang_PART_SRCS
0018     settingtype.h
0019     kcmregionandlang.cpp
0020     localelistmodel.cpp
0021     optionsmodel.cpp
0022     languagelistmodel.cpp
0023     localegenerator.cpp
0024     localegeneratorbase.cpp
0025     localegeneratorgeneratedglibc.cpp
0026     regionandlangsettings.cpp
0027 )
0028 kconfig_add_kcfg_files(kcm_regionandlang_PART_SRCS regionandlangsettingsbase.kcfgc GENERATE_MOC)
0029
0030 if(GLIBC_LOCALE_GEN)
0031     set(kcm_regionandlang_PART_SRCS
0032         ${kcm_regionandlang_PART_SRCS}
0033         localegeneratorglibc.cpp)
0034 endif()
0035 if(UBUNTU_PACKAGEKIT)
0036     set(kcm_regionandlang_PART_SRCS
0037         ${kcm_regionandlang_PART_SRCS}
0038         localegeneratorubuntu.cpp)
0039 endif()
0040 ecm_qt_declare_logging_category(
0041     kcm_regionandlang_PART_SRCS
0042     HEADER kcm_regionandlang_debug.h
0043     IDENTIFIER KCM_REGIONANDLANG
0044     CATEGORY_NAME org.kde.kcm_regionandlang
0045     DESCRIPTION "Region and Language KCM"
0046     EXPORT kcm_regionandlang
0047 )
0048
0049 ################ Build helper and add additional source files #############
0050 if(REGION_LANG_GENERATE_LOCALE_HELPER)
0051     add_subdirectory("localegenhelper")
0052     qt_generate_dbus_interface(
0053         ${CMAKE_CURRENT_SOURCE_DIR}/localegenhelper/localegenhelper.h
0054         org.kde.localegenhelper.xml
0055         OPTIONS -s -m
0056     )
0057     qt_add_dbus_interface(kcm_regionandlang_PART_SRCS ${CMAKE_CURRENT_BINARY_DIR}/org.kde.localegenhelper.xml localegenhelperinterface)
0058 endif()
0059
0060 #################### Declare target #######################
0061 kcoreaddons_add_plugin(kcm_regionandlang SOURCES ${kcm_regionandlang_PART_SRCS} INSTALL_NAMESPACE "plasma/kcms/systemsettings")
0062
0063 kcmutils_generate_desktop_file(kcm_regionandlang)
0064 ecm_qt_install_logging_categories(
0065     EXPORT kcm_regionandlang
0066     DESTINATION "${KDE_INSTALL_LOGGINGCATEGORIESDIR}"
0067 )
0068
0069 ################# Link libraries ####################
0070 target_link_libraries(kcm_regionandlang
0071     kcm_regionandlang_example_static
0072     Qt::Core
0073     Qt::DBus
0074     KF5::I18n
0075     KF5::KCMUtils
0076     KF5::QuickAddons
0077     KF5::ItemModels)
0078 if (QT_MAJOR_VERSION EQUAL "6")
0079     target_link_libraries(kcm_regionandlang Qt::Core5Compat) # for QTextCodec
0080 endif()
0081 if(UBUNTU_PACKAGEKIT)
0082     target_link_libraries(kcm_regionandlang PK::packagekitqt${QT_MAJOR_VERSION})
0083 endif()
0084 ########### install files ###############
0085 kpackage_install_package(package kcm_regionandlang kcms)
0086
0087 ########### unit tests ##############
0088 if(BUILD_TESTING)
0089     add_subdirectory(autotests)
0090 endif()