libksysguard/faces/CMakeLists.txt

0001 set(KSYSGUARD_SENSORS_SOVERSION 2)
0002
0003 add_definitions(-DTRANSLATION_DOMAIN=\"KSysGuardSensorFaces\")
0004
0005 add_subdirectory(import)
0006 add_subdirectory(facepackages)
0007 add_subdirectory(packagestructure)
0008
0009 set(faces_LIB_SRCS
0010     SensorFaceController.cpp
0011     SensorFace.cpp
0012     FaceLoader.cpp
0013     resources.qrc
0014 )
0015
0016 set(faces_LIB_HEADERS
0017     SensorFace_p.h
0018     SensorFaceController.h
0019     FaceLoader.h
0020 )
0021
0022 ecm_qt_declare_logging_category(faces_LIB_SRCS
0023     HEADER faces_logging.h
0024     IDENTIFIER LIBKSYSGUARD_SENSORS
0025     CATEGORY_NAME org.kde.libksysguard.faces
0026     DESCRIPTION "libksysguard (faces)" EXPORT LIBKSYSGUARD)
0027
0028 set_source_files_properties(org.kde.KSysGuardDaemon.xml PROPERTIES INCLUDE SensorInfo_p.h)
0029
0030 add_library(SensorFaces ${faces_LIB_SRCS} ${faces_LIB_HEADERS})
0031 add_library(KSysGuard::SensorFaces ALIAS SensorFaces)
0032
0033 target_include_directories(SensorFaces
0034     PUBLIC
0035     "$<BUILD_INTERFACE:${libksysguard_SOURCE_DIR}>"
0036     "$<INSTALL_INTERFACE:${KDE_INSTALL_INCLUDEDIR}/ksysguard/>"
0037 )
0038
0039 generate_export_header(SensorFaces)
0040
0041 target_link_libraries(SensorFaces
0042     PUBLIC
0043         Qt::Qml
0044         Qt::Quick
0045         KF6::ConfigCore
0046         KF6::ConfigGui
0047         KSysGuard::Formatter
0048         KSysGuard::Sensors
0049     PRIVATE
0050         Qt::Core
0051         Qt::DBus
0052         KF6::I18n
0053         KF6::Package
0054         KF6::ConfigQml
0055         KF6::Solid
0056 )
0057
0058 set_target_properties(SensorFaces PROPERTIES
0059     LIBRARY_OUTPUT_NAME KSysGuardSensorFaces
0060     VERSION ${KSYSGUARD_VERSION}
0061     SOVERSION ${KSYSGUARD_SENSORS_SOVERSION}
0062 )
0063
0064 install(TARGETS SensorFaces EXPORT libksysguardLibraryTargets ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
0065 install(FILES
0066     ${faces_LIB_HEADERS}
0067     ${CMAKE_CURRENT_BINARY_DIR}/sensorfaces_export.h
0068     DESTINATION ${KDE_INSTALL_INCLUDEDIR}/ksysguard/faces
0069     COMPONENT Devel
0070 )
0071
0072 install(FILES systemmonitor-faces.knsrc systemmonitor-presets.knsrc DESTINATION ${KDE_INSTALL_KNSRCDIR})