plasma/plasma-activities-stats/CMakeLists.txt

0001 # vim:set softtabstop=3 shiftwidth=3 tabstop=3 expandtab:
0002 cmake_minimum_required(VERSION 3.16)
0003
0004 set(PROJECT_VERSION "6.0.80")
0005 set(PROJECT_VERSION_MAJOR 6)
0006 project(PlasmaActivitiesStats VERSION ${PROJECT_VERSION})
0007
0008 set(PROJECT_DEP_VERSION "6.0.80")
0009 set(QT_MIN_VERSION "6.6.0")
0010 set(KF6_MIN_VERSION "5.240.0")
0011 set(KDE_COMPILERSETTINGS_LEVEL "5.82")
0012
0013 set(CMAKE_CXX_STANDARD 20)
0014 set(CMAKE_CXX_STANDARD_REQUIRED ON)
0015
0016 find_package(ECM ${KF6_MIN_VERSION} REQUIRED NO_MODULE)
0017 set(CMAKE_MODULE_PATH ${ECM_MODULE_PATH} ${CMAKE_CURRENT_SOURCE_DIR}/cmake/modules)
0018
0019 set(KASTATS_CURRENT_ROOT_SOURCE_DIR ${CMAKE_CURRENT_SOURCE_DIR})
0020
0021 include(FeatureSummary)
0022 include(KDEInstallDirs)
0023 include(KDECMakeSettings)
0024 include(KDEGitCommitHooks)
0025 include(KDECompilerSettings NO_POLICY_SCOPE)
0026 include(ECMGenerateExportHeader)
0027 include(ECMGenerateHeaders)
0028 include(ECMGeneratePkgConfigFile)
0029 include(ECMAddQch)
0030 include(ECMQtDeclareLoggingCategory)
0031 include(ECMDeprecationSettings)
0032
0033 option(BUILD_QCH "Build API documentation in QCH format (for e.g. Qt Assistant, Qt Creator & KDevelop)" OFF)
0034 add_feature_info(QCH ${BUILD_QCH} "API documentation in QCH format (for e.g. Qt Assistant, Qt Creator & KDevelop)")
0035
0036 find_package(Qt6 ${QT_MIN_VERSION} CONFIG REQUIRED COMPONENTS Core DBus Sql)
0037
0038 find_package(KF6Config ${KF6_MIN_VERSION} CONFIG REQUIRED)
0039 find_package(PlasmaActivities ${PROJECT_DEP_VERSION} CONFIG REQUIRED)
0040 find_package(Threads REQUIRED)
0041
0042 include(CMakePackageConfigHelpers)
0043 include(ECMSetupVersion)
0044
0045 set(plasmaactivitiesstats_version_header "${CMAKE_CURRENT_BINARY_DIR}/src/plasmaactivitiesstats_version.h")
0046 ecm_setup_version (
0047    PROJECT
0048    VARIABLE_PREFIX PLASMAACTIVITIESSTATS
0049    VERSION_HEADER ${plasmaactivitiesstats_version_header}
0050    PACKAGE_VERSION_FILE "${CMAKE_CURRENT_BINARY_DIR}/PlasmaActivitiesStatsConfigVersion.cmake"
0051    SOVERSION 1
0052    )
0053 ecm_set_disabled_deprecation_versions(
0054     QT 6.4.0
0055     KF 5.102.0
0056 )
0057
0058 add_subdirectory(src)
0059 if(BUILD_TESTING)
0060   set(Boost_NO_BOOST_CMAKE ON)
0061   find_package(Boost 1.49)
0062   if (Boost_FOUND)
0063     add_subdirectory(autotests)
0064   endif()
0065   add_subdirectory(tests)
0066 endif(BUILD_TESTING)
0067
0068 set (CMAKECONFIG_INSTALL_DIR "${KDE_INSTALL_CMAKEPACKAGEDIR}/PlasmaActivitiesStats")
0069
0070 if(BUILD_QCH)
0071     ecm_install_qch_export(
0072         TARGETS PlasmaActivitiesStats_QCH
0073         FILE PlasmaActivitiesStatsLibraryQchTargets.cmake
0074         DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0075         COMPONENT Devel
0076     )
0077     set(PACKAGE_INCLUDE_QCHTARGETS "include(\"\${CMAKE_CURRENT_LIST_DIR}/PlasmaActivitiesStatsLibraryQchTargets.cmake\")")
0078 endif()
0079
0080 install(
0081    EXPORT PlasmaActivitiesStatsLibraryTargets
0082    DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0083    FILE PlasmaActivitiesStatsLibraryTargets.cmake
0084    NAMESPACE Plasma::
0085    )
0086
0087 configure_package_config_file(
0088    "${CMAKE_CURRENT_SOURCE_DIR}/PlasmaActivitiesStatsConfig.cmake.in"
0089    "${CMAKE_CURRENT_BINARY_DIR}/PlasmaActivitiesStatsConfig.cmake"
0090    INSTALL_DESTINATION  ${CMAKECONFIG_INSTALL_DIR}
0091    )
0092
0093 install(
0094    FILES "${CMAKE_CURRENT_BINARY_DIR}/PlasmaActivitiesStatsConfig.cmake"
0095          "${CMAKE_CURRENT_BINARY_DIR}/PlasmaActivitiesStatsConfigVersion.cmake"
0096    DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0097    COMPONENT Devel
0098    )
0099
0100 install(
0101    FILES ${plasmaactivitiesstats_version_header}
0102    DESTINATION ${KDE_INSTALL_INCLUDEDIR}/PlasmaActivitiesStats COMPONENT Devel
0103    )
0104
0105 # Write out the features
0106 feature_summary(WHAT ALL FATAL_ON_MISSING_REQUIRED_PACKAGES)
0107
0108 kde_configure_git_pre_commit_hook(CHECKS CLANG_FORMAT)