plasma-activities-stats/src/CMakeLists.txt

0001 # vim:set softtabstop=3 shiftwidth=3 tabstop=3 expandtab:
0002
0003 set (
0004    KActivitiesStats_LIB_SRCS
0005
0006    query.cpp
0007    terms.cpp
0008    resultset.cpp
0009    resultwatcher.cpp
0010    resultmodel.cpp
0011    activitiessync_p.cpp
0012    cleaning.cpp
0013
0014    ${KASTATS_CURRENT_ROOT_SOURCE_DIR}/src/common/database/Database.cpp
0015    ${KASTATS_CURRENT_ROOT_SOURCE_DIR}/src/common/database/schema/ResourcesDatabaseSchema.cpp
0016    ${KASTATS_CURRENT_ROOT_SOURCE_DIR}/src/utils/qsqlquery_iterator.cpp
0017    )
0018
0019 ecm_qt_declare_logging_category(KActivitiesStats_LIB_SRCS
0020     HEADER kactivities-stats-logsettings.h
0021     IDENTIFIER KACTIVITIES_STATS_LOG
0022     CATEGORY_NAME kf.activitiesstats
0023     OLD_CATEGORY_NAMES kf5.kactivity.stat
0024     DESCRIPTION "KActivities Stats"
0025     EXPORT KACTIVITIES_STATS
0026 )
0027
0028
0029 qt_add_dbus_interface (
0030    KActivitiesStats_LIB_SRCS
0031
0032    ${KASTATS_CURRENT_ROOT_SOURCE_DIR}/src/common/dbus/org.kde.ActivityManager.ResourcesScoring.xml
0033    resourcesscoring_interface
0034    )
0035
0036 qt_add_dbus_interface (
0037    KActivitiesStats_LIB_SRCS
0038
0039    ${KASTATS_CURRENT_ROOT_SOURCE_DIR}/src/common/dbus/org.kde.ActivityManager.ResourcesLinking.xml
0040    resourceslinking_interface
0041    )
0042
0043
0044 add_library (
0045    KF5ActivitiesStats SHARED
0046    ${KActivitiesStats_LIB_SRCS}
0047    )
0048 add_library(KF5::ActivitiesStats ALIAS KF5ActivitiesStats)
0049
0050 include_directories (
0051    ${KASTATS_CURRENT_ROOT_SOURCE_DIR}/src
0052    )
0053
0054 set_target_properties (
0055    KF5ActivitiesStats
0056    PROPERTIES
0057    VERSION ${KACTIVITIESSTATS_VERSION}
0058    SOVERSION ${KACTIVITIESSTATS_SOVERSION}
0059    EXPORT_NAME ActivitiesStats
0060    )
0061
0062 target_link_libraries (
0063    KF5ActivitiesStats
0064    PUBLIC
0065       Qt${QT_MAJOR_VERSION}::Core
0066    PRIVATE
0067       Qt${QT_MAJOR_VERSION}::DBus
0068       Qt${QT_MAJOR_VERSION}::Sql
0069       KF5::Activities
0070       KF5::ConfigCore
0071       Threads::Threads
0072    )
0073
0074 target_include_directories (
0075    KF5ActivitiesStats
0076    INTERFACE "$<INSTALL_INTERFACE:${KDE_INSTALL_INCLUDEDIR_KF}/KActivitiesStats>"
0077    )
0078
0079 # install
0080 generate_export_header (KF5ActivitiesStats BASE_NAME KActivitiesStats)
0081
0082 ecm_generate_headers (
0083    KActivitiesStats_CamelCase_HEADERS
0084    HEADER_NAMES
0085    Query
0086    Terms
0087    ResultSet
0088    ResultWatcher
0089    ResultModel
0090    Cleaning
0091
0092    PREFIX KActivitiesStats
0093    REQUIRED_HEADERS KActivitiesStats_HEADERS
0094 )
0095
0096 install (
0097    TARGETS KF5ActivitiesStats
0098    EXPORT KF5ActivitiesStatsLibraryTargets
0099    ${SKIP_NAMELINK}
0100    ${KF_INSTALL_TARGETS_DEFAULT_ARGS}
0101    )
0102
0103 install (
0104    FILES ${KActivitiesStats_CamelCase_HEADERS}
0105    DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/KActivitiesStats/KActivities/Stats
0106    COMPONENT Devel
0107    )
0108
0109 install (
0110    FILES ${KActivitiesStats_HEADERS} ${CMAKE_CURRENT_BINARY_DIR}/kactivitiesstats_export.h
0111    DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/KActivitiesStats/kactivitiesstats
0112    COMPONENT Devel
0113    )
0114
0115 ecm_qt_install_logging_categories(
0116     EXPORT KACTIVITIES_STATS
0117     FILE kactivities-stats.categories
0118     DESTINATION ${KDE_INSTALL_LOGGINGCATEGORIESDIR}
0119 )
0120
0121 if(BUILD_QCH)
0122     ecm_add_qch(
0123         KF5ActivitiesStats_QCH
0124         NAME KActivitiesStats
0125         BASE_NAME KF5ActivitiesStats
0126         VERSION ${KF_VERSION}
0127         ORG_DOMAIN org.kde
0128         SOURCES # using only public headers, to cover only public API
0129             ${KActivitiesStats_HEADERS}
0130         MD_MAINPAGE "${CMAKE_SOURCE_DIR}/README.md"
0131         LINK_QCHS
0132             Qt5Core_QCH
0133             KF5Activities_QCH # while not in API symbols, some classes are referenced in comments
0134         INCLUDE_DIRS
0135             ${CMAKE_CURRENT_BINARY_DIR}
0136         BLANK_MACROS
0137             KACTIVITIESSTATS_EXPORT
0138             KACTIVITIESSTATS_DEPRECATED
0139             KACTIVITIESSTATS_DEPRECATED_EXPORT
0140         TAGFILE_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0141         QCH_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0142         COMPONENT Devel
0143     )
0144 endif()
0145
0146 if (NOT WIN32)
0147     ecm_generate_pkgconfig_file(BASE_NAME libKActivitiesStats
0148       LIB_NAME KF5ActivitiesStats
0149       INCLUDE_INSTALL_DIR ${KDE_INSTALL_INCLUDEDIR_KF}/KActivitiesStats
0150       DEPS Qt${QT_MAJOR_VERSION}Core
0151       DESCRIPTION "libKActivitiesStats is a C++ library for using KDE activities"
0152       INSTALL
0153     )
0154 endif ()
0155
0156 include (ECMGeneratePriFile)
0157 ecm_generate_pri_file (
0158    BASE_NAME KActivitiesStats
0159    LIB_NAME KF5ActivitiesStats
0160    DEPS "KActivities"
0161    FILENAME_VAR PRI_FILENAME INCLUDE_INSTALL_DIR ${KDE_INSTALL_INCLUDEDIR_KF}/KActivitiesStats
0162    )
0163 install (
0164    FILES ${PRI_FILENAME}
0165    DESTINATION ${ECM_MKSPECS_INSTALL_DIR}
0166    )
0167