src/libkwineffects/CMakeLists.txt

0001 ########### next target ###############
0002 include(ECMSetupVersion)
0003 include(ECMSetupQtPluginMacroNames)
0004
0005 ecm_setup_version(${PROJECT_VERSION}
0006                   VARIABLE_PREFIX KWINEFFECTS
0007                   VERSION_HEADER "${CMAKE_CURRENT_BINARY_DIR}/kwineffects_version.h"
0008                   PACKAGE_VERSION_FILE "${CMAKE_CURRENT_BINARY_DIR}/KWinEffectsConfigVersion.cmake"
0009                   SOVERSION 14
0010 )
0011
0012 ecm_setup_qtplugin_macro_names(
0013     JSON_ARG2
0014         "KWIN_EFFECT_FACTORY"
0015     JSON_ARG3
0016         "KWIN_EFFECT_FACTORY_ENABLED"
0017         "KWIN_EFFECT_FACTORY_SUPPORTED"
0018     JSON_ARG4
0019         "KWIN_EFFECT_FACTORY_SUPPORTED_ENABLED"
0020     CONFIG_CODE_VARIABLE
0021         PACKAGE_SETUP_AUTOMOC_VARIABLES
0022 )
0023
0024 ###  effects lib  ###
0025 set(kwin_EFFECTSLIB_SRCS
0026     anidata.cpp
0027     kwinanimationeffect.cpp
0028     kwineffects.cpp
0029     kwinoffscreeneffect.cpp
0030     kwinoffscreenquickview.cpp
0031     kwinquickeffect.cpp
0032     logging.cpp
0033     sharedqmlengine.cpp
0034 )
0035
0036 add_library(kwineffects SHARED ${kwin_EFFECTSLIB_SRCS})
0037 generate_export_header(kwineffects EXPORT_FILE_NAME kwineffects_export.h)
0038 target_link_libraries(kwineffects
0039     PUBLIC
0040         KF5::ConfigCore
0041         KF5::CoreAddons
0042         KF5::WindowSystem
0043         XCB::XCB
0044     PRIVATE
0045         Qt::Quick
0046         KF5::I18n
0047         kwinglutils
0048 )
0049 if (QT_MAJOR_VERSION EQUAL "6")
0050     target_link_libraries(kwineffects PRIVATE Qt::GuiPrivate)
0051 endif()
0052 set_target_properties(kwineffects PROPERTIES
0053     VERSION ${KWINEFFECTS_VERSION}
0054     SOVERSION ${KWINEFFECTS_SOVERSION}
0055 )
0056
0057 install(TARGETS kwineffects EXPORT KWinEffectsTargets ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
0058
0059 # kwingl(es)utils library
0060 set(kwin_GLUTILSLIB_SRCS
0061     kwinglplatform.cpp
0062     kwingltexture.cpp
0063     kwinglutils.cpp
0064     kwinglutils_funcs.cpp
0065     kwineglimagetexture.cpp
0066     logging.cpp
0067 )
0068
0069 add_library(kwinglutils SHARED ${kwin_GLUTILSLIB_SRCS})
0070 generate_export_header(kwinglutils BASE_NAME kwinglutils EXPORT_FILE_NAME kwinglutils_export.h)
0071 target_link_libraries(kwinglutils PUBLIC XCB::XCB KF5::CoreAddons KF5::ConfigCore KF5::WindowSystem epoxy::epoxy)
0072 set_target_properties(kwinglutils PROPERTIES
0073     VERSION ${KWINEFFECTS_VERSION}
0074     SOVERSION ${KWINEFFECTS_SOVERSION}
0075 )
0076
0077 install(TARGETS kwinglutils EXPORT KWinEffectsTargets ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
0078
0079 install(FILES
0080     ${CMAKE_CURRENT_BINARY_DIR}/kwinconfig.h
0081     ${CMAKE_CURRENT_BINARY_DIR}/kwineffects_export.h
0082     ${CMAKE_CURRENT_BINARY_DIR}/kwinglutils_export.h
0083     kwinanimationeffect.h
0084     kwineffects.h
0085     kwinglobals.h
0086     kwinglplatform.h
0087     kwingltexture.h
0088     kwinglutils.h
0089     kwinglutils_funcs.h
0090     kwinoffscreeneffect.h
0091     kwinoffscreenquickview.h
0092     kwinquickeffect.h
0093     DESTINATION ${KDE_INSTALL_INCLUDEDIR} COMPONENT Devel)
0094
0095 set(CMAKECONFIG_INSTALL_DIR "${KDE_INSTALL_CMAKEPACKAGEDIR}/KWinEffects")
0096
0097
0098 install(FILES  "${CMAKE_CURRENT_BINARY_DIR}/KWinEffectsConfig.cmake"
0099                "${CMAKE_CURRENT_BINARY_DIR}/KWinEffectsConfigVersion.cmake"
0100         DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0101         COMPONENT Devel )
0102
0103 configure_package_config_file(
0104   "${CMAKE_CURRENT_SOURCE_DIR}/KWinEffectsConfig.cmake.in"
0105   "${CMAKE_CURRENT_BINARY_DIR}/KWinEffectsConfig.cmake"
0106   INSTALL_DESTINATION  ${CMAKECONFIG_INSTALL_DIR}
0107 )
0108
0109 install(EXPORT KWinEffectsTargets DESTINATION "${CMAKECONFIG_INSTALL_DIR}" FILE KWinEffectsTargets.cmake NAMESPACE KWinEffects:: )