plasma/kpipewire/CMakeLists.txt

0001 cmake_minimum_required(VERSION 3.16)
0002 project(KPipewire VERSION "6.0.80")
0003
0004 set(KF6_MIN_VERSION "5.240.0")
0005 find_package(ECM ${KF6_MIN_VERSION} REQUIRED NO_MODULE)
0006 set(CMAKE_MODULE_PATH ${ECM_MODULE_PATH} ${CMAKE_SOURCE_DIR}/cmake)
0007 include(KDEInstallDirs)
0008 include(KDECompilerSettings NO_POLICY_SCOPE)
0009 include(KDECMakeSettings)
0010 include(KDEClangFormat)
0011 include(KDEGitCommitHooks)
0012 include(ECMQtDeclareLoggingCategory)
0013
0014 find_package(Qt6 REQUIRED COMPONENTS DBus Quick)
0015 find_package(KF6 REQUIRED COMPONENTS I18n CoreAddons)
0016
0017 find_package(PlasmaWaylandProtocols REQUIRED)
0018 find_package(EGL REQUIRED)
0019
0020 pkg_check_modules(PipeWire IMPORTED_TARGET libpipewire-0.3 REQUIRED)
0021
0022 # ffmpeg, for recording
0023 pkg_check_modules(AVCodec IMPORTED_TARGET libavcodec REQUIRED)
0024 pkg_check_modules(AVUtil IMPORTED_TARGET libavutil REQUIRED)
0025 pkg_check_modules(AVFormat IMPORTED_TARGET libavformat REQUIRED)
0026 pkg_check_modules(AVFilter IMPORTED_TARGET libavfilter REQUIRED)
0027 pkg_check_modules(GBM IMPORTED_TARGET gbm REQUIRED)
0028 pkg_check_modules(SWScale IMPORTED_TARGET libswscale REQUIRED)
0029 find_package(epoxy 1.3 REQUIRED)
0030 find_package(Libdrm 2.4.62 REQUIRED)
0031 pkg_check_modules(LIBVA IMPORTED_TARGET libva REQUIRED)
0032 pkg_check_modules(LIBVA-drm IMPORTED_TARGET libva-drm REQUIRED)
0033
0034 set(CMAKE_CXX_STANDARD 20)
0035 set(CMAKE_CXX_STANDARD_REQUIRED ON)
0036
0037 # add clang-format target for all our real source files
0038 file(GLOB_RECURSE ALL_CLANG_FORMAT_SOURCE_FILES *.cpp *.h)
0039 kde_clang_format(${ALL_CLANG_FORMAT_SOURCE_FILES})
0040 kde_configure_git_pre_commit_hook(CHECKS CLANG_FORMAT)
0041
0042 # Prevent EGL headers from including platform headers, in particular Xlib.h.
0043 add_definitions(-DMESA_EGL_NO_X11_HEADERS)
0044 add_definitions(-DEGL_NO_X11)
0045 add_definitions(-DEGL_NO_PLATFORM_SPECIFIC_TYPES)
0046
0047 if (BUILD_TESTING)
0048    include(ECMAddTests)
0049    find_package(Qt6 REQUIRED COMPONENTS Test QuickTest)
0050    add_subdirectory(tests)
0051 endif()
0052 add_subdirectory(src)
0053
0054 ki18n_install(po)