src/tests/CMakeLists.txt

0001 remove_definitions(-DQT_NO_CAST_FROM_ASCII)
0002
0003 find_package(Qt6Test ${REQUIRED_QT_VERSION} CONFIG REQUIRED)
0004
0005 if(NOT CMAKE_SYSTEM_NAME MATCHES FreeBSD)
0006     find_pythonmodule(chai)
0007     set_package_properties("chai-PythonModule" PROPERTIES
0008         DESCRIPTION "Python module chai is required for testing."
0009         TYPE REQUIRED)
0010     add_test(NAME preambletest
0011         COMMAND ${Python3_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/preambletest.py)
0012 endif()
0013
0014 # Test helper for systeminformationtest
0015 if(HAVE_UNAME)
0016     add_executable(lsb_release lsb_release_double.c)
0017
0018     ecm_add_tests(systeminformationtest.cpp LINK_LIBRARIES Qt::Core Qt::Test DrKonqiInternal)
0019 endif()
0020
0021 add_subdirectory(crashtest)
0022 add_subdirectory(backtraceparsertest)
0023 add_subdirectory(bugzillalibtest)
0024 add_subdirectory(sentrytest)
0025
0026 ecm_add_tests(gdbbacktracelinetest.cpp LINK_LIBRARIES Qt::Core Qt::Test drkonqi_backtrace_parser)
0027 ecm_add_tests(
0028         linuxprocmapsparsertest.cpp
0029         statusnotifier_activationclosetimertest.cpp
0030     LINK_LIBRARIES Qt::Core Qt::Test DrKonqiInternal)
0031
0032 if(NOT APPLE)
0033     if(NOT RUBY_EXECTUABLE)
0034         find_program(RUBY_EXECUTABLE ruby)
0035     endif()
0036     if(RUBY_EXECUTABLE)
0037         execute_process(COMMAND ${RUBY_EXECUTABLE} -e "require 'atspi'" RESULT_VARIABLE RUBY_ATSPI)
0038     endif()
0039     if(NOT GDB_EXECUTABLE)
0040         # Needed so drkonqi can actually trace something.
0041         find_program(GDB_EXECUTABLE gdb)
0042     endif()
0043     if(NOT XVFB_RUN_EXECTUABLE)
0044         find_program(XVFB_RUN_EXECTUABLE xvfb-run)
0045     endif()
0046
0047     set(ATSPI_PATHS
0048         /usr/lib/at-spi2-core/ # debians
0049         /usr/libexec/ # newer debians
0050         /usr/lib/at-spi2/ # suses
0051     )
0052     if(NOT ATSPI_BUS_LAUNCHER_EXECUTABLE)
0053         find_program(
0054             ATSPI_BUS_LAUNCHER_EXECUTABLE
0055             NAMES at-spi-bus-launcher
0056             PATHS ${ATSPI_PATHS}
0057             DOC "AT-SPI accessibility dbus launcher"
0058         )
0059     endif()
0060     if(NOT ATSPI_REGISTRYD_EXECUTABLE)
0061         find_program(
0062             ATSPI_REGISTRYD_EXECUTABLE
0063             NAMES at-spi2-registryd
0064             PATHS ${ATSPI_PATHS}
0065             DOC "AT-SPI accessibility registry daemon"
0066         )
0067     endif()
0068
0069     if(
0070         RUBY_EXECUTABLE
0071         AND XVFB_RUN_EXECTUABLE
0072         AND ATSPI_BUS_LAUNCHER_EXECUTABLE
0073         AND ATSPI_REGISTRYD_EXECUTABLE
0074         AND GDB_EXECUTABLE
0075         AND RUBY_ATSPI EQUAL 0
0076     )
0077         set(WITH_DRKONI_INTEGRATION_TESTING TRUE)
0078         add_subdirectory(integration)
0079     endif()
0080     add_feature_info(
0081         DrKonqiIntegrationTesting
0082         WITH_DRKONI_INTEGRATION_TESTING
0083         "Needs Ruby, functional atspi gem, gdb, as well as xvfb-run."
0084     )
0085 endif()