kcms/activities/CMakeLists.txt

0001 # vim:set softtabstop=3 shiftwidth=3 tabstop=3 expandtab:
0002 project (KCMActivities)
0003 add_definitions(-DTRANSLATION_DOMAIN=\"kcm_activities5\")
0004
0005 find_package (Qt${QT_MAJOR_VERSION} REQUIRED NO_MODULE COMPONENTS Core Quick Sql Qml DBus)
0006 find_package (KF5KCMUtils ${KF5_MIN_VERSION} CONFIG REQUIRED)
0007 find_package (KF5Declarative ${KF5_MIN_VERSION} CONFIG REQUIRED)
0008 find_package (KF5XmlGui ${KF5_MIN_VERSION} CONFIG REQUIRED)
0009 find_package (KF5GlobalAccel ${KF5_MIN_VERSION} CONFIG REQUIRED)
0010 find_package (KF5Activities ${KF5_MIN_VERSION} CONFIG REQUIRED)
0011
0012 set (KAMD_KCM_DATADIR
0013    ${KDE_INSTALL_DATADIR_KF5}/kactivitymanagerd/workspace/settings/
0014    )
0015
0016 if (NOT IS_ABSOLUTE "${KDE_INSTALL_DATADIR_KF5}")
0017    set (KAMD_KCM_DATADIR "${CMAKE_INSTALL_PREFIX}/${KAMD_KCM_DATADIR}")
0018 endif ()
0019
0020 configure_file (kactivities-kcm-features.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/kactivities-kcm-features.h)
0021
0022 include_directories(${CMAKE_CURRENT_SOURCE_DIR})
0023
0024 add_subdirectory(imports)
0025
0026 set (KAMD_KCM_SRCS
0027    kcm_activities.cpp
0028
0029    MainConfigurationWidget.cpp
0030    ActivitiesTab.cpp
0031    SwitchingTab.cpp
0032
0033    ExtraActivitiesInterface.cpp
0034    )
0035
0036 ki18n_wrap_ui (
0037    KAMD_KCM_SRCS
0038    ui/MainConfigurationWidgetBase.ui
0039    ui/SwitchingTabBase.ui
0040    )
0041
0042 qt_add_dbus_interface (
0043    KAMD_KCM_SRCS
0044
0045    common/dbus/org.kde.ActivityManager.Features.xml
0046    features_interface
0047    )
0048
0049 qt_add_dbus_interface (
0050    KAMD_KCM_SRCS
0051
0052    common/dbus/org.kde.ActivityManager.ResourceScoring.xml
0053    resourcescoring_interface
0054    )
0055
0056
0057 kcmutils_generate_module_data(
0058     KAMD_KCM_SRCS
0059     MODULE_DATA_HEADER kactivitiesdata.h
0060     MODULE_DATA_CLASS_NAME KActivitiesData
0061     SETTINGS_HEADERS kactivitymanagerd_settings.h kactivitymanagerd_plugins_settings.h
0062     SETTINGS_CLASSES KActivityManagerdSettings KActivityManagerdPluginsSettings
0063 )
0064
0065 kconfig_add_kcfg_files(KAMD_KCM_SRCS kactivitymanagerd_settings.kcfgc GENERATE_MOC)
0066 kconfig_add_kcfg_files(KAMD_KCM_SRCS kactivitymanagerd_plugins_settings.kcfgc GENERATE_MOC)
0067
0068 add_library (kcm_activities MODULE ${KAMD_KCM_SRCS})
0069 kcmutils_generate_desktop_file(kcm_activities)
0070
0071 target_link_libraries (kcm_activities
0072    Qt::Quick
0073    Qt::QuickWidgets
0074    Qt::Core
0075    Qt::Sql
0076    Qt::Qml
0077    Qt::DBus
0078    KF5::KCMUtils
0079    KF5::I18n
0080    KF5::Service
0081    KF5::Declarative
0082    KF5::XmlGui
0083    KF5::GlobalAccel
0084    KF5::Activities
0085    )
0086
0087 install (
0088    TARGETS kcm_activities
0089    DESTINATION ${KDE_INSTALL_PLUGINDIR}/plasma/kcms/systemsettings_qwidgets
0090    )
0091
0092 install (
0093    DIRECTORY
0094
0095    qml/activitiesTab
0096
0097    DESTINATION ${KAMD_KCM_DATADIR}/qml
0098    )
0099
0100 install(FILES kactivitymanagerd_settings.kcfg DESTINATION ${KDE_INSTALL_KCFGDIR})
0101 install(FILES kactivitymanagerd_plugins_settings.kcfg DESTINATION ${KDE_INSTALL_KCFGDIR})