discover/libdiscover/CMakeLists.txt

0001 add_definitions(-DTRANSLATION_DOMAIN=\"libdiscover\")
0002
0003 configure_file(${CMAKE_CURRENT_SOURCE_DIR}/config-paths.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config-paths.h)
0004
0005 add_subdirectory(backends)
0006 add_subdirectory(notifiers)
0007 add_subdirectory(tests)
0008
0009 if (TARGET AppStreamQt)
0010     add_library(DiscoverAppStreamIntegration STATIC
0011         appstream/AppStreamIntegration.cpp
0012     )
0013     target_link_libraries(DiscoverAppStreamIntegration KF6::CoreAddons KF6::ConfigCore AppStreamQt)
0014     set_property(TARGET DiscoverAppStreamIntegration PROPERTY POSITION_INDEPENDENT_CODE ON)
0015 endif()
0016
0017 set(discovercommon_SRCS
0018     Category/Category.cpp
0019     Category/CategoryModel.cpp
0020     Category/CategoriesReader.cpp
0021     ReviewsBackend/AbstractReviewsBackend.cpp
0022     ReviewsBackend/Rating.cpp
0023     ReviewsBackend/Review.cpp
0024     ReviewsBackend/ReviewsModel.cpp
0025     Transaction/AddonList.cpp
0026     Transaction/Transaction.cpp
0027     Transaction/TransactionListener.cpp
0028     Transaction/TransactionModel.cpp
0029     UpdateModel/UpdateItem.cpp
0030     UpdateModel/UpdateModel.cpp
0031     resources/DiscoverAction.cpp
0032     resources/ResourcesModel.cpp
0033     resources/ResourcesProxyModel.cpp
0034     resources/PackageState.cpp
0035     resources/ResourcesUpdatesModel.cpp
0036     resources/StandardBackendUpdater.cpp
0037     resources/SourcesModel.cpp
0038     resources/AbstractResourcesBackend.cpp
0039     resources/AbstractResource.cpp
0040     resources/AbstractBackendUpdater.cpp
0041     resources/AbstractSourcesBackend.cpp
0042     resources/StoredResultsStream.cpp
0043     DiscoverBackendsFactory.cpp
0044     ScreenshotsModel.cpp
0045     ApplicationAddonsModel.cpp
0046     CachedNetworkAccessManager.cpp
0047 )
0048
0049 ecm_qt_declare_logging_category(discovercommon_SRCS HEADER libdiscover_debug.h IDENTIFIER LIBDISCOVER_LOG CATEGORY_NAME org.kde.plasma.libdiscover DESCRIPTION "libdiscover" EXPORT DISCOVER)
0050
0051
0052 add_library(DiscoverCommon ${discovercommon_SRCS})
0053 if(TARGET AppStreamQt)
0054     target_sources(DiscoverCommon PRIVATE
0055         appstream/OdrsReviewsBackend.cpp
0056         appstream/AppStreamIntegration.cpp
0057         appstream/AppStreamUtils.cpp
0058     )
0059     target_link_libraries(DiscoverCommon PRIVATE Qt::Concurrent AppStreamQt)
0060 endif()
0061
0062 target_link_libraries(DiscoverCommon
0063 PUBLIC
0064     Qt::Core
0065     Qt::Qml
0066     Qt::Gui
0067     KF6::I18n
0068 PRIVATE
0069     KF6::CoreAddons
0070     KF6::ConfigCore
0071     KF6::KIOCore
0072 )
0073 add_library(Discover::Common ALIAS DiscoverCommon)
0074
0075 generate_export_header(DiscoverCommon)
0076
0077 target_include_directories(DiscoverCommon PRIVATE ${PHONON_INCLUDES} PUBLIC ${CMAKE_CURRENT_BINARY_DIR} ${CMAKE_CURRENT_SOURCE_DIR})
0078
0079 install(TARGETS DiscoverCommon DESTINATION ${KDE_INSTALL_LIBDIR}/plasma-discover)
0080 install(FILES resources/discoverabstractnotifier.notifyrc DESTINATION ${KDE_INSTALL_KNOTIFYRCDIR})