kcms/mouse/CMakeLists.txt

0001 # KI18N Translation Domain for this library
0002 add_definitions(-DTRANSLATION_DOMAIN=\"kcmmouse\")
0003
0004 add_subdirectory( misc )
0005
0006 ## Add common files here.
0007 set(common_SRCS
0008     inputbackend.cpp
0009 )
0010
0011 ecm_qt_declare_logging_category(common_SRCS
0012     HEADER
0013         logging.h
0014     IDENTIFIER
0015         KCM_MOUSE
0016     CATEGORY_NAME
0017         kcm_mouse
0018     DEFAULT_SEVERITY
0019         Critical
0020     DESCRIPTION
0021         "KCM for mouse input"
0022     EXPORT
0023         kcm_mouse
0024 )
0025 ecm_qt_install_logging_categories(
0026     EXPORT kcm_mouse
0027     DESTINATION "${KDE_INSTALL_LOGGINGCATEGORIESDIR}"
0028 )
0029
0030 if (BUILD_KCM_MOUSE_KWIN_WAYLAND)
0031     include(backends/kwin_wl.cmake)
0032 endif()
0033
0034 if (BUILD_KCM_MOUSE_X11)
0035     if (NOT EVDEV_FOUND)
0036         list(APPEND MISSING_DEPS "xorg-evdev")
0037     endif()
0038     if (NOT XORGLIBINPUT_FOUND)
0039         list(APPEND MISSING_DEPS "xorg-libinput")
0040     endif()
0041     if (NOT X11_Xi_FOUND)
0042         list(APPEND MISSING_DEPS "X11_Xi")
0043     endif()
0044     if (NOT X11_Xinput_FOUND)
0045         list(APPEND MISSING_DEPS "X11_Xinput")
0046     endif()
0047     if (MISSING_DEPS)
0048         message(FATAL_ERROR "Missing X11 dependencies for kcm_mouse: ${MISSING_DEPS}. Install dependencies or set CMake option -DBUILD_KCM_MOUSE_X11=OFF.")
0049     endif()
0050
0051     include(backends/x11.cmake)
0052
0053     # kapplymousetheme is an X11-only tool, called by startplasma-x11 but not startplasma-wayland
0054     add_executable(kapplymousetheme
0055         kapplymousetheme.cpp
0056         ${common_SRCS}
0057         ${backend_SRCS}
0058     )
0059     target_link_libraries(kapplymousetheme
0060         ${backend_LIBS}
0061         Qt::Gui
0062         Qt::DBus
0063         KF6::CoreAddons
0064         KF6::ConfigCore
0065         KF6::I18n
0066         KF6::WindowSystem
0067         PW::KWorkspace
0068     )
0069     install(TARGETS kapplymousetheme ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
0070 endif()
0071
0072 qt_add_resources( common_SRCS kcm/resources.qrc )
0073
0074 add_library(kcm_mouse MODULE
0075     ${common_SRCS}
0076     ${backend_SRCS}
0077     plugin.cpp
0078     kcm/configcontainer.cpp
0079     kcm/configplugin.cpp
0080     kcm/libinput/libinput_config.cpp
0081 )
0082 kcmutils_generate_desktop_file(kcm_mouse)
0083
0084 target_link_libraries(kcm_mouse
0085     ${backend_LIBS}
0086     KF6::KCMUtils
0087     KF6::I18n
0088     KF6::KIOCore
0089     KF6::KIOWidgets
0090     KF6::WindowSystem
0091     PW::KWorkspace
0092     Qt::DBus
0093     Qt::QuickWidgets
0094 )
0095
0096 install(TARGETS kcm_mouse DESTINATION ${KDE_INSTALL_PLUGINDIR}/plasma/kcms/systemsettings)
0097
0098 ########### install files ###############
0099
0100
0101 add_custom_command(TARGET kcm_mouse POST_BUILD
0102                    COMMAND ${CMAKE_COMMAND} -E create_symlink "../kcms/systemsettings/kcm_mouse.so" "kcm_mouse_init.so")
0103
0104 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/kcm_mouse_init.so DESTINATION ${KDE_INSTALL_PLUGINDIR}/plasma/kcminit)