plasma/kde-gtk-config/CMakeLists.txt

0001 cmake_minimum_required(VERSION 3.16)
0002
0003 project(kde-gtk-config)
0004 set(PROJECT_VERSION "6.0.80")
0005
0006 set(QT_MIN_VERSION "6.6.0")
0007 set(KF6_MIN_VERSION "5.240.0")
0008 set(KDE_COMPILERSETTINGS_LEVEL "5.82")
0009
0010 set(CMAKE_CXX_STANDARD 20)
0011 set(CMAKE_CXX_STANDARD_REQUIRED ON)
0012
0013 find_package(ECM ${KF6_MIN_VERSION} REQUIRED NO_MODULE)
0014 set(CMAKE_MODULE_PATH "${CMAKE_CURRENT_SOURCE_DIR}/cmake/modules" ${ECM_MODULE_PATH})
0015
0016 include(ECMSetupVersion)
0017 include(ECMInstallIcons)
0018 include(ECMMarkAsTest)
0019 include(GenerateExportHeader)
0020 include(FeatureSummary)
0021 include(KDEInstallDirs)
0022 include(KDECMakeSettings)
0023 include(KDECompilerSettings NO_POLICY_SCOPE)
0024 include(KDEClangFormat)
0025 include(KDEGitCommitHooks)
0026
0027 find_package(Qt6 ${QT_MIN_VERSION} REQUIRED NO_MODULE COMPONENTS DBus Svg)
0028 find_package(KF6 ${KF6_MIN_VERSION} REQUIRED COMPONENTS ColorScheme CoreAddons Config GuiAddons DBusAddons WindowSystem)
0029 find_package(PkgConfig REQUIRED)
0030 find_package(KDecoration2 REQUIRED)
0031 find_package(GSettingSchemas REQUIRED)
0032 find_package(Sass REQUIRED)
0033 find_package(XSettingsd)
0034
0035 pkg_check_modules(GTK+3 REQUIRED IMPORTED_TARGET gtk+-3.0)
0036 pkg_check_modules(GLib2 REQUIRED IMPORTED_TARGET glib-2.0)
0037 pkg_check_modules(GObject REQUIRED IMPORTED_TARGET gobject-2.0)
0038 pkg_check_modules(GIO REQUIRED IMPORTED_TARGET gio-2.0)
0039
0040
0041 set_package_properties(XSettingsd PROPERTIES
0042     DESCRIPTION "XSettingsd daemon"
0043     TYPE RUNTIME
0044     PURPOSE "Required to apply settings to GTK applications on the fly"
0045 )
0046
0047 set_package_properties(Sass PROPERTIES
0048     DESCRIPTION "SASS compiler"
0049     URL "https://sass-lang.com/"
0050     PURPOSE "Required for building a modification, that allows Breeze GTK to change it's window decorations' appearance"
0051 )
0052
0053 configure_file(${CMAKE_CURRENT_SOURCE_DIR}/config.h.cmake kded/config.h)
0054
0055 add_subdirectory(gtk3proxies)
0056 add_subdirectory(kded)
0057 add_subdirectory(kconf_update)
0058 add_subdirectory(color-reload-module)
0059 add_subdirectory(window-decorations-reload-module)
0060
0061 # add clang-format target for all our real source files
0062 file(GLOB_RECURSE ALL_CLANG_FORMAT_SOURCE_FILES *.cpp *.h)
0063 kde_clang_format(${ALL_CLANG_FORMAT_SOURCE_FILES})
0064 kde_configure_git_pre_commit_hook(CHECKS CLANG_FORMAT)
0065
0066 feature_summary(WHAT ALL FATAL_ON_MISSING_REQUIRED_PACKAGES)