Warning, /plasma/plasma-pa/CMakeLists.txt is written in an unsupported language. File is not indexed.

0001 cmake_minimum_required(VERSION 3.16)
0002 
0003 project(plasma-volume-control)
0004 
0005 set(PROJECT_VERSION "5.27.10")
0006 set(PROJECT_VERSION_MAJOR 5)
0007 
0008 set(QT_MIN_VERSION "5.15.2")
0009 set(KF5_MIN_VERSION "5.102.0")
0010 set(KDE_COMPILERSETTINGS_LEVEL "5.82")
0011 
0012 set(CMAKE_CXX_STANDARD 17)
0013 set(CMAKE_CXX_STANDARD_REQUIRED ON)
0014 
0015 find_package(ECM ${KF5_MIN_VERSION} REQUIRED NO_MODULE)
0016 set(CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake/ ${ECM_MODULE_PATH})
0017 
0018 add_definitions(-DTRANSLATION_DOMAIN=\"kcm_pulseaudio\" -DQT_NO_KEYWORDS)
0019 include(FeatureSummary)
0020 include(KDEInstallDirs)
0021 include(KDECMakeSettings)
0022 include(KDECompilerSettings NO_POLICY_SCOPE)
0023 include(KDEClangFormat)
0024 include(KDEGitCommitHooks)
0025 include(ECMSetupVersion)
0026 include(ECMOptionalAddSubdirectory)
0027 include(FindPkgConfig)
0028 include(ECMDeprecationSettings)
0029 
0030 ecm_setup_version(${PROJECT_VERSION}
0031     VARIABLE_PREFIX PLASMAPA
0032     VERSION_HEADER ${CMAKE_BINARY_DIR}/version.h)
0033 
0034 find_package(Qt${QT_MAJOR_VERSION} ${QT_MIN_VERSION} REQUIRED COMPONENTS
0035     Core
0036     Gui
0037     DBus
0038     Quick
0039 )
0040 find_package(KF5 ${KF5_MIN_VERSION} REQUIRED COMPONENTS
0041     CoreAddons
0042     Declarative
0043     DocTools
0044     GlobalAccel
0045     Notifications
0046     I18n
0047     Plasma
0048     KCMUtils
0049 )
0050 
0051 find_package(Canberra REQUIRED)
0052 
0053 pkg_check_modules(LIBPULSE libpulse REQUIRED IMPORTED_TARGET)
0054 pkg_check_modules(LIBPULSE_MAINLOOP libpulse-mainloop-glib REQUIRED IMPORTED_TARGET)
0055 
0056 pkg_check_modules(GIO gio-2.0 REQUIRED IMPORTED_TARGET)
0057 
0058 find_package(CanberraPulse)
0059 set_package_properties(CanberraPulse PROPERTIES
0060     DESCRIPTION "Pulseaudio backend for libcanberra"
0061     PURPOSE "Required for volume feedback sounds"
0062     TYPE RUNTIME
0063 )
0064 
0065 find_package(SoundThemeFreedesktop)
0066 set_package_properties(SoundThemeFreedesktop PROPERTIES
0067     DESCRIPTION "The standard freedesktop sound theme"
0068     PURPOSE "Required for volume feedback sounds"
0069     URL "https://www.freedesktop.org/wiki/Specifications/sound-theme-spec/"
0070     TYPE RUNTIME
0071 )
0072 
0073 find_package(KF5Kirigami2 ${KF5_MIN_VERSION} CONFIG)
0074 set_package_properties(KF5Kirigami2 PROPERTIES
0075     DESCRIPTION "A QtQuick based components set"
0076     PURPOSE "Required at runtime the KCM"
0077     TYPE RUNTIME
0078 )
0079 
0080 ecm_set_disabled_deprecation_versions(QT 5.15.2
0081     KF 5.101
0082 )
0083 
0084 add_subdirectory(applet)
0085 add_subdirectory(src)
0086 add_subdirectory(data)
0087 add_subdirectory(doc)
0088 
0089 # add clang-format target for all our real source files
0090 file(GLOB_RECURSE ALL_CLANG_FORMAT_SOURCE_FILES *.cpp *.h)
0091 kde_clang_format(${ALL_CLANG_FORMAT_SOURCE_FILES})
0092 kde_configure_git_pre_commit_hook(CHECKS CLANG_FORMAT)
0093 
0094 ki18n_install(po)
0095 kdoctools_install(po)
0096 
0097 feature_summary(WHAT ALL FATAL_ON_MISSING_REQUIRED_PACKAGES)