kcms/touchpad/CMakeLists.txt

0001 # KI18N Translation Domain for this library
0002 add_definitions(-DTRANSLATION_DOMAIN=\"kcm_touchpad\")
0003
0004 add_subdirectory(icon)
0005
0006 set(TOUCHPAD_SRCS
0007     actions.cpp
0008     touchpadbackend.cpp
0009     logging.cpp
0010     touchpadparametersbase.cpp
0011 )
0012
0013 if (BUILD_KCM_TOUCHPAD_X11)
0014     if (NOT X11_XCB_FOUND)
0015         list(APPEND MISSING_DEPS "X11_XCB")
0016     endif()
0017     if (NOT X11_Xi_FOUND)
0018         list(APPEND MISSING_DEPS "X11_Xi")
0019     endif()
0020     if (NOT XORGSERVER_FOUND)
0021         list(APPEND MISSING_DEPS "xorg-server")
0022     endif()
0023     if (MISSING_DEPS)
0024         message(FATAL_ERROR "Missing X11 dependencies for kcm_touchpad: ${MISSING_DEPS}. Install dependencies or set CMake option -DBUILD_KCM_TOUCHPAD_X11=OFF.")
0025     endif()
0026     include(backends/x11.cmake)
0027 endif()
0028
0029 if (BUILD_KCM_TOUCHPAD_KWIN_WAYLAND)
0030     include(backends/kwin_wayland.cmake)
0031 endif()
0032
0033 qt_add_dbus_interfaces(TOUCHPAD_SRCS
0034                         ${CMAKE_CURRENT_BINARY_DIR}/org.kde.touchpad.xml
0035 )
0036
0037 qt_generate_dbus_interface(kded/kded.h org.kde.touchpad.xml)
0038
0039 kconfig_add_kcfg_files(TOUCHPAD_SRCS kdedsettings.kcfgc)
0040 kconfig_add_kcfg_files(TOUCHPAD_SRCS touchpadparameters.kcfgc)
0041
0042 add_library(touchpad STATIC ${TOUCHPAD_SRCS} ${backend_SRCS})
0043
0044 set_property(TARGET touchpad PROPERTY POSITION_INDEPENDENT_CODE ON)
0045
0046 target_link_libraries(touchpad
0047     PUBLIC
0048     Qt::Core
0049     KF6::XmlGui
0050     PRIVATE
0051     ${backend_LIBS}
0052     Qt::DBus
0053     KF6::ConfigCore
0054     KF6::ConfigGui
0055     KF6::WindowSystem
0056     KF6::I18n
0057     KF6::GlobalAccel
0058 )
0059 target_link_libraries(touchpad PRIVATE Qt::GuiPrivate)
0060
0061 add_subdirectory(kcm)
0062 add_subdirectory(kded)
0063 add_subdirectory(applet)
0064
0065 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/org.kde.touchpad.xml
0066         DESTINATION ${KDE_INSTALL_DBUSINTERFACEDIR}
0067 )