cmake/modules/FindSass.cmake

0001 #.rst:
0002 # FindSass
0003 # -----------
0004 #
0005 # Try to find Sass compiler.
0006 #
0007 # If the Sass compiler executable is not in your PATH, you can provide
0008 # an alternative name or full path location with the ``Sass_EXECUTABLE`` variable.
0009 # In this case, do not forget to set ``Sass_COMPILER_TYPE`` variable also.
0010 #
0011 # This will define the following variables:
0012 #
0013 # ``Sass_FOUND``
0014 #     True if sass is available.
0015 #
0016 # ``Sass_EXECUTABLE``
0017 #     The Sass compiler executable.
0018 #
0019 # ``Sass_COMPILER_TYPE``
0020 #     Sass compiler type: ``sass`` or ``sassc``.
0021 #
0022 # If ``Sass_FOUND`` is TRUE, it will also define the following imported
0023 # target:
0024 #
0025 # ``Sass::Sass``
0026 #     The Sass compiler executable.
0027 #
0028
0029 #=============================================================================
0030 # SPDX-FileCopyrightText: 2018 Alexander Kernozhitsky <sh200105@mail.ru>
0031 #
0032 # SPDX-License-Identifier: BSD-3-Clause
0033 #=============================================================================
0034
0035 find_program(Sass_EXECUTABLE NAMES sassc)
0036
0037 if(Sass_EXECUTABLE)
0038     if(NOT Sass_COMPILER_TYPE)
0039       set(Sass_COMPILER_TYPE sassc)
0040     endif()
0041 else()
0042     find_program(Sass_EXECUTABLE NAMES sass)
0043     set(Sass_COMPILER_TYPE sass)
0044 endif()
0045
0046 include(FindPackageHandleStandardArgs)
0047
0048 find_package_handle_standard_args(Sass
0049     FOUND_VAR
0050         Sass_FOUND
0051     REQUIRED_VARS
0052         Sass_EXECUTABLE
0053 )
0054 mark_as_advanced(Sass_EXECUTABLE)
0055
0056 if (Sass_FOUND)
0057     if (NOT TARGET Sass::Sass)
0058         add_executable(Sass::Sass IMPORTED)
0059         set_target_properties(Sass::Sass PROPERTIES
0060             IMPORTED_LOCATION "${Sass_EXECUTABLE}"
0061         )
0062     endif()
0063 endif()