kglobalacceld/src/CMakeLists.txt

0001 set(kglobalaccelprivate_SRCS
0002     kglobalacceld.cpp
0003     kglobalaccel_interface.cpp
0004     kserviceactioncomponent.cpp
0005     component.cpp
0006     logging.cpp
0007     globalshortcut.cpp
0008     globalshortcutsregistry.cpp
0009     globalshortcutcontext.cpp
0010     sequencehelpers_p.cpp
0011 )
0012
0013 configure_file(config-kglobalaccel.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config-kglobalaccel.h )
0014
0015 add_library(KGlobalAccelD ${kglobalaccelprivate_SRCS})
0016 add_library(K::KGlobalAccelD ALIAS KGlobalAccelD)
0017
0018 ecm_generate_export_header(KGlobalAccelD
0019     EXPORT_FILE_NAME kglobalacceld_export.h
0020     BASE_NAME KGlobalAccelD
0021     VERSION ${PROJECT_VERSION}
0022     USE_VERSION_HEADER
0023     VERSION_BASE_NAME KGlobalAccel
0024     DEPRECATED_BASE_VERSION 0
0025     DEPRECATION_VERSIONS 4.3 5.90
0026     EXCLUDE_DEPRECATED_BEFORE_AND_AT ${EXCLUDE_DEPRECATED_BEFORE_AND_AT}
0027 )
0028
0029 target_include_directories(KGlobalAccelD INTERFACE "$<INSTALL_INTERFACE:${KDE_INSTALL_INCLUDEDIR}/KGlobalAccelD>")
0030
0031 target_link_libraries(KGlobalAccelD
0032     PUBLIC
0033         KF6::GlobalAccel
0034     PRIVATE
0035         Qt6::DBus
0036         KF6::WindowSystem # KKeyServer
0037         KF6::CoreAddons   # KAboutData
0038         KF6::ConfigCore
0039         KF6::Service
0040         KF6::KIOGui
0041         KF6::JobWidgets
0042 )
0043
0044 set_target_properties(KGlobalAccelD PROPERTIES VERSION ${KGLOBALACCELD_VERSION}
0045                                                 SOVERSION ${KGLOBALACCELD_SOVERSION}
0046                                                 EXPORT_NAME "KGlobalAccelD"
0047 )
0048
0049 target_compile_definitions(KGlobalAccelD PRIVATE -DQDBUS=${qdbus_EXECUTABLE})
0050
0051 if(XCB_XCB_FOUND)
0052     target_link_libraries(KGlobalAccelD PUBLIC Qt6::GuiPrivate) # qtx11extras_p.h
0053 endif()
0054
0055 add_executable(kglobalacceld main.cpp logging.cpp)
0056
0057 target_include_directories(kglobalacceld PRIVATE ${CMAKE_BINARY_DIR})
0058
0059 target_link_libraries(kglobalacceld
0060     KGlobalAccelD
0061     KF6::CoreAddons
0062     KF6::DBusAddons   # KDBusService
0063     KF6::Crash
0064     )
0065
0066 add_subdirectory(plugins)
0067
0068 install(TARGETS KGlobalAccelD EXPORT KGlobalAccelDTargets ${KF_INSTALL_TARGETS_DEFAULT_ARGS} LIBRARY NAMELINK_SKIP)
0069 install(TARGETS kglobalacceld DESTINATION ${KDE_INSTALL_LIBEXECDIR})
0070
0071 install(FILES
0072   ${CMAKE_CURRENT_BINARY_DIR}/kglobalacceld_export.h
0073   kglobalacceld.h
0074   kglobalaccel_interface.h
0075   DESTINATION ${KDE_INSTALL_INCLUDEDIR}/KGlobalAccelD/ COMPONENT Devel
0076 )
0077
0078 include (ECMConfiguredInstall)
0079 ecm_install_configured_files(
0080    INPUT plasma-kglobalaccel.service.in
0081    DESTINATION ${KDE_INSTALL_SYSTEMDUSERUNITDIR}
0082 )
0083
0084 ecm_install_configured_files(
0085     INPUT kglobalacceld.desktop.in
0086     DESTINATION ${KDE_INSTALL_AUTOSTARTDIR} @ONLY
0087 )