src/lib/CMakeLists.txt

0001 # vim:set softtabstop=3 shiftwidth=3 tabstop=3 expandtab:
0002
0003 # =======================================================
0004 # Now that we finished with the boilerplate, start
0005 # with the library definition
0006
0007 add_library(PlasmaActivities)
0008 add_library(Plasma::Activities ALIAS PlasmaActivities)
0009
0010 set_target_properties(PlasmaActivities PROPERTIES
0011    VERSION     ${PLASMA_ACTIVITIES_VERSION}
0012    SOVERSION   ${PLASMA_ACTIVITIES_SOVERSION}
0013    EXPORT_NAME Activities
0014 )
0015
0016 target_sources(PlasmaActivities PRIVATE
0017    ${PLASMA_ACTIVITIES_CURRENT_ROOT_SOURCE_DIR}/src/common/dbus/org.kde.ActivityManager.Activities.cpp
0018
0019    consumer.cpp
0020    controller.cpp
0021    info.cpp
0022    resourceinstance.cpp
0023    activitiesmodel.cpp
0024
0025    mainthreadexecutor_p.cpp
0026    manager_p.cpp
0027    activitiescache_p.cpp
0028
0029    ${PLASMA_ACTIVITIES_CURRENT_ROOT_SOURCE_DIR}/src/utils/dbusfuture_p.cpp
0030
0031    version.cpp
0032 )
0033
0034 set_source_files_properties (
0035    ${PLASMA_ACTIVITIES_CURRENT_ROOT_SOURCE_DIR}/src/common/dbus/org.kde.ActivityManager.Activities.xml
0036    PROPERTIES
0037    INCLUDE ${PLASMA_ACTIVITIES_CURRENT_ROOT_SOURCE_DIR}/src/common/dbus/org.kde.ActivityManager.Activities.h
0038    )
0039
0040 set(PlasmaActivities_DBus_SRCS)
0041 qt_add_dbus_interface(PlasmaActivities_DBus_SRCS
0042    ${PLASMA_ACTIVITIES_CURRENT_ROOT_SOURCE_DIR}/src/common/dbus/org.kde.ActivityManager.Activities.xml
0043    activities_interface
0044 )
0045 qt_add_dbus_interface(PlasmaActivities_DBus_SRCS
0046    ${PLASMA_ACTIVITIES_CURRENT_ROOT_SOURCE_DIR}/src/common/dbus/org.kde.ActivityManager.Resources.xml
0047    resources_interface
0048 )
0049 qt_add_dbus_interface(PlasmaActivities_DBus_SRCS
0050    ${PLASMA_ACTIVITIES_CURRENT_ROOT_SOURCE_DIR}/src/common/dbus/org.kde.ActivityManager.Features.xml
0051    features_interface
0052 )
0053 qt_add_dbus_interface(PlasmaActivities_DBus_SRCS
0054    ${PLASMA_ACTIVITIES_CURRENT_ROOT_SOURCE_DIR}/src/common/dbus/org.kde.ActivityManager.ResourcesLinking.xml
0055    resources_linking_interface
0056 )
0057 qt_add_dbus_interface(PlasmaActivities_DBus_SRCS
0058    ${PLASMA_ACTIVITIES_CURRENT_ROOT_SOURCE_DIR}/src/common/dbus/org.kde.ActivityManager.Application.xml
0059    application_interface
0060 )
0061 target_sources(PlasmaActivities PRIVATE
0062    ${PlasmaActivities_DBus_SRCS}
0063 )
0064
0065 ecm_qt_declare_logging_category(PlasmaActivities
0066     HEADER debug_p.h
0067     IDENTIFIER KAMD_CORELIB
0068     CATEGORY_NAME kde.plasma.activities
0069     OLD_CATEGORY_NAMES org.kde.kactivities.lib.core
0070     DEFAULT_SEVERITY Warning
0071     DESCRIPTION "Plasma Activities core lib"
0072     EXPORT PLASMA_ACTIVITIES
0073 )
0074
0075 target_link_libraries(PlasmaActivities
0076    PUBLIC
0077       Qt6::Core
0078    PRIVATE
0079       Qt6::DBus
0080 )
0081
0082 set(PLASMA_ACTIVITIES_BUILD_INCLUDE_DIRS
0083    ${PLASMA_ACTIVITIES_CURRENT_ROOT_SOURCE_DIR}/src
0084    ${CMAKE_BINARY_DIR}/
0085 )
0086
0087 target_include_directories(PlasmaActivities
0088    INTERFACE "$<INSTALL_INTERFACE:${KDE_INSTALL_INCLUDEDIR}/PlasmaActivities>"
0089    PRIVATE  ${PLASMA_ACTIVITIES_BUILD_INCLUDE_DIRS}
0090 )
0091
0092 # install
0093 ecm_generate_export_header (PlasmaActivities
0094    BASE_NAME Plasma_Activities
0095    VERSION ${PROJECT_VERSION}
0096    USE_VERSION_HEADER plasma_activities_version.h
0097    DEPRECATED_BASE_VERSION 0
0098 )
0099
0100 ecm_generate_headers (
0101    PlasmaActivities_CamelCase_HEADERS
0102    HEADER_NAMES
0103    Consumer
0104    Controller
0105    Info
0106    ResourceInstance
0107    ActivitiesModel
0108    Version
0109    PREFIX PlasmaActivities
0110    REQUIRED_HEADERS PlasmaActivities_HEADERS
0111    )
0112 install (
0113    FILES ${PlasmaActivities_CamelCase_HEADERS}
0114    DESTINATION ${KDE_INSTALL_INCLUDEDIR}/PlasmaActivities/PlasmaActivities
0115    COMPONENT Devel
0116    )
0117
0118 install (
0119    FILES ${PlasmaActivities_HEADERS} ${CMAKE_CURRENT_BINARY_DIR}/plasma_activities_export.h
0120    DESTINATION ${KDE_INSTALL_INCLUDEDIR}/PlasmaActivities/plasmaactivities
0121    COMPONENT Devel
0122    )
0123
0124 install (
0125    TARGETS PlasmaActivities
0126    EXPORT PlasmaActivitiesLibraryTargets
0127    ${KDE_INSTALL_TARGETS_DEFAULT_ARGS}
0128    )
0129
0130 if(BUILD_QCH)
0131     ecm_add_qch(
0132         PlasmaActivities_QCH
0133         NAME PlasmaActivities
0134         BASE_NAME PlasmaActivities
0135         VERSION ${PROJECT_VERSION}
0136         ORG_DOMAIN org.kde
0137         SOURCES # using only public headers, to cover only public API
0138             ${PlasmaActivities_HEADERS}
0139         MD_MAINPAGE "${CMAKE_SOURCE_DIR}/README.md"
0140         LINK_QCHS
0141             Qt6Core_QCH
0142         INCLUDE_DIRS
0143             ${PLASMA_ACTIVITIES_BUILD_INCLUDE_DIRS}
0144         BLANK_MACROS
0145             PLASMA_ACTIVITIES_EXPORT
0146             PLASMA_ACTIVITIES_DEPRECATED
0147             PLASMA_ACTIVITIES_DEPRECATED_EXPORT
0148         TAGFILE_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0149         QCH_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0150         COMPONENT Devel
0151     )
0152 endif()
0153
0154
0155 if (NOT WIN32)
0156     ecm_generate_pkgconfig_file(BASE_NAME PlasmaActivities
0157       LIB_NAME PlasmaActivities
0158       INCLUDE_INSTALL_DIR ${KDE_INSTALL_INCLUDEDIR}/PlasmaActivities
0159       DEPS Qt6Core
0160       DESCRIPTION "Plasma Activities is a C++ library for using Plasma's activities"
0161       INSTALL
0162     )
0163 endif ()
0164