libksysguard/formatter/CMakeLists.txt

0001
0002 set(Formatter_SOVERSION 1)
0003
0004 set(formatter_SRCS
0005     Formatter.cpp
0006     Unit.cpp
0007 )
0008
0009 set(formatter_HDRS
0010     Formatter.h
0011     Unit.h
0012 )
0013
0014 ecm_qt_declare_logging_category(formatter_SRCS
0015     HEADER formatter_debug.h
0016     IDENTIFIER FORMATTER
0017     CATEGORY_NAME org.kde.libksysguard.formatter
0018     DESCRIPTION "libksysguard (formatter)" EXPORT LIBKSYSGUARD
0019 )
0020
0021 add_library(Formatter ${formatter_SRCS} ${formatter_HDRS})
0022 add_library(KSysGuard::Formatter ALIAS Formatter)
0023
0024 target_link_libraries(Formatter
0025     PUBLIC
0026     Qt::Core
0027     Qt::Gui
0028     PRIVATE
0029     KF5::CoreAddons
0030     KF5::I18n
0031 )
0032
0033 generate_export_header(Formatter)
0034
0035 target_include_directories(Formatter
0036     PUBLIC
0037     "$<BUILD_INTERFACE:${libksysguard_SOURCE_DIR}>"
0038     "$<INSTALL_INTERFACE:${KDE_INSTALL_INCLUDEDIR}/ksysguard/>"
0039 )
0040
0041 set_target_properties(Formatter PROPERTIES
0042     LIBRARY_OUTPUT_NAME KSysGuardFormatter
0043     VERSION ${KSYSGUARD_VERSION}
0044     SOVERSION ${Formatter_SOVERSION}
0045 )
0046
0047 target_compile_definitions(Formatter PRIVATE -DTRANSLATION_DOMAIN=\"KSysGuardFormatter\")
0048
0049 add_subdirectory(declarative)
0050
0051 install(TARGETS Formatter EXPORT libksysguardLibraryTargets ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
0052
0053 install(FILES
0054     ${formatter_HDRS}
0055     ${CMAKE_CURRENT_BINARY_DIR}/formatter_export.h
0056     DESTINATION ${KDE_INSTALL_INCLUDEDIR}/ksysguard/formatter
0057 )