Warning, /plasma/plasma-workspace/applets/appmenu/package/contents/ui/main.qml is written in an unsupported language. File is not indexed.

 /*
     SPDX-FileCopyrightText: 2013 Heena Mahour <heena393@gmail.com>
     SPDX-FileCopyrightText: 2013 Sebastian Kügler <sebas@kde.org>
     SPDX-FileCopyrightText: 2016 Kai Uwe Broulik <kde@privat.broulik.de>
 
     SPDX-License-Identifier: GPL-2.0-or-later
 */
 import QtQuick 2.15
 import QtQuick.Layouts 1.15
 import QtQuick.Controls 2.15
 // Deliberately imported after QtQuick to avoid missing restoreMode property in Binding. Fix in Qt 6.
 import QtQml 2.15
 
 import org.kde.plasma.plasmoid 2.0
 import org.kde.kquickcontrolsaddons 2.0 // For KCMShell
 import org.kde.plasma.core as PlasmaCore
 import org.kde.plasma.private.keyboardindicator as KeyboardIndicator
 import org.kde.plasma.components 3.0 as PlasmaComponents3
 import org.kde.plasma.private.appmenu 1.0 as AppMenuPrivate
 import org.kde.kirigami 2.5 as Kirigami
 
 PlasmoidItem {
     id: root
 
     readonly property bool vertical: Plasmoid.formFactor === PlasmaCore.Types.Vertical
     readonly property bool view: Plasmoid.configuration.compactView
 
     onViewChanged: {
         Plasmoid.view = view;
     }
 
     Plasmoid.constraintHints: Plasmoid.CanFillArea
     preferredRepresentation: Plasmoid.configuration.compactView ? compactRepresentation : fullRepresentation
 
     // Only exists because the default CompactRepresentation doesn't expose a
     // way to mark its icon as disabled.
     // TODO remove once it gains that feature.
     compactRepresentation: PlasmaComponents3.ToolButton {
         readonly property int fakeIndex: 0
         Layout.fillWidth: false
         Layout.fillHeight: false
         Layout.minimumWidth: implicitWidth
         Layout.maximumWidth: implicitWidth
         enabled: appMenuModel.menuAvailable
         checkable: appMenuModel.menuAvailable && Plasmoid.currentIndex === fakeIndex
         checked: checkable
         icon.name: "application-menu"
 
         display: PlasmaComponents3.AbstractButton.IconOnly
         text: Plasmoid.title
         Accessible.description: toolTipSubText
 
         onClicked: Plasmoid.trigger(this, 0);
     }
 
     fullRepresentation: GridLayout {
         id: buttonGrid
 
         Plasmoid.status: {
             if (appMenuModel.menuAvailable && Plasmoid.currentIndex > -1 && buttonRepeater.count > 0) {
                 return PlasmaCore.Types.NeedsAttentionStatus;
             } else {
                 //when we're not enabled set to active to show the configure button
                 return buttonRepeater.count > 0 ? PlasmaCore.Types.ActiveStatus : PlasmaCore.Types.HiddenStatus;
             }
         }
 
         LayoutMirroring.enabled: Qt.application.layoutDirection === Qt.RightToLeft
         Layout.minimumWidth: implicitWidth
         Layout.minimumHeight: implicitHeight
 
         flow: root.vertical ? GridLayout.TopToBottom : GridLayout.LeftToRight
         rowSpacing: 0
         columnSpacing: 0
 
         Binding {
             target: plasmoid
             property: "buttonGrid"
             value: buttonGrid
             restoreMode: Binding.RestoreNone
         }
 
         Connections {
             target: Plasmoid
             function onRequestActivateIndex(index: int) {
                 const button = buttonRepeater.itemAt(index);
                 if (button) {
                     button.activated();
                 }
             }
         }
 
         Connections {
             target: Plasmoid
             function onActivated() {
                 const button = buttonRepeater.itemAt(0);
                 if (button) {
                     button.activated();
                 }
             }
         }
 
         PlasmaComponents3.ToolButton {
             id: noMenuPlaceholder
             visible: buttonRepeater.count === 0
             text: Plasmoid.title
             Layout.fillWidth: root.vertical
             Layout.fillHeight: !root.vertical
         }
 
         Repeater {
             id: buttonRepeater
             model: appMenuModel.visible ? appMenuModel : null
 
             MenuDelegate {
                 readonly property int buttonIndex: index
 
                 Layout.fillWidth: root.vertical
                 Layout.fillHeight: !root.vertical
                 text: activeMenu
                 // TODO: Alt and other modifiers might be unavailable on Wayland
                 Kirigami.MnemonicData.active: altState.pressed
 
                 down: pressed || Plasmoid.currentIndex === index
                 visible: text !== "" && model.activeActions.visible
 
                 menuIsOpen: Plasmoid.currentIndex !== -1
                 onActivated: Plasmoid.trigger(this, index)
 
                 // So we can show mnemonic underlines only while Alt is pressed
                 KeyboardIndicator.KeyState {
                     id: altState
                     key: Qt.Key_Alt
                 }
             }
         }
         Item {
             Layout.preferredWidth: 0
             Layout.preferredHeight: 0
             Layout.fillWidth: true
             Layout.fillHeight: true
         }
     }
 
     AppMenuPrivate.AppMenuModel {
         id: appMenuModel
         containmentStatus: Plasmoid.containment.status
         screenGeometry: root.screenGeometry
         onRequestActivateIndex: Plasmoid.requestActivateIndex(index)
         Component.onCompleted: {
             Plasmoid.model = appMenuModel;
         }
     }
 }