Warning, /plasma/plank-player/app/qml/FileItemDelegate.qml is written in an unsupported language. File is not indexed.

 // SPDX-FileCopyrightText: 2021 Aditya Mehra <aix.m@outlook.com>
 //
 // SPDX-License-Identifier: GPL-2.0-or-later
 
 import QtQuick 2.15
 import QtQuick.Layouts 1.15
 import QtQuick.Controls 2.15
 import org.kde.kirigami 2.19 as Kirigami
 import Qt5Compat.GraphicalEffects
 
 ItemDelegate {
     id: delegate
     property int borderSize: Kirigami.Units.smallSpacing
     property int baseRadius: 3
 
     readonly property Flickable gridView: {
         var candidate = parent;
         while (candidate) {
             if (candidate instanceof Flickable) {
                 return candidate;
             }
             candidate = candidate.parent;
         }
         return null;
     }
 
     readonly property bool isCurrent: {
         gridView.currentIndex == index && activeFocus && !gridView.moving
     }
 
     leftPadding: Kirigami.Units.largeSpacing * 2
     topPadding: Kirigami.Units.largeSpacing * 2
     rightPadding: Kirigami.Units.largeSpacing * 2
     bottomPadding: Kirigami.Units.largeSpacing * 2
 
     leftInset: Kirigami.Units.largeSpacing
     topInset: Kirigami.Units.largeSpacing
     rightInset: Kirigami.Units.largeSpacing
     bottomInset: Kirigami.Units.largeSpacing
 
     implicitWidth: gridView.cellWidth
     height: gridView.cellHeight
 
     background: Item {
         id: background
 
         readonly property Item highlight: Rectangle {
             parent: delegate
             z: 1
             anchors {
                 fill: parent
             }
             color: "transparent"
             border {
                 width: delegate.borderSize
                 color: delegate.Kirigami.Theme.highlightColor
             }
             opacity: delegate.isCurrent || delegate.highlighted
             Behavior on opacity {
                 OpacityAnimator {
                     duration: Kirigami.Units.longDuration/2
                     easing.type: Easing.InOutQuad
                 }
             }
         }
 
         Rectangle {
             id: frame
             anchors {
                 fill: parent
             }
             radius: delegate.baseRadius
             color: delegate.Kirigami.Theme.backgroundColor
             layer.enabled: true
             layer.effect: DropShadow {
                 transparentBorder: false
                 horizontalOffset: 1.25
                 verticalOffset: 1
             }
 
             states: [
                 State {
                     when: delegate.isCurrent
                     PropertyChanges {
                         target: delegate
                         leftInset: 0
                         rightInset: 0
                         topInset: 0
                         bottomInset: 0
                     }
                     PropertyChanges {
                         target: background.highlight.anchors
                         margins: 0
                     }
                     PropertyChanges {
                         target: frame
                         // baseRadius + borderSize preserves the original radius for the visible part of frame
                         radius: delegate.baseRadius + delegate.borderSize
                     }
                     PropertyChanges {
                         target: background.highlight
                         // baseRadius + borderSize preserves the original radius for the visible part of frame
                         radius: delegate.baseRadius + delegate.borderSize
                     }
                 },
                 State {
                     when: !delegate.isCurrent
                     PropertyChanges {
                         target: delegate
                         leftInset: Kirigami.Units.largeSpacing
                         rightInset: Kirigami.Units.largeSpacing
                         topInset: Kirigami.Units.largeSpacing
                         bottomInset: Kirigami.Units.largeSpacing
                     }
                     PropertyChanges {
                         target: background.highlight.anchors
                         margins: Kirigami.Units.largeSpacing
                     }
                     PropertyChanges {
                         target: frame
                         radius: delegate.baseRadius
                     }
                     PropertyChanges {
                         target: background.highlight
                         radius: delegate.baseRadius
                     }
                 }
             ]
 
             transitions: Transition {
                 ParallelAnimation {
                     NumberAnimation {
                         property: "leftInset"
                         duration: Kirigami.Units.longDuration
                         easing.type: Easing.InOutQuad
                     }
                     NumberAnimation {
                         property: "rightInset"
                         duration: Kirigami.Units.longDuration
                         easing.type: Easing.InOutQuad
                     }
                     NumberAnimation {
                         property: "topInset"
                         duration: Kirigami.Units.longDuration
                         easing.type: Easing.InOutQuad
                     }
                     NumberAnimation {
                         property: "bottomInset"
                         duration: Kirigami.Units.longDuration
                         easing.type: Easing.InOutQuad
                     }
                     NumberAnimation {
                         property: "radius"
                         duration: Kirigami.Units.longDuration
                         easing.type: Easing.InOutQuad
                     }
                     NumberAnimation {
                         property: "margins"
                         duration: Kirigami.Units.longDuration
                         easing.type: Easing.InOutQuad
                     }
                 }
             }
         }
     }
 
     contentItem: ColumnLayout {
         spacing: Kirigami.Units.smallSpacing
 
         Item {
             id: imgRoot
             //clip: true
             Layout.alignment: Qt.AlignTop
             Layout.fillWidth: true
             Layout.topMargin: -delegate.topPadding + delegate.topInset + extraBorder
             Layout.leftMargin: -delegate.leftPadding + delegate.leftInset + extraBorder
             Layout.rightMargin: -delegate.rightPadding + delegate.rightInset + extraBorder
             // Any width times 0.5625 is a 16:9 ratio
             // Adding baseRadius is needed to prevent the bottom from being rounded
             Layout.preferredHeight: width * 0.5625 + delegate.baseRadius
             // FIXME: another thing copied from AbstractDelegate
             property real extraBorder: 0
 
             layer.enabled: true
             layer.effect: OpacityMask {
                 cached: true
                 maskSource: Rectangle {
                     x: imgRoot.x;
                     y: imgRoot.y
                     width: imgRoot.width
                     height: imgRoot.height
                     radius: delegate.baseRadius
                 }
             }
 
             Kirigami.Icon {
                 id: img
                 source: "kdenlive-show-videothumb"
                 anchors {
                     fill: parent
                     // To not round under
                     bottomMargin: delegate.baseRadius
                 }
                 opacity: 1
             }
 
             states: [
                 State {
                     when: delegate.isCurrent
                     PropertyChanges {
                         target: imgRoot
                         extraBorder: delegate.borderSize
                     }
                 },
                 State {
                     when: !delegate.isCurrent
                     PropertyChanges {
                         target: imgRoot
                         extraBorder: 0
                     }
                 }
             ]
             transitions: Transition {
                 onRunningChanged: {
                     // Optimize when animating the thumbnail
                     img.smooth = !running
                 }
                 NumberAnimation {
                     property: "extraBorder"
                     duration: Kirigami.Units.longDuration
                     easing.type: Easing.InOutQuad
                 }
             }
         }
 
         ColumnLayout {
             Layout.fillWidth: true
             Layout.fillHeight: true
             // Compensate for blank space created from not rounding thumbnail bottom corners
             Layout.topMargin: -delegate.baseRadius
             Layout.alignment: Qt.AlignLeft | Qt.AlignTop
             spacing: Kirigami.Units.smallSpacing
 
             Kirigami.Heading {
                 id: videoLabel
                 Layout.fillWidth: true
                 Layout.alignment: Qt.AlignLeft | Qt.AlignTop
                 wrapMode: Text.Wrap
                 level: 3
                 maximumLineCount: 1
                 elide: Text.ElideRight
                 color: Kirigami.Theme.textColor
                 Component.onCompleted: {
                     text = fileName + (fileIsDir ? "/" : "")
                 }
             }
         }
     }
 
     Keys.onReturnPressed: (event)=> {
         clicked()
     }
 }