applets/systemtray/CMakeLists.txt

0001 add_definitions(-DTRANSLATION_DOMAIN=\"plasma_applet_org.kde.plasma.private.systemtray\")
0002
0003 plasma_install_package(package org.kde.plasma.private.systemtray)
0004
0005 include_directories(${plasma-workspace_SOURCE_DIR}/statusnotifierwatcher)
0006
0007 set(systemtray_SRCS
0008     dbusserviceobserver.cpp
0009     plasmoidregistry.cpp
0010     statusnotifieritemjob.cpp
0011     statusnotifieritemhost.cpp
0012     statusnotifieritemservice.cpp
0013     statusnotifieritemsource.cpp
0014     systemtraysettings.cpp
0015     systemtraytypes.cpp
0016 )
0017
0018 qt_add_dbus_interface(systemtray_SRCS ${KSTATUSNOTIFIERITEM_DBUS_INTERFACES_DIR}/kf6_org.kde.StatusNotifierWatcher.xml statusnotifierwatcher_interface)
0019 qt_add_dbus_interface(systemtray_SRCS ${plasma-workspace_SOURCE_DIR}/libkmpris/dbus/org.freedesktop.DBus.Properties.xml dbusproperties)
0020
0021 set(statusnotifieritem_xml ${KSTATUSNOTIFIERITEM_DBUS_INTERFACES_DIR}/kf6_org.kde.StatusNotifierItem.xml)
0022 set_source_files_properties(${statusnotifieritem_xml} PROPERTIES
0023    NO_NAMESPACE false
0024    INCLUDE "systemtraytypes.h"
0025    CLASSNAME OrgKdeStatusNotifierItem
0026 )
0027 qt_add_dbus_interface(systemtray_SRCS ${statusnotifieritem_xml} statusnotifieritem_interface)
0028
0029 ecm_qt_declare_logging_category(systemtray_SRCS HEADER debug.h
0030                                             IDENTIFIER SYSTEM_TRAY
0031                                             CATEGORY_NAME kde.systemtray
0032                                             DEFAULT_SEVERITY Info
0033                                             DESCRIPTION "plasma applet systemtray"
0034                                             EXPORT PLASMAWORKSPACE
0035                                         )
0036 add_library(systemtray_static STATIC ${systemtray_SRCS})
0037 target_link_libraries(systemtray_static
0038     PUBLIC
0039         Qt::DBus
0040         Qt::Gui
0041         Qt${QT_VERSION_MAJOR}::GuiPrivate
0042         Qt::Quick
0043         KF6::ConfigCore
0044         KF6::IconThemes
0045         KF6::I18n
0046         KF6::ItemModels
0047         KF6::WindowSystem
0048         KF6::XmlGui
0049         Plasma::Plasma
0050         Plasma::Plasma5Support
0051         Plasma::PlasmaQuick
0052         dbusmenuqt
0053 )
0054
0055 set_property(TARGET systemtray_static PROPERTY POSITION_INDEPENDENT_CODE ON)
0056
0057 add_library(systemtraymodel_static STATIC systemtraymodel.cpp sortedsystemtraymodel.cpp)
0058 target_link_libraries(systemtraymodel_static PUBLIC systemtray_static)
0059 set_property(TARGET systemtraymodel_static PROPERTY POSITION_INDEPENDENT_CODE ON)
0060
0061 kcoreaddons_add_plugin(org.kde.plasma.private.systemtray SOURCES systemtray.cpp INSTALL_NAMESPACE "plasma/applets")
0062
0063 target_link_libraries(org.kde.plasma.private.systemtray systemtraymodel_static)
0064
0065 ecm_add_qml_module(systemtrayplugin URI org.kde.plasma.private.systemtray GENERATE_PLUGIN_SOURCE)
0066 target_sources(systemtrayplugin PRIVATE systemtraymodel.cpp)
0067 target_link_libraries(systemtrayplugin PRIVATE systemtray_static)
0068 ecm_finalize_qml_module(systemtrayplugin)
0069
0070 install(FILES statusnotifieritem.operations DESTINATION ${PLASMA5SUPPORT_DATA_INSTALL_DIR}/services)
0071
0072 add_subdirectory(container)
0073 if(BUILD_TESTING)
0074   add_subdirectory(autotests)
0075   add_subdirectory(tests)
0076 endif()