Warning, /plasma/plasma-bigscreen/components/qml/AbstractDelegate.qml is written in an unsupported language. File is not indexed.

 /*
     SPDX-FileCopyrightText: 2019 Aditya Mehra <aix.m@outlook.com>
     SPDX-FileCopyrightText: 2019 Marco Martin <mart@kde.org>
 
     SPDX-License-Identifier: GPL-2.0-or-later
 */
 
 import QtQuick 2.14
 import QtQuick.Layouts 1.14
 import Qt5Compat.GraphicalEffects
 
 import org.kde.plasma.core 2.0 as PlasmaCore
 import org.kde.plasma.components 3.0 as PlasmaComponents
 import org.kde.kirigami 2.12 as Kirigami
 import org.kde.mycroft.bigscreen 1.0 as BigScreen
 
 PlasmaComponents.ItemDelegate {
     id: delegate
 
     readonly property Flickable listView: {
         var candidate = parent;
         while (candidate) {
             if (candidate instanceof Flickable) {
                 return candidate;
             }
             candidate = candidate.parent;
         }
         return null;
     }
     readonly property bool isCurrent: {//print(text+index+" "+listView.currentIndex+activeFocus+" "+listView.moving)
         listView.currentIndex == index && activeFocus && !listView.moving
     }
 
     highlighted: isCurrent
     property int borderSize: Kirigami.Units.smallSpacing
     property int baseRadius: 3
     
     z: isCurrent ? 2 : 0
 
     onClicked: {
         listView.forceActiveFocus()
         listView.currentIndex = index
     }
 
     leftPadding: Kirigami.Units.largeSpacing * 2
     topPadding: Kirigami.Units.largeSpacing * 2
     rightPadding: Kirigami.Units.largeSpacing * 2
     bottomPadding: Kirigami.Units.largeSpacing * 2
 
     leftInset: Kirigami.Units.largeSpacing
     topInset: Kirigami.Units.largeSpacing
     rightInset: Kirigami.Units.largeSpacing
     bottomInset: Kirigami.Units.largeSpacing
 
 
     Keys.onReturnPressed: {
         clicked();
     }
 
     contentItem: Item {}
 
     background: Item {
         id: background
 
         readonly property Item highlight: Rectangle {
             parent: delegate
             z: 1
             anchors {
                 fill: parent
             }
             color: "transparent"
             border {
                 width: delegate.borderSize
                 color: delegate.Kirigami.Theme.highlightColor
             }
             opacity: delegate.isCurrent || delegate.highlighted
             Behavior on opacity {
                 OpacityAnimator {
                     duration: Kirigami.Units.longDuration/2
                     easing.type: Easing.InOutQuad
                 }
             }
         }
 
         Kirigami.ShadowedRectangle {
             id: frame
             anchors {
                 fill: parent
             }
             radius: delegate.baseRadius
             color: delegate.Kirigami.Theme.backgroundColor
             shadow {
                 size: Kirigami.Units.largeSpacing * 2
             }
 
             states: [
                 State {
                     when: delegate.isCurrent
                     PropertyChanges {
                         target: delegate
                         leftInset: 0
                         rightInset: 0
                         topInset: 0
                         bottomInset: 0
                     }
                     PropertyChanges {
                         target: background.highlight.anchors
                         margins: 0
                     }
                     PropertyChanges {
                         target: frame
                         // baseRadius + borderSize preserves the original radius for the visible part of frame
                         radius: delegate.baseRadius + delegate.borderSize
                     }
                     PropertyChanges {
                         target: background.highlight
                         // baseRadius + borderSize preserves the original radius for the visible part of frame
                         radius: delegate.baseRadius + delegate.borderSize
                     }
                 },
                 State {
                     when: !delegate.isCurrent
                     PropertyChanges {
                         target: delegate
                         leftInset: Kirigami.Units.largeSpacing
                         rightInset: Kirigami.Units.largeSpacing
                         topInset: Kirigami.Units.largeSpacing
                         bottomInset: Kirigami.Units.largeSpacing
                     }
                     PropertyChanges {
                         target: background.highlight.anchors
                         margins: Kirigami.Units.largeSpacing
                     }
                     PropertyChanges {
                         target: frame
                         radius: delegate.baseRadius
                     }
                     PropertyChanges {
                         target: background.highlight
                         radius: delegate.baseRadius
                     }
                 }
             ]
 
             transitions: Transition {
                 ParallelAnimation {
                     NumberAnimation {
                         property: "leftInset"
                         duration: Kirigami.Units.longDuration
                         easing.type: Easing.InOutQuad
                     }
                     NumberAnimation {
                         property: "rightInset"
                         duration: Kirigami.Units.longDuration
                         easing.type: Easing.InOutQuad
                     }
                     NumberAnimation {
                         property: "topInset"
                         duration: Kirigami.Units.longDuration
                         easing.type: Easing.InOutQuad
                     }
                     NumberAnimation {
                         property: "bottomInset"
                         duration: Kirigami.Units.longDuration
                         easing.type: Easing.InOutQuad
                     }
                     NumberAnimation {
                         property: "radius"
                         duration: Kirigami.Units.longDuration
                         easing.type: Easing.InOutQuad
                     }
                     NumberAnimation {
                         property: "margins"
                         duration: Kirigami.Units.longDuration
                         easing.type: Easing.InOutQuad
                     }
                 }
             }
         }
     }
 }