plasma/plasma-firewall/CMakeLists.txt

0001 # SPDX-License-Identifier: BSD-3-Clause
0002 # SPDX-FileCopyrightText: 2020 Tomaz Canabrava <tcanabrava@kde.org>
0003
0004 cmake_minimum_required(VERSION 3.16)
0005 #-----------------------------------------------------------------------------
0006 #                           GENERAL CONFIGURATION
0007 #-----------------------------------------------------------------------------
0008 project(plasma-firewall)
0009 set(PROJECT_VERSION "5.27.80")
0010
0011 set(KF6_MIN_VERSION "5.240.0")
0012 set(KDE_COMPILERSETTINGS_LEVEL "5.82")
0013 set(QT_MIN_VERSION "6.4.0")
0014
0015 set(CMAKE_AUTOMOC TRUE)
0016 set(CMAKE_AUTORCC TRUE)
0017
0018 set(CMAKE_CXX_STANDARD 20)
0019 set(CMAKE_CXX_STANDARD_REQUIRED ON)
0020
0021 #-----------------------------------------------------------------------------
0022 #                                OPTIONS
0023 #-----------------------------------------------------------------------------
0024
0025 include(FeatureSummary)
0026
0027 option(BUILD_FIREWALLD_BACKEND "Build the firewalld backend" ON)
0028 add_feature_info(FIREWALLD_BACKEND ${BUILD_FIREWALLD_BACKEND} "Build the FirewallD backend")
0029
0030 option(BUILD_UFW_BACKEND "Build the Uncomplicated Firewall (UFW) backend" ON)
0031 add_feature_info(UFW_BACKEND ${BUILD_UFW_BACKEND} "Build the Uncomplicated Firewall (UFW) backend")
0032
0033 #-----------------------------------------------------------------------------
0034 #                              DEPENDENCIES
0035 #-----------------------------------------------------------------------------
0036 find_package(Python3 COMPONENTS Interpreter)
0037 # KF6
0038 find_package(ECM ${KF6_MIN_VERSION} REQUIRED NO_MODULE)
0039 set(CMAKE_MODULE_PATH ${ECM_MODULE_PATH})
0040 include(KDEInstallDirs)
0041 include(KDECompilerSettings)
0042 include(KDECMakeSettings)
0043 include(ECMDeprecationSettings)
0044
0045 # Qt6
0046 find_package(Qt6 REQUIRED COMPONENTS
0047     Core
0048     Qml
0049     Quick
0050     DBus
0051     Test
0052 )
0053
0054 ecm_set_disabled_deprecation_versions(QT 6.4
0055     KF 5.240
0056 )
0057
0058 find_package(KF6 ${KF6_MIN_VERSION} REQUIRED COMPONENTS
0059     Config
0060     CoreAddons
0061     KCMUtils
0062     I18n
0063     Package
0064     Auth
0065 )
0066
0067
0068 #-----------------------------------------------------------------------------
0069 #                               SOURCES
0070 #-----------------------------------------------------------------------------
0071 add_subdirectory(kcm)
0072
0073 enable_testing(true)
0074 add_subdirectory(autotests)
0075 add_subdirectory(tests)
0076
0077 #-----------------------------------------------------------------------------
0078 #                               Clang Format
0079 #-----------------------------------------------------------------------------
0080 include(KDEClangFormat)
0081 file(GLOB_RECURSE ALL_CLANG_FORMAT_SOURCE_FILES *.cpp *.h)
0082 kde_clang_format(${ALL_CLANG_FORMAT_SOURCE_FILES})
0083
0084 install(FILES org.kde.plasma.firewall.metainfo.xml DESTINATION ${KDE_INSTALL_METAINFODIR})
0085
0086 #-----------------------------------------------------------------------------
0087 #                                Translations
0088 #-----------------------------------------------------------------------------
0089 ki18n_install(po)
0090
0091 #-----------------------------------------------------------------------------
0092 #                               BUILD SUMMARY
0093 #-----------------------------------------------------------------------------
0094 feature_summary(WHAT ALL FATAL_ON_MISSING_REQUIRED_PACKAGES)