src/service/CMakeLists.txt

0001 # vim:set softtabstop=3 shiftwidth=3 tabstop=3 expandtab:
0002
0003 project (ActivityManager)
0004
0005 # General
0006 find_package (ECM 0.0.8 REQUIRED NO_MODULE)
0007 set (CMAKE_MODULE_PATH ${CMAKE_MODULE_PATH} ${ECM_MODULE_PATH})
0008
0009 find_package (Qt${QT_MAJOR_VERSION} REQUIRED NO_MODULE COMPONENTS Sql Gui Widgets)
0010
0011 find_package (KF5Config ${KF5_MIN_VERSION} CONFIG REQUIRED)
0012 find_package (KF5CoreAddons ${KF5_MIN_VERSION} CONFIG REQUIRED)
0013 find_package (KF5I18n ${KF5_MIN_VERSION} CONFIG REQUIRED)
0014 find_package (KF5WindowSystem ${KF5_MIN_VERSION} CONFIG REQUIRED)
0015 find_package (KF5GlobalAccel ${KF5_MIN_VERSION} CONFIG REQUIRED)
0016 find_package (KF5XmlGui ${KF5_MIN_VERSION} CONFIG REQUIRED)
0017 find_package (KF5KIO ${KF5_MIN_VERSION} CONFIG REQUIRED)
0018 find_package (KF5Crash ${KF5_MIN_VERSION} CONFIG REQUIRED)
0019
0020
0021 # Standard stuff
0022
0023 add_library(kactivitymanagerd_plugin SHARED Plugin.cpp Module.cpp Event.cpp ${debug_SRCS})
0024 generate_export_header(kactivitymanagerd_plugin)
0025 target_link_libraries(kactivitymanagerd_plugin PUBLIC Qt::Core Qt::DBus KF5::CoreAddons KF5::ConfigCore)
0026
0027 add_subdirectory (plugins)
0028
0029 set (kactivitymanager_SRCS
0030    Application.cpp
0031    ${KACTIVITIES_CURRENT_ROOT_SOURCE_DIR}/src/common/dbus/org.kde.ActivityManager.Activities.cpp
0032
0033    ${debug_SRCS}
0034    Activities.cpp
0035    Resources.cpp
0036    Features.cpp
0037    Config.cpp
0038
0039    ksmserver/KSMServer.cpp
0040    )
0041
0042 qt_add_dbus_adaptor (
0043    kactivitymanager_SRCS
0044    ../common/dbus/org.kde.ActivityManager.Activities.xml
0045    Activities.h Activities
0046    )
0047
0048 qt_add_dbus_adaptor (
0049    kactivitymanager_SRCS
0050    ../common/dbus/org.kde.ActivityManager.Resources.xml
0051    Resources.h Resources
0052    )
0053
0054 qt_add_dbus_adaptor (
0055    kactivitymanager_SRCS
0056    ../common/dbus/org.kde.ActivityManager.Features.xml
0057    Features.h Features
0058    )
0059
0060 add_executable (kactivitymanagerd ${kactivitymanager_SRCS})
0061
0062 target_link_libraries (kactivitymanagerd
0063    Qt::Core
0064    Qt::DBus
0065    Qt::Gui
0066    Qt::Widgets
0067    KF5::DBusAddons
0068    KF5::CoreAddons
0069    KF5::ConfigCore
0070    KF5::I18n
0071    KF5::WindowSystem
0072    KF5::Crash
0073    kactivitymanagerd_plugin
0074    )
0075
0076 ########### install application ###############
0077
0078 install (FILES
0079    files/kactivitymanagerd.desktop
0080    DESTINATION ${KDE_INSTALL_KSERVICESDIR}
0081    )
0082
0083 install (TARGETS
0084     kactivitymanagerd
0085     DESTINATION ${KDE_INSTALL_LIBEXECDIR}
0086    )
0087
0088 install (TARGETS
0089    kactivitymanagerd_plugin ${KDE_INSTALL_TARGETS_DEFAULT_ARGS}
0090    )