plasma/plasma-integration/CMakeLists.txt

0001 cmake_minimum_required(VERSION 3.16)
0002
0003 project(PlasmaIntegration)
0004 set(PROJECT_VERSION "5.27.10")
0005 set(PROJECT_VERSION_MAJOR 5)
0006
0007 set(QT_MIN_VERSION "5.15.2")
0008 set(KF5_MIN_VERSION "5.102.0")
0009 set(KDE_COMPILERSETTINGS_LEVEL "5.82")
0010
0011 find_package(ECM ${KF5_MIN_VERSION}  REQUIRED NO_MODULE)
0012 set(CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake/modules ${ECM_MODULE_PATH} )
0013
0014 include(KDEInstallDirs)
0015 include(KDECMakeSettings)
0016 include(KDECompilerSettings NO_POLICY_SCOPE)
0017 include(FeatureSummary)
0018 include(GenerateExportHeader)
0019 include(KDEClangFormat)
0020 include(KDEGitCommitHooks)
0021 include(ECMDeprecationSettings)
0022
0023 find_package(Qt${QT_MAJOR_VERSION} ${QT_MIN_VERSION} CONFIG REQUIRED Widgets DBus QuickControls2 WaylandClient)
0024 find_package(Qt${QT_MAJOR_VERSION}Gui ${QT_MIN_VERSION} CONFIG REQUIRED Private)
0025 if (QT_MAJOR_VERSION EQUAL "5")
0026     find_package(Qt5 ${QT_MIN_VERSION} CONFIG REQUIRED X11Extras)
0027 endif()
0028
0029 find_package(KF5 ${KF5_MIN_VERSION} REQUIRED COMPONENTS
0030                 Config ConfigWidgets I18n IconThemes KIO Notifications
0031                 WidgetsAddons WindowSystem ConfigWidgets
0032 )
0033
0034 if (QT_MAJOR_VERSION EQUAL "5")
0035     find_package(QtWaylandScanner ${QT_MIN_VERSION} REQUIRED)
0036 endif()
0037 find_package(Wayland 1.9 REQUIRED Client)
0038 find_package(PlasmaWaylandProtocols 1.6.0 CONFIG REQUIRED)
0039
0040 find_package(XCB COMPONENTS XCB)
0041 set_package_properties(XCB PROPERTIES
0042     DESCRIPTION "X protocol C-language Binding"
0043     URL "https://xcb.freedesktop.org"
0044     TYPE REQUIRED
0045     PURPOSE "Required to pass style properties to native Windows on X11 Platform"
0046 )
0047
0048 find_package(Breeze 5 CONFIG)
0049 set_package_properties(Breeze PROPERTIES
0050                        TYPE REQUIRED
0051                        PURPOSE "For setting the default QStyle name")
0052
0053 # dependencies for QPA plugin
0054 if (QT_MAJOR_VERSION EQUAL "5")
0055     find_package(Qt5ThemeSupport REQUIRED)
0056     set(QT5PLATFORMSUPPORT_LIBS Qt5ThemeSupport::Qt5ThemeSupport)
0057 else()
0058     set(QT5PLATFORMSUPPORT_LIBS)
0059 endif()
0060 ecm_set_disabled_deprecation_versions(QT 5.15.2
0061     KF 5.101
0062 )
0063
0064 add_definitions(-DTRANSLATION_DOMAIN=\"plasmaintegration5\")
0065 if (IS_DIRECTORY "${CMAKE_CURRENT_SOURCE_DIR}/po")
0066     ki18n_install(po)
0067 endif()
0068 add_subdirectory(src)
0069 add_subdirectory(autotests)
0070 add_subdirectory(tests)
0071
0072 find_package(FontNotoSans)
0073 set_package_properties(FontNotoSans PROPERTIES
0074     PURPOSE "Default sans-serif font -- this is not detected automatically, pass -DCMAKE_DISABLE_FIND_PACKAGE_FontNotoSans=true to mark it ignored."
0075     URL "https://www.google.com/get/noto/"
0076     TYPE RUNTIME
0077 )
0078 find_package(FontHack)
0079 set_package_properties(FontHack PROPERTIES
0080     PURPOSE "Default monospace font -- this is not detected automatically, pass -DCMAKE_DISABLE_FIND_PACKAGE_FontHack=true to mark it ignored."
0081     URL "https://sourcefoundry.org/hack/"
0082     TYPE RUNTIME
0083 )
0084
0085 # add clang-format target for all our real source files
0086 file(GLOB_RECURSE ALL_CLANG_FORMAT_SOURCE_FILES *.cpp *.h)
0087 kde_clang_format(${ALL_CLANG_FORMAT_SOURCE_FILES})
0088 kde_configure_git_pre_commit_hook(CHECKS CLANG_FORMAT)
0089
0090 feature_summary(WHAT ALL INCLUDE_QUIET_PACKAGES FATAL_ON_MISSING_REQUIRED_PACKAGES)