libksysguard/processui/CMakeLists.txt

0001 add_definitions(-DTRANSLATION_DOMAIN=\"processui\")
0002
0003 check_include_files(sys/endian.h HAVE_SYS_ENDIAN_H)
0004 check_include_files(byteswap.h HAVE_BYTESWAP_H)
0005
0006 set(ksysguard_WIDGETS "ksysguard.widgets")
0007
0008 set(processui_LIB_SRCS
0009    ksysguardprocesslist.cpp
0010    ProcessFilter.cpp
0011    ProcessModel.cpp
0012    ReniceDlg.cpp ReniceDlg.h
0013    KTextEditVT.cpp
0014    scripting.cpp scripting.h
0015    processdetails/GeneralTab.cpp processdetails/GeneralTab.h
0016    processdetails/MemoryMapsTab.cpp processdetails/MemoryMapsTab.h
0017    processdetails/OpenFilesTab.cpp processdetails/OpenFilesTab.h
0018    processdetails/ProcessDetailsDialog.cpp processdetails/ProcessDetailsDialog.h
0019 )
0020
0021 ecm_qt_declare_logging_category(processui_LIB_SRCS HEADER processui_debug.h IDENTIFIER LIBKSYSGUARD_PROCESSUI CATEGORY_NAME org.kde.libksysguard.processui
0022     DESCRIPTION "libksysguard (processui)" EXPORT LIBKSYSGUARD)
0023
0024
0025 ki18n_wrap_ui( processui_LIB_SRCS
0026    ReniceDlgUi.ui
0027    ProcessWidgetUI.ui
0028 )
0029
0030 add_library(processui ${processui_LIB_SRCS})
0031 add_library(KSysGuard::ProcessUi ALIAS processui)
0032
0033 if(HAVE_XRES)
0034     target_link_libraries(processui PRIVATE ${X11_XRes_LIB} ${X11_LIBRARIES})
0035     include_directories(${X11_XRes_INCLUDE_PATH})
0036 endif()
0037
0038 generate_export_header(processui)
0039
0040 target_link_libraries(processui
0041     PUBLIC
0042         KSysGuard::ProcessCore
0043         Qt::Widgets
0044         KF6::ConfigCore
0045     PRIVATE
0046         Qt::DBus
0047         KF6::I18n
0048         KF6::WindowSystem
0049         KF6::AuthCore
0050         KF6::ConfigWidgets
0051         KF6::WidgetsAddons
0052         KF6::IconThemes
0053         KF6::JobWidgets
0054         KF6::GlobalAccel
0055         KF6::Service
0056         KF6::KIOGui
0057 )
0058 target_include_directories(processui
0059     PUBLIC
0060         "$<BUILD_INTERFACE:${libksysguard_SOURCE_DIR}>"
0061         "$<INSTALL_INTERFACE:${KDE_INSTALL_INCLUDEDIR}/ksysguard>"
0062 )
0063 if(HAVE_X11)
0064     target_link_libraries(processui PRIVATE Qt6::GuiPrivate KF6::WindowSystem)
0065 endif()
0066
0067 if(WEBENGINE_SCRIPTING_ENABLED)
0068     target_link_libraries(processui PRIVATE Qt::WebEngineWidgets Qt::WebChannel)
0069 endif()
0070
0071 if(NOT HAVE_CLOCK_GETTIME_C)
0072     target_link_libraries(processui PRIVATE rt)
0073 endif()
0074
0075 set_target_properties(processui PROPERTIES
0076    VERSION ${KSYSGUARD_VERSION}
0077    SOVERSION ${KSYSGUARD_SOVERSION}
0078    EXPORT_NAME ProcessUi
0079 )
0080
0081 install(TARGETS processui EXPORT libksysguardLibraryTargets ${KDE_INSTALL_TARGETS_DEFAULT_ARGS} )
0082
0083 install( FILES
0084     ProcessModel.h
0085     ProcessFilter.h
0086     KTextEditVT.h
0087     ksysguardprocesslist.h
0088     ${CMAKE_CURRENT_BINARY_DIR}/processui_export.h
0089     DESTINATION ${KDE_INSTALL_INCLUDEDIR}/ksysguard/processui
0090     COMPONENT Devel
0091 )
0092
0093 if(BUILD_DESIGNERPLUGIN)
0094     add_subdirectory(designer)
0095 endif()