plasma/latte-dock/CMakeLists.txt

0001 project(lattedock)
0002 cmake_minimum_required(VERSION 3.0 FATAL_ERROR)
0003
0004 set(CMAKE_CXX_STANDARD 14)
0005 set(VERSION 0.9.12)
0006 set(AUTHOR "Michail Vourlakos, Smith Ar")
0007 set(EMAIL "mvourlakos@gmail.com, audoban@openmailbox.org")
0008 set(WEBSITE "https://userbase.kde.org/LatteDock")
0009 set(BUG_ADDRESS "https://bugs.kde.org/enter_bug.cgi?product=lattedock")
0010 set(FAQS "https://userbase.kde.org/LatteDock/FAQ")
0011
0012 set(QT_MIN_VERSION "5.9.0")
0013 set(KF5_MIN_VERSION "5.38.0")
0014
0015 set(KF5_LOCALE_PREFIX "")
0016
0017 find_package(ECM ${KF5_MIN_VER} REQUIRED NO_MODULE)
0018 set(CMAKE_MODULE_PATH ${ECM_MODULE_PATH} ${ECM_KDE_MODULE_DIR})
0019
0020 find_package(Qt5 ${QT_MIN_VERSION} CONFIG REQUIRED NO_MODULE COMPONENTS DBus Gui Qml Quick)
0021
0022 find_package(KF5 ${KF5_MIN_VERSION} REQUIRED COMPONENTS
0023     Activities Archive CoreAddons GuiAddons Crash DBusAddons Declarative GlobalAccel I18n
0024     IconThemes NewStuff Notifications Plasma PlasmaQuick Wayland WindowSystem XmlGui)
0025
0026 find_package(X11 REQUIRED)
0027 set_package_properties(X11 PROPERTIES DESCRIPTION "X11 libraries"
0028     URL "http://www.x.org"
0029     TYPE OPTIONAL
0030     PURPOSE "Required for building the X11 based workspace")
0031
0032 if(X11_FOUND)
0033     find_package(XCB MODULE REQUIRED COMPONENTS XCB RANDR EVENT)
0034     set_package_properties(XCB PROPERTIES TYPE REQUIRED)
0035     find_package(Qt5 ${QT_MIN_VERSION} CONFIG REQUIRED COMPONENTS X11Extras)
0036
0037     if(NOT X11_SM_FOUND)
0038         message(FATAL_ERROR "\nThe X11 Session Management (SM) development package could not be found.
0039                 \nPlease install libSM.\n")
0040     endif(NOT X11_SM_FOUND)
0041
0042 endif()
0043
0044 if(X11_FOUND AND XCB_XCB_FOUND)
0045     set(HAVE_X11 ON)
0046 endif()
0047
0048 string(REGEX MATCH "\\.([^]]+)\\." KF5_VERSION_MINOR ${KF5_VERSION})
0049 string(REGEX REPLACE "\\." "" KF5_VERSION_MINOR ${KF5_VERSION_MINOR})
0050
0051 message(STATUS "KF5 VERSION : ${KF5_VERSION}")
0052 message(STATUS "KF5 VERSION MINOR : ${KF5_VERSION_MINOR}")
0053
0054 if(${KF5_VERSION_MINOR} LESS "62")
0055 find_package(KF5 REQUIRED COMPONENTS SysGuard)
0056 endif()
0057
0058 include(ECMQMLModules)
0059 ecm_find_qmlmodule(QtQuick 2.7)
0060 ecm_find_qmlmodule(QtQuick.Layouts 1.3)
0061 ecm_find_qmlmodule(QtQuick.Controls 1.4)
0062 ecm_find_qmlmodule(QtQuick.Controls.Styles.Plasma 2.0)
0063 ecm_find_qmlmodule(QtGraphicalEffects 1.0)
0064 ecm_find_qmlmodule(org.kde.kquickcontrolsaddons 2.0)
0065 ecm_find_qmlmodule(org.kde.plasma.core 2.0)
0066 ecm_find_qmlmodule(org.kde.plasma.components 2.0)
0067
0068 include(CheckIncludeFiles)
0069 include(CMakePackageConfigHelpers)
0070 include(ECMOptionalAddSubdirectory)
0071 include(ECMQtDeclareLoggingCategory)
0072 include(KDECMakeSettings)
0073 include(KDECompilerSettings NO_POLICY_SCOPE)
0074 include(KDEInstallDirs)
0075 include(KDEPackageAppTemplates)
0076 include(WriteBasicConfigVersionFile)
0077
0078 include(Definitions.cmake)
0079
0080 add_subdirectory(declarativeimports)
0081 add_subdirectory(liblatte2)
0082 add_subdirectory(indicators)
0083 add_subdirectory(app)
0084 add_subdirectory(containmentactions)
0085 add_subdirectory(containment)
0086 add_subdirectory(icons)
0087 add_subdirectory(plasmoid)
0088 add_subdirectory(shell)
0089
0090 ki18n_install(po)