plasma-mobile/calindori/CMakeLists.txt

0001 # SPDX-FileCopyrightText: 2020 Dimitris Kardarakos <dimkard@posteo.net>
0002 #
0003 # SPDX-License-Identifier: BSD-2-Clause
0004
0005 cmake_minimum_required(VERSION 3.16)
0006
0007 # KDE Applications version, managed by release script.
0008 set(RELEASE_SERVICE_VERSION_MAJOR "24")
0009 set(RELEASE_SERVICE_VERSION_MINOR "04")
0010 set(RELEASE_SERVICE_VERSION_MICRO "70")
0011 set(RELEASE_SERVICE_VERSION "${RELEASE_SERVICE_VERSION_MAJOR}.${RELEASE_SERVICE_VERSION_MINOR}.${RELEASE_SERVICE_VERSION_MICRO}")
0012
0013 project(calindori VERSION ${RELEASE_SERVICE_VERSION})
0014
0015 set(KF_MIN_VERSION "5.95.0")
0016 set(QT_MIN_VERSION "5.15.0")
0017
0018 set(CMAKE_CXX_STANDARD 20)
0019 set(CMAKE_CXX_STANDARD_REQUIRED ON)
0020
0021 find_package(ECM ${KF_MIN_VERSION} REQUIRED NO_MODULE)
0022
0023 set(CMAKE_MODULE_PATH ${ECM_MODULE_PATH})
0024
0025 include(CTest)
0026 include(FeatureSummary)
0027 include(ECMSetupVersion)
0028 include(KDEInstallDirs)
0029 include(KDECMakeSettings)
0030 include(KDECompilerSettings NO_POLICY_SCOPE)
0031 include(KDEClangFormat)
0032 include(KDEGitCommitHooks)
0033 include(ECMPoQmTools)
0034 include(ECMConfiguredInstall)
0035
0036 ecm_setup_version(${PROJECT_VERSION}
0037     VARIABLE_PREFIX CALINDORI
0038     VERSION_HEADER ${CMAKE_CURRENT_BINARY_DIR}/version.h
0039 )
0040
0041 find_package(Qt${QT_MAJOR_VERSION} ${QT_MIN_VERSION} REQUIRED NO_MODULE COMPONENTS
0042     Core
0043     Gui
0044     Qml
0045     Quick
0046     QuickControls2
0047     Svg
0048     Network
0049 )
0050
0051 if (QT_MAJOR_VERSION EQUAL "5")
0052     find_package(Qt5QuickCompiler REQUIRED)
0053 endif()
0054
0055 if (BUILD_TESTING)
0056     find_package(Qt${QT_MAJOR_VERSION} ${QT_MIN_VERSION} REQUIRED NO_MODULE COMPONENTS Test)
0057 endif()
0058
0059 find_package(KF${QT_MAJOR_VERSION} ${KF_MIN_VERSION} REQUIRED COMPONENTS
0060     Config
0061     Kirigami2
0062     I18n
0063     CoreAddons
0064     CalendarCore
0065     Notifications
0066     People
0067 )
0068
0069 if(NOT ANDROID)
0070     find_package(Qt${QT_MAJOR_VERSION} ${QT_MIN_VERSION} REQUIRED COMPONENTS DBus)
0071     find_package(KF${QT_MAJOR_VERSION} ${KF_MIN_VERSION} REQUIRED COMPONENTS DBusAddons)
0072 endif()
0073
0074 add_subdirectory(src)
0075 add_subdirectory(icons)
0076
0077 if(NOT ANDROID)
0078     add_subdirectory(calindac)
0079 endif()
0080
0081 if (IS_DIRECTORY "${CMAKE_CURRENT_SOURCE_DIR}/po")
0082     ki18n_install(po)
0083 endif()
0084
0085 install(FILES org.kde.calindori.appdata.xml DESTINATION ${KDE_INSTALL_METAINFODIR})
0086 install(PROGRAMS org.kde.calindori.desktop DESTINATION ${KDE_INSTALL_APPDIR})
0087
0088 feature_summary(WHAT ALL INCLUDE_QUIET_PACKAGES FATAL_ON_MISSING_REQUIRED_PACKAGES)
0089