libkscreen/src/CMakeLists.txt

0001 add_subdirectory(backendlauncher)
0002 add_subdirectory(doctor)
0003 add_subdirectory(libdpms)
0004 set(libkscreen_SRCS
0005     abstractbackend.cpp
0006     backendmanager.cpp
0007     config.cpp
0008     configoperation.cpp
0009     getconfigoperation.cpp
0010     setconfigoperation.cpp
0011     configmonitor.cpp
0012     configserializer.cpp
0013     screen.cpp
0014     output.cpp
0015     edid.cpp
0016     mode.cpp
0017     log.cpp
0018 )
0019
0020 qt_add_dbus_interface(libkscreen_SRCS ${CMAKE_SOURCE_DIR}/interfaces/org.kde.KScreen.Backend.xml backendinterface)
0021
0022 ecm_qt_declare_logging_category(libkscreen_SRCS
0023                                 HEADER kscreen_debug.h
0024                                 IDENTIFIER KSCREEN
0025                                 CATEGORY_NAME org.kde.kscreen
0026 )
0027
0028 ecm_qt_declare_logging_category(libkscreen_SRCS
0029                                 HEADER kscreen_debug_edid.h
0030                                 IDENTIFIER KSCREEN_EDID
0031                                 CATEGORY_NAME org.kde.kscreen.edid
0032 )
0033
0034
0035 add_library(KF5Screen SHARED ${libkscreen_SRCS})
0036 generate_export_header(KF5Screen BASE_NAME KScreen)
0037
0038 ecm_create_qm_loader(KF5Screen libkscreen5_qt)
0039
0040 target_link_libraries(KF5Screen
0041     PUBLIC
0042     Qt::Core
0043     Qt::Gui
0044     PRIVATE
0045     Qt::DBus
0046 )
0047 if (QT_MAJOR_VERSION EQUAL "5")
0048     target_link_libraries(KF5Screen PRIVATE Qt::X11Extras)
0049 else()
0050     target_link_libraries(KF5Screen PRIVATE Qt::GuiPrivate)
0051 endif()
0052
0053 set_target_properties(KF5Screen PROPERTIES
0054     VERSION "${KSCREEN_VERSION}"
0055     SOVERSION "${KSCREEN_SOVERSION}"
0056     EXPORT_NAME Screen
0057 )
0058
0059 target_include_directories(KF5Screen PUBLIC "$<INSTALL_INTERFACE:${KDE_INSTALL_INCLUDEDIR_KF}/KScreen>")
0060
0061 install(TARGETS KF5Screen EXPORT KF5ScreenTargets ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
0062 add_library(KF5::Screen ALIAS KF5Screen)
0063
0064 ecm_generate_headers(KScreen_HEADERS
0065     HEADER_NAMES
0066         Log
0067         Mode
0068         Output
0069         EDID
0070         Screen
0071         Config
0072         ConfigMonitor
0073         ConfigOperation
0074         GetConfigOperation
0075         SetConfigOperation
0076         Types
0077     PREFIX KScreen
0078     REQUIRED_HEADERS KScreen_REQ_HEADERS
0079 )
0080
0081 install(FILES ${KScreen_HEADERS}
0082         DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/KScreen/KScreen
0083         COMPONENT Devel)
0084 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/kscreen_export.h
0085               backendmanager_p.h # needed for unit-tests in KScreen
0086               ${KScreen_REQ_HEADERS}
0087         DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF}/KScreen/kscreen)
0088
0089 if(NOT WIN32)
0090    configure_file(${CMAKE_CURRENT_SOURCE_DIR}/kscreen2.pc.in ${CMAKE_CURRENT_BINARY_DIR}/kscreen2.pc @ONLY)
0091    install(FILES ${CMAKE_CURRENT_BINARY_DIR}/kscreen2.pc DESTINATION ${KDE_INSTALL_LIBDIR}/pkgconfig)
0092 endif(NOT WIN32)
0093
0094 include(ECMGeneratePriFile)
0095 ecm_generate_pri_file(BASE_NAME KScreen LIB_NAME KF5Screen DEPS "core" FILENAME_VAR PRI_FILENAME)
0096 install(FILES ${PRI_FILENAME} DESTINATION ${ECM_MKSPECS_INSTALL_DIR})
0097
0098 if(BUILD_QCH)
0099     ecm_add_qch(
0100         KF5Screen_QCH
0101         NAME KScreen
0102         BASE_NAME KF5Screen
0103         VERSION ${PROJECT_VERSION}
0104         ORG_DOMAIN org.kde
0105         SOURCES # using only public headers, to cover only public API
0106             ${KScreen_REQ_HEADERS}
0107         # MD_MAINPAGE "${CMAKE_SOURCE_DIR}/README.md"
0108         LINK_QCHS
0109             Qt5Core_QCH
0110             Qt5Gui_QCH
0111         BLANK_MACROS
0112             KSCREEN_EXPORT
0113             KSCREEN_DEPRECATED
0114             KSCREEN_DEPRECATED_EXPORT
0115         TAGFILE_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0116         QCH_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0117         COMPONENT Devel
0118     )
0119 endif()