cmake/modules/FindQt5PlatformSupport.cmake

0001 #.rst:
0002 # FindQt5PlatformSupport
0003 # -------
0004 #
0005 # Try to find Qt5PlatformSupport on a Unix system.
0006 #
0007 # This will define the following variables:
0008 #
0009 # ``Qt5PlatformSupport_FOUND``
0010 #     True if (the requested version of) Qt5PlatformSupport is available
0011 # ``Qt5PlatformSupport_VERSION``
0012 #     The version of Qt5PlatformSupport
0013 # ``Qt5PlatformSupport_LIBRARIES``
0014 #     This can be passed to target_link_libraries() instead of the ``Qt5PlatformSupport::Qt5PlatformSupport``
0015 #     target
0016 # ``Qt5PlatformSupport_INCLUDE_DIRS``
0017 #     This should be passed to target_include_directories() if the target is not
0018 #     used for linking
0019 # ``Qt5PlatformSupport_DEFINITIONS``
0020 #     This should be passed to target_compile_options() if the target is not
0021 #     used for linking
0022 #
0023 # If ``Qt5PlatformSupport_FOUND`` is TRUE, it will also define the following imported target:
0024 #
0025 # ``Qt5PlatformSupport::Qt5PlatformSupport``
0026 #     The Qt5PlatformSupport library
0027 #
0028 # In general we recommend using the imported target, as it is easier to use.
0029 # Bear in mind, however, that if the target is in the link interface of an
0030 # exported library, it must be made available by the package config file.
0031
0032 #=============================================================================
0033 # SPDX-FileCopyrightText: 2014 Alex Merry <alex.merry@kde.org>
0034 # SPDX-FileCopyrightText: 2014 Martin Gräßlin <mgraesslin@kde.org>
0035 #
0036 # SPDX-License-Identifier: BSD-3-Clause
0037 #=============================================================================
0038
0039 if(CMAKE_VERSION VERSION_LESS 2.8.12)
0040     message(FATAL_ERROR "CMake 2.8.12 is required by FindQt5PlatformSupport.cmake")
0041 endif()
0042 if(CMAKE_MINIMUM_REQUIRED_VERSION VERSION_LESS 2.8.12)
0043     message(AUTHOR_WARNING "Your project should require at least CMake 2.8.12 to use FindQt5PlatformSupport.cmake")
0044 endif()
0045
0046 # Use pkg-config to get the directories and then use these values
0047 # in the FIND_PATH() and FIND_LIBRARY() calls
0048 find_package(PkgConfig)
0049 pkg_check_modules(PKG_Qt5PlatformSupport QUIET Qt5Gui)
0050
0051 set(Qt5PlatformSupport_DEFINITIONS ${PKG_Qt5PlatformSupport_CFLAGS_OTHER})
0052 set(Qt5PlatformSupport_VERSION ${PKG_Qt5PlatformSupport_VERSION})
0053
0054 find_path(Qt5PlatformSupport_INCLUDE_DIR
0055     NAMES
0056         QtPlatformSupport/private/qfontconfigdatabase_p.h
0057     HINTS
0058         ${PKG_Qt5PlatformSupport_INCLUDEDIR}/QtPlatformSupport/${PKG_Qt5PlatformSupport_VERSION}/
0059 )
0060 find_library(Qt5PlatformSupport_LIBRARY
0061     NAMES
0062         Qt5PlatformSupport
0063     HINTS
0064         ${PKG_Qt5PlatformSupport_LIBRARY_DIRS}
0065 )
0066
0067 include(FindPackageHandleStandardArgs)
0068 find_package_handle_standard_args(Qt5PlatformSupport
0069     FOUND_VAR
0070         Qt5PlatformSupport_FOUND
0071     REQUIRED_VARS
0072         Qt5PlatformSupport_LIBRARY
0073         Qt5PlatformSupport_INCLUDE_DIR
0074     VERSION_VAR
0075         Qt5PlatformSupport_VERSION
0076 )
0077
0078 if(Qt5PlatformSupport_FOUND AND NOT TARGET Qt5PlatformSupport::Qt5PlatformSupport)
0079     add_library(Qt5PlatformSupport::Qt5PlatformSupport UNKNOWN IMPORTED)
0080     set_target_properties(Qt5PlatformSupport::Qt5PlatformSupport PROPERTIES
0081         IMPORTED_LOCATION "${Qt5PlatformSupport_LIBRARY}"
0082         INTERFACE_COMPILE_OPTIONS "${Qt5PlatformSupport_DEFINITIONS}"
0083         INTERFACE_INCLUDE_DIRECTORIES "${Qt5PlatformSupport_INCLUDE_DIR}"
0084     )
0085 endif()
0086
0087 mark_as_advanced(Qt5PlatformSupport_LIBRARY Qt5PlatformSupport_INCLUDE_DIR)
0088
0089 # compatibility variables
0090 set(Qt5PlatformSupport_LIBRARIES ${Qt5PlatformSupport_LIBRARY})
0091 set(Qt5PlatformSupport_INCLUDE_DIRS ${Qt5PlatformSupport_INCLUDE_DIR})
0092 set(Qt5PlatformSupport_VERSION_STRING ${Qt5PlatformSupport_VERSION})
0093
0094
0095 include(FeatureSummary)
0096 set_package_properties(Qt5PlatformSupport PROPERTIES
0097     URL "https://www.qt.io"
0098     DESCRIPTION "Qt PlatformSupport module."
0099 )
0100