breeze-gtk/src/CMakeLists.txt

0001 file(GLOB_RECURSE SCSS_SOURCES "*.scss")
0002 file(GLOB CSS_SOURCES "*.css")
0003 file(GLOB_RECURSE GTK2_SOURCES "gtk2/*")
0004
0005 configure_file(build_theme.sh.cmake ${CMAKE_CURRENT_BINARY_DIR}/build_theme.sh @ONLY)
0006
0007 set(SOURCES
0008     ${SCSS_SOURCES}
0009     ${CSS_SOURCES}
0010     ${GTK2_SOURCES}
0011     render_assets.py
0012 )
0013
0014 function(gen_targets THEME_NAME)
0015     set(THEME_DIR "${PROJECT_BINARY_DIR}/${THEME_NAME}")
0016     set(${THEME_NAME}_TARGETS
0017         "${THEME_DIR}/gtk-2.0/gtkrc"
0018         "${THEME_DIR}/gtk-3.0/gtk.css"
0019         PARENT_SCOPE
0020     )
0021 endfunction()
0022
0023 gen_targets(Breeze)
0024 gen_targets(Breeze-Dark)
0025
0026 list(APPEND Breeze_TARGETS
0027     "${PROJECT_BINARY_DIR}/Breeze/gtk-3.0/gtk-dark.css"
0028     "${PROJECT_BINARY_DIR}/Breeze/gtk-4.0/gtk-dark.css"
0029 )
0030
0031 add_custom_command(
0032     OUTPUT ${Breeze-Dark_TARGETS}
0033     DEPENDS ${SOURCES} ${CMAKE_CURRENT_BINARY_DIR}/build_theme.sh
0034     COMMAND ${CMAKE_CURRENT_BINARY_DIR}/build_theme.sh -c BreezeDark -t "${PROJECT_BINARY_DIR}/Breeze-Dark" -r "${BREEZE_COLOR_INSTALL_ROOT}"
0035     WORKING_DIRECTORY "${PROJECT_SOURCE_DIR}/src"
0036 )
0037 add_custom_target(Breeze-Dark ALL DEPENDS ${Breeze-Dark_TARGETS})
0038
0039 add_custom_command(
0040     OUTPUT ${Breeze_TARGETS}
0041     DEPENDS ${SOURCES} ${CMAKE_CURRENT_BINARY_DIR}/build_theme.sh
0042     COMMAND ${CMAKE_CURRENT_BINARY_DIR}/build_theme.sh -c BreezeLight -t "${PROJECT_BINARY_DIR}/Breeze" -r "${BREEZE_COLOR_INSTALL_ROOT}"
0043     COMMAND cp gtk-dark-3.0.css "${PROJECT_BINARY_DIR}/Breeze/gtk-3.0/gtk-dark.css"
0044     COMMAND cp gtk-dark-4.0.css "${PROJECT_BINARY_DIR}/Breeze/gtk-4.0/gtk-dark.css"
0045     WORKING_DIRECTORY "${PROJECT_SOURCE_DIR}/src"
0046 )
0047 add_custom_target(Breeze ALL DEPENDS ${Breeze_TARGETS})
0048
0049 install(DIRECTORY "${PROJECT_BINARY_DIR}/Breeze" DESTINATION "${KDE_INSTALL_FULL_DATAROOTDIR}/themes/")
0050 install(DIRECTORY "${PROJECT_BINARY_DIR}/Breeze-Dark" DESTINATION "${KDE_INSTALL_FULL_DATAROOTDIR}/themes/")
0051 install(FILES settings.ini DESTINATION "${KDE_INSTALL_FULL_DATAROOTDIR}/themes/Breeze")
0052 install(FILES settings.ini DESTINATION "${KDE_INSTALL_FULL_DATAROOTDIR}/themes/Breeze-Dark")