contents/configuration/ShellContainmentConfiguration.qml

0001 /*
0002     SPDX-FileCopyrightText: 2021 Cyril Rossi <cyril.rossi@enioka.com>
0003
0004     SPDX-License-Identifier: LGPL-2.0-or-later
0005 */
0006
0007 import QtQuick 2.15
0008 import QtQuick.Controls 2.4 as QQC2
0009 import QtQuick.Layouts 1.3
0010 import QtQuick.Window 2.15
0011
0012 import org.kde.kirigami 2.13 as Kirigami
0013
0014 import "shellcontainmentconfiguration"
0015
0016 Kirigami.AbstractApplicationWindow {
0017     id: root
0018
0019     title: i18nd("plasma_shell_org.kde.plasma.desktop", "Panels and Desktops Management")
0020
0021     width: Kirigami.Units.gridUnit * 40
0022     height: Kirigami.Units.gridUnit * 32
0023
0024     minimumWidth: Kirigami.Units.gridUnit * 30
0025     minimumHeight: Kirigami.Units.gridUnit * 25
0026
0027     header: QQC2.ToolBar {
0028         anchors {
0029             left: parent.left
0030             right: parent.right
0031         }
0032         contentItem: QQC2.Label {
0033             Layout.fillWidth: parent
0034             text: i18nd("plasma_shell_org.kde.plasma.desktop", "You can drag Panels and Desktops around to move them to different screens.")
0035             textFormat: Text.PlainText
0036             horizontalAlignment: Text.AlignHCenter
0037             wrapMode: Text.WordWrap
0038         }
0039     }
0040
0041     footer: QQC2.Control {
0042         contentItem: QQC2.DialogButtonBox {
0043             QQC2.Button {
0044                 text: i18nd("plasma_shell_org.kde.plasma.desktop", "Close")
0045                 onClicked: Window.window.close()
0046             }
0047         }
0048         background: Item {
0049             // FIXME: automate that somehow?
0050             Kirigami.Separator {
0051                 anchors {
0052                     left: parent.left
0053                     top: parent.top
0054                     right: parent.right
0055                 }
0056                 visible: mainPage.flickable.contentHeight > mainPage.flickable.height
0057             }
0058         }
0059     }
0060
0061     Kirigami.ScrollablePage {
0062         id: mainPage
0063         anchors.fill: parent
0064
0065         leftPadding: 0
0066         topPadding: 0
0067         rightPadding: 0
0068         bottomPadding: 0
0069
0070         Flow {
0071             id: mainGrid
0072             width: mainPage.flickable.width
0073             spacing: 0
0074
0075             Repeater {
0076                 id: repeater
0077                 model: ShellContainmentModel
0078
0079                 delegate: Delegate {
0080                     viewPort: mainPage
0081                 }
0082             }
0083         }
0084     }
0085 }