kcms/lookandfeel/CMakeLists.txt

0001 # KI18N Translation Domain for this library
0002 add_definitions(-DTRANSLATION_DOMAIN=\"kcm_lookandfeel\")
0003
0004 if(HAVE_X11)
0005     set(HAVE_XCURSOR TRUE)
0006 endif()
0007
0008 if(${Breeze_FOUND})
0009     if(${BREEZE_WITH_KDECORATION})
0010         set(HAVE_BREEZE_DECO TRUE)
0011     endif()
0012 endif()
0013
0014 configure_file (config-kcm.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config-kcm.h )
0015
0016 add_library(lookandfeelmanager STATIC
0017     lookandfeelmanager.cpp
0018     ../colors/colorsapplicator.cpp
0019     ../kcms-common.cpp
0020 )
0021
0022 if (HAVE_X11)
0023     target_sources(lookandfeelmanager PRIVATE
0024         ../cursortheme/xcursor/cursortheme.cpp
0025         ../cursortheme/xcursor/xcursortheme.cpp
0026     )
0027 endif ()
0028
0029 kcmutils_generate_module_data(
0030     lookandfeeldata
0031     MODULE_DATA_HEADER lookandfeeldata.h
0032     MODULE_DATA_CLASS_NAME LookAndFeelData
0033     SETTINGS_HEADERS lookandfeelsettings.h
0034     SETTINGS_CLASSES LookAndFeelSettings
0035 )
0036 target_sources(lookandfeelmanager PRIVATE ${lookandfeeldata})
0037 kconfig_add_kcfg_files(lookandfeelmanager lookandfeelsettings.kcfgc GENERATE_MOC)
0038
0039 set_property(TARGET lookandfeelmanager PROPERTY POSITION_INDEPENDENT_CODE ON)
0040
0041 target_link_libraries(lookandfeelmanager
0042     Qt::DBus
0043     KF5::ConfigCore
0044     KF5::GuiAddons
0045     KF5::I18n
0046     KF5::KIOGui
0047     KF5::KCMUtils
0048     KF5::NewStuff
0049     KF5::Package
0050     PlasmaAutostart
0051     krdb
0052 )
0053
0054 if(HAVE_X11)
0055     if (QT_MAJOR_VERSION EQUAL "5")
0056         target_link_libraries(lookandfeelmanager Qt::X11Extras)
0057     else()
0058         target_link_libraries(lookandfeelmanager Qt::GuiPrivate)
0059     endif()
0060    target_link_libraries(lookandfeelmanager X11::Xcursor X11::Xfixes)
0061 endif()
0062
0063 add_library(kcm_lookandfeel_objects OBJECT kcm.cpp)
0064 target_link_libraries(kcm_lookandfeel_objects
0065     lookandfeelmanager
0066     KF5::IconThemes
0067     KF5::JobWidgets
0068     KF5::KIOGui
0069     KF5::QuickAddons
0070     PW::KWorkspace
0071 )
0072
0073 set_property(TARGET kcm_lookandfeel_objects PROPERTY POSITION_INDEPENDENT_CODE ON)
0074
0075 kcoreaddons_add_plugin(kcm_lookandfeel SOURCES kcmmain.cpp INSTALL_NAMESPACE "plasma/kcms/systemsettings")
0076 kcmutils_generate_desktop_file(kcm_lookandfeel)
0077 target_link_libraries(kcm_lookandfeel kcm_lookandfeel_objects)
0078
0079 install(FILES lookandfeelsettings.kcfg DESTINATION ${KDE_INSTALL_KCFGDIR})
0080 install(FILES lookandfeel.knsrc DESTINATION ${KDE_INSTALL_KNSRCDIR})
0081
0082 if(BUILD_TESTING)
0083    find_package(Qt${QT_MAJOR_VERSION}Test ${QT_MIN_VERSION} CONFIG REQUIRED)
0084    add_subdirectory(autotests)
0085 endif()
0086
0087 kpackage_install_package(package kcm_lookandfeel kcms)
0088
0089 ###### Command line tool
0090
0091 add_executable(plasma-apply-lookandfeel lnftool.cpp)
0092
0093 target_link_libraries(plasma-apply-lookandfeel kcm_lookandfeel_objects)
0094
0095 ADD_CUSTOM_TARGET(plasma-apply-lookandfeel_link ALL
0096                   COMMAND ${CMAKE_COMMAND} -E create_symlink ${KDE_INSTALL_FULL_BINDIR}/plasma-apply-lookandfeel ${CMAKE_CURRENT_BINARY_DIR}/lookandfeeltool)
0097 install( FILES ${CMAKE_CURRENT_BINARY_DIR}/lookandfeeltool DESTINATION ${KDE_INSTALL_FULL_BINDIR}/ )
0098 install( TARGETS plasma-apply-lookandfeel ${KDE_INSTALL_TARGETS_DEFAULT_ARGS} )