Warning, /plasma/drkonqi/src/CMakeLists.txt is written in an unsupported language. File is not indexed.

0001 add_definitions(-DTRANSLATION_DOMAIN=\"drkonqi5\")
0002 
0003 include(CheckFunctionExists)
0004 
0005 check_function_exists("strsignal" HAVE_STRSIGNAL)
0006 check_function_exists("uname" HAVE_UNAME)
0007 
0008 if(NOT DEBUG_PACKAGE_INSTALLER_NAME)
0009     set(DEBUG_PACKAGE_INSTALLER_NAME "installdbgsymbols.sh")
0010 endif()
0011 
0012 configure_file(config-drkonqi.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config-drkonqi.h)
0013 
0014 add_subdirectory(bugzillaintegration/libbugzilla)
0015 add_subdirectory(data)
0016 add_subdirectory(parser)
0017 if(WIN32)
0018     find_package(KDEWin REQUIRED)
0019     # for finding drkonqi_debug.h
0020     include_directories(${CMAKE_CURRENT_BINARY_DIR})
0021     add_subdirectory(kdbgwin)
0022 endif()
0023 
0024 set(drkonqi_SRCS
0025     drkonqidialog.cpp
0026     statuswidget.cpp
0027     backtraceratingwidget.cpp
0028     backtracewidget.cpp
0029     backtracegenerator.cpp
0030     drkonqi.cpp
0031     drkonqibackends.cpp
0032     detachedprocessmonitor.cpp
0033     debugpackageinstaller.cpp
0034     systeminformation.cpp
0035     crashedapplication.cpp
0036     debugger.cpp
0037     debuggerlaunchers.cpp
0038     ptracer.cpp
0039     debuggermanager.cpp
0040     statusnotifier.cpp
0041     statusnotifier_activationclosetimer.cpp
0042     linuxprocmapsparser.cpp
0043     drkonqi_globals.cpp
0044     qmlextensions/duplicatemodel.cpp
0045     qmlextensions/platformmodel.cpp
0046     qmlextensions/reproducibilitymodel.cpp
0047     qmlextensions/credentialstore.cpp
0048     qmlextensions/commentmodel.cpp
0049     qmlextensions/qobjectlistmodel.cpp
0050     qmlextensions/doctore.cpp
0051 )
0052 
0053 ki18n_wrap_ui(drkonqi_SRCS
0054     ui/maindialog.ui
0055     ui/backtracewidget.ui
0056 )
0057 
0058 # if BACKTRACE_PARSER_DEBUG is enabled, it will show both the
0059 # parsed and the unparsed backtrace in the backtrace widget.
0060 # Comment this out for release.
0061 #add_definitions(-DBACKTRACE_PARSER_DEBUG)
0062 
0063 set(drkonqi_SRCS
0064     ${drkonqi_SRCS}
0065     bugzillaintegration/bugzillalib.cpp
0066     bugzillaintegration/reportinterface.cpp
0067     bugzillaintegration/productmapping.cpp
0068     bugzillaintegration/parsebugbacktraces.cpp
0069     bugzillaintegration/duplicatefinderjob.cpp
0070 )
0071 
0072 ecm_qt_declare_logging_category(
0073     drkonqi_SRCS
0074     HEADER drkonqi_debug.h
0075     IDENTIFIER DRKONQI_LOG
0076     CATEGORY_NAME org.kde.drkonqi
0077     DESCRIPTION "drkonqi"
0078     EXPORT DRKONQI
0079 )
0080 
0081 # transient static lib we can use to link autotests against
0082 add_library(DrKonqiInternal STATIC ${drkonqi_SRCS})
0083 
0084 target_link_libraries(
0085     DrKonqiInternal
0086     KF5::I18n
0087     KF5::CoreAddons
0088     KF5::ConfigGui
0089     KF5::JobWidgets
0090     KF5::KIOCore
0091     KF5::KIOGui
0092     KF5::Crash
0093     KF5::Completion
0094     KF5::WindowSystem
0095     Qt::DBus
0096     Qt::Concurrent
0097     KF5::WidgetsAddons
0098     KF5::Wallet
0099     KF5::Notifications # for status notifier
0100     KF5::IdleTime # hide status notifier only if user saw it
0101     KF5::SyntaxHighlighting # Backtrace Highlighting
0102     drkonqi_backtrace_parser
0103     qbugzilla
0104     KF5::Declarative
0105 )
0106 
0107 if(Systemd_FOUND)
0108     add_subdirectory(coredump)
0109 
0110     target_sources(DrKonqiInternal PRIVATE coredumpbackend.cpp)
0111     target_compile_definitions(DrKonqiInternal PRIVATE SYSTEMD_AVAILABLE)
0112     if(Systemd_VERSION GREATER 247)
0113         add_compile_definitions(COREDUMPD_SUPPORTS_DEBUGGER_ARGUMENTS)
0114     endif()
0115 endif()
0116 
0117 if(WIN32)
0118     target_link_libraries(DrKonqiInternal kdewin)
0119 endif()
0120 
0121 add_executable(drkonqi main.cpp qml/qml.qrc)
0122 ecm_mark_nongui_executable(drkonqi)
0123 target_link_libraries(drkonqi DrKonqiInternal)
0124 
0125 install(TARGETS drkonqi DESTINATION ${KDE_INSTALL_LIBEXECDIR})
0126 configure_file(org.kde.drkonqi.desktop.cmake ${CMAKE_BINARY_DIR}/src/org.kde.drkonqi.desktop)
0127 install(PROGRAMS ${CMAKE_BINARY_DIR}/src/org.kde.drkonqi.desktop DESTINATION ${KDE_INSTALL_APPDIR})
0128 
0129 add_subdirectory(tests)
0130 
0131 add_subdirectory(bugzillaintegration/libbugzilla/autotests)