plasma-mobile/plasma-dialer/CMakeLists.txt

0001 # SPDX-FileCopyrightText: 2021 Alexey Andreyev <aa13q@ya.ru>
0002 #
0003 # SPDX-License-Identifier: LicenseRef-KDE-Accepted-GPL
0004
0005 cmake_minimum_required (VERSION 3.16)
0006
0007 set(PROJECT_VERSION "23.01")
0008 project(plasma-dialer-with-subprojects VERSION ${PROJECT_VERSION})
0009
0010 include(FeatureSummary)
0011
0012 set(CMAKE_CXX_STANDARD 20)
0013 set(CMAKE_CXX_STANDARD_REQUIRED ON)
0014
0015 option(DIALER_BUILD_SHELL_OVERLAY "Enable building of Dialer lockscreen functionality" ON)
0016 if (DIALER_BUILD_SHELL_OVERLAY)
0017     add_definitions(-DDIALER_BUILD_SHELL_OVERLAY)
0018 endif() # DIALER_BUILD_SHELL_OVERLAY
0019
0020 # QT_MAJOR_VERSION is defined automatically by QtVersionOption (since ECM 5.82)
0021 # which is included by KDEInstallDirs;
0022 # This variables are updated below if Qt6 is found by ECM
0023 set(QT_REQUIRED_VERSION "5.15.2")
0024 set(KF_MIN_VERSION "5.101.0")
0025 set(KF_MAJOR_VERSION "5")
0026
0027 find_package(ECM ${KF_MIN_VERSION} NO_MODULE)
0028 set_package_properties(ECM PROPERTIES TYPE REQUIRED DESCRIPTION "Extra CMake Modules." URL "https://projects.kde.org/projects/kdesupport/extra-cmake-modules")
0029
0030 # where to look first for cmake modules, before ${CMAKE_ROOT}/Modules/ is checked
0031 set(CMAKE_MODULE_PATH ${CMAKE_MODULE_PATH} ${ECM_MODULE_PATH})
0032
0033 include(KDEInstallDirs)
0034 include(KDECMakeSettings)
0035 include(KDECompilerSettings NO_POLICY_SCOPE)
0036 include(ECMInstallIcons)
0037 include(ECMMarkNonGuiExecutable)
0038 include(ECMConfiguredInstall)
0039 include(ECMFindQmlModule)
0040 include(ECMSetupVersion)
0041 include(KDEClangFormat)
0042 include(KDEGitCommitHooks)
0043 include(ECMCheckOutboundLicense)
0044
0045 if (QT_MAJOR_VERSION STREQUAL "6")
0046     set(REQUIRED_QT_VERSION "6.4")
0047     set(KF_MIN_VERSION "5.240.0")
0048     set(KF_MAJOR_VERSION "6")
0049 endif()
0050
0051 ecm_setup_version(${PROJECT_VERSION}
0052     VARIABLE_PREFIX PLASMADIALER
0053     VERSION_HEADER ${CMAKE_CURRENT_BINARY_DIR}/version.h
0054 )
0055
0056 find_package(KF${KF_MAJOR_VERSION}I18n NO_MODULE)
0057 ki18n_install(po)
0058
0059 #set(DBUS_INTERFACES_PATH "${CMAKE_INSTALL_PREFIX}/${KDE_INSTALL_DBUSINTERFACEDIR}/")
0060
0061 add_subdirectory(kde-telephony-meta)
0062
0063 set(DBUS_INTERFACES_PATH "${CMAKE_INSTALL_PREFIX}/${KDE_INSTALL_DBUSINTERFACEDIR}/")
0064 set(DBUS_INTERFACES_PATH "${SHARED_DBUS_XML_DIR}")
0065 message("Using D-Bus interface descriptions from: ${DBUS_INTERFACES_PATH}")
0066
0067 set(MODEM_SUBSYSTEM "ModemManager" CACHE INTERNAL "")
0068
0069 add_subdirectory(modem-daemon)
0070 add_subdirectory(kde-telephony-daemon)
0071 add_subdirectory(kde-telephony-plugin-declarative)
0072 add_subdirectory(plasma-dialer)
0073
0074 file(GLOB_RECURSE ALL_CLANG_FORMAT_SOURCE_FILES *.cpp *.h)
0075 kde_clang_format(${ALL_CLANG_FORMAT_SOURCE_FILES})
0076 kde_configure_git_pre_commit_hook(CHECKS CLANG_FORMAT)
0077
0078 file(GLOB_RECURSE ALL_SOURCE_FILES *.cpp *.h *.qml)
0079 ecm_check_outbound_license(LICENSES GPL-3.0-only FILES ${ALL_SOURCE_FILES})
0080
0081 feature_summary(WHAT ALL INCLUDE_QUIET_PACKAGES FATAL_ON_MISSING_REQUIRED_PACKAGES)