libksysguard/faces/FaceDetailsConfig.qml

0001 /*
0002     SPDX-FileCopyrightText: 2019 Marco Martin <mart@kde.org>
0003     SPDX-FileCopyrightText: 2019 David Edmundson <davidedmundson@kde.org>
0004     SPDX-FileCopyrightText: 2019 Arjen Hiemstra <ahiemstra@heimr.nl>
0005
0006     SPDX-License-Identifier: LGPL-2.0-or-later
0007 */
0008
0009 import QtQuick
0010 import QtQuick.Layouts
0011
0012 import org.kde.kirigami as Kirigami
0013 import org.kde.kquickcontrols
0014
0015 import org.kde.ksysguard.sensors as Sensors
0016 import org.kde.ksysguard.faces as Faces
0017
0018 Loader {
0019     id: root
0020
0021     property Faces.SensorFaceController controller
0022
0023     signal configurationChanged
0024
0025     function saveConfig() {
0026         if (item.saveConfig) {
0027             item.saveConfig()
0028         }
0029         for (var key in root.controller.faceConfiguration) {
0030             if (item.hasOwnProperty("cfg_" + key)) {
0031                 root.controller.faceConfiguration[key] = item["cfg_" + key]
0032             }
0033         }
0034     }
0035
0036
0037     onItemChanged: {
0038         if (!item || !root.controller.faceConfiguration) {
0039             return;
0040         }
0041
0042         for (var key in root.controller.faceConfiguration) {
0043             if (!item.hasOwnProperty("cfg_" + key)) {
0044                 continue;
0045             }
0046
0047             item["cfg_" + key] = root.controller.faceConfiguration[key];
0048             var changedSignal = item["cfg_" + key + "Changed"];
0049             if (changedSignal) {
0050                 changedSignal.connect(root.configurationChanged);
0051             }
0052         }
0053     }
0054 }