kinfocenter/cmake/FindUSB1.cmake

0001 # - Try to find libusb-1.0
0002 # Once done this will define
0003 #
0004 #  USB1_FOUND - system has libusb-1.0
0005 #  USB1_INCLUDE_DIRS - the libusb-1.0 include directories
0006 #  USB1_LIBRARIES - Link these to use libusb-1.0
0007 #  USB1_DEFINITIONS - Compiler switches required for using libusb-1.0
0008
0009 #=============================================================================
0010 # SPDX-FileCopyrightText: 2017 Pino Toscano <toscano.pino@tiscali.it>
0011 #
0012 # SPDX-License-Identifier: BSD-3-Clause
0013 #=============================================================================
0014
0015 find_package(PkgConfig)
0016 pkg_check_modules(PC_LIBUSB1 QUIET libusb-1.0)
0017
0018 find_path(USB1_INCLUDE_DIR
0019   NAMES
0020     libusb.h
0021   HINTS
0022     ${PC_LIBUSB1_INCLUDE_DIRS}
0023   PATH_SUFFIXES
0024     libusb-1.0
0025 )
0026
0027 find_library(USB1_LIBRARY
0028   NAMES
0029     ${PC_LIBUSB1_LIBRARIES}
0030     usb-1.0
0031   HINTS
0032     ${PC_LIBUSB1_LIBRARY_DIRS}
0033 )
0034
0035 set(USB1_INCLUDE_DIRS ${USB1_INCLUDE_DIR})
0036 set(USB1_LIBRARIES ${USB1_LIBRARY})
0037
0038 include(FindPackageHandleStandardArgs)
0039 find_package_handle_standard_args(USB1
0040   FOUND_VAR
0041     USB1_FOUND
0042   REQUIRED_VARS
0043     USB1_LIBRARY
0044     USB1_INCLUDE_DIR
0045   VERSION_VAR
0046     PC_LIBUSB1_VERSION
0047 )
0048 if(USB1_FOUND AND NOT TARGET Libusb-1.0)
0049   add_library(Libusb-1.0 SHARED IMPORTED)
0050   set_target_properties(Libusb-1.0 PROPERTIES
0051     IMPORTED_LOCATION "${USB1_LIBRARIES}"
0052     INTERFACE_INCLUDE_DIRECTORIES "${USB1_INCLUDE_DIRS}"
0053   )
0054 endif()
0055
0056 mark_as_advanced(USB1_INCLUDE_DIRS USB1_LIBRARIES)