Warning, /plasma/breeze-plymouth/CMakeLists.txt is written in an unsupported language. File is not indexed.

0001 project(breeze-plymouth)
0002 set(PROJECT_VERSION "5.27.10")
0003 set(PROJECT_VERSION_MAJOR 5)
0004 
0005 cmake_minimum_required(VERSION 2.8.12 FATAL_ERROR)
0006 
0007 find_package(ECM 1.8.0 REQUIRED NO_MODULE)
0008 set(CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake ${ECM_MODULE_PATH} )
0009 
0010 include(FeatureSummary)
0011 include(KDEClangFormat)
0012 include(KDEGitCommitHooks)
0013 
0014 find_package(Plymouth REQUIRED)
0015 
0016 find_library(MATH_LIBRARY m)
0017 
0018 # Otherwise MODULE libs have a lib prefix, which is not compatible with
0019 # plymouth plugin names (i.e we want breeze-text.so not libbreeze-text.so).
0020 set(CMAKE_SHARED_MODULE_PREFIX "")
0021 
0022 if(NOT DISTRO_NAME AND "${CMAKE_VERSION}" VERSION_GREATER_EQUAL "3.22.0")
0023     cmake_host_system_information(RESULT PRETTY_NAME QUERY DISTRIB_PRETTY_NAME)
0024 endif()
0025 
0026 if(NOT PRETTY_NAME)
0027     set(PRETTY_NAME "Plasma ${PROJECT_VERSION}")
0028 endif()
0029 
0030 set(DISTRO_NAME "${PRETTY_NAME}" CACHE STRING "Name to use on splash screen (defaults to os-release)")
0031 set(DISTRO_VERSION "" CACHE STRING "Version to use on splash screen") # prefer to have the version in the name, makes it easier for os-release data
0032 
0033 add_feature_info(DISTRO_NAME On "name to use on splash screen is '${DISTRO_NAME}'")
0034 add_feature_info(DISTRO_VERSION On "extra version to use on splash screen is '${DISTRO_VERSION}'")
0035 
0036 # Allow to force installation into CMAKE_INSTALL_PREFIX, even if that would
0037 # result in a non-functional installation. This is needed e.g. for the CI
0038 option(INSTALL_BROKEN_PLYMOUTH_DATA "Force installation into CMAKE_INSTALL_PREFIX, will possibly result in a non-functional installation and is only intended for CI/development use!" OFF)
0039 if (INSTALL_BROKEN_PLYMOUTH_DATA)
0040     message(WARNING "Installing Plymouth theme to the wrong location!")
0041     set(PLYMOUTH_THEME_INSTALL_DIR "${CMAKE_INSTALL_PREFIX}/${Plymouth_THEMESDIR}")
0042     set(PLYMOUTH_PLUGIN_INSTALL_DIR "${CMAKE_INSTALL_PREFIX}/${Plymouth_PLUGINSDIR}")
0043 else()
0044     set(PLYMOUTH_THEME_INSTALL_DIR ${Plymouth_THEMESDIR})
0045     set(PLYMOUTH_PLUGIN_INSTALL_DIR ${Plymouth_PLUGINSDIR})
0046 endif()
0047 
0048 add_subdirectory(breeze-text)
0049 add_subdirectory(breeze)
0050 
0051 # add clang-format target for all our real source files
0052 file(GLOB_RECURSE ALL_CLANG_FORMAT_SOURCE_FILES *.cpp *.h *.c)
0053 kde_clang_format(${ALL_CLANG_FORMAT_SOURCE_FILES})
0054 kde_configure_git_pre_commit_hook(CHECKS CLANG_FORMAT)
0055 
0056 feature_summary(WHAT ALL INCLUDE_QUIET_PACKAGES FATAL_ON_MISSING_REQUIRED_PACKAGES)