Warning, /plasma-bigscreen/soundcloud-voice-application/ui/+mediacenter/delegates/SideAudioCard.qml is written in an unsupported language. File is not indexed.

 import QtQuick 2.9
 import QtQuick.Layouts 1.4
 import QtGraphicalEffects 1.0
 import QtQuick.Controls 2.3
 import org.kde.kirigami 2.8 as Kirigami
 import org.kde.plasma.core 2.0 as PlasmaCore
 import org.kde.plasma.components 3.0 as PlasmaComponents3
 import org.kde.plasma.components 2.0 as PlasmaComponents
 import Mycroft 1.0 as Mycroft
 import org.kde.mycroft.bigscreen 1.0 as BigScreen
 
 BigScreen.AbstractDelegate {
     id: delegate    
     implicitWidth: listView.cellWidth
     height: parent.height
     property bool busyIndicate: false
 
     contentItem: ColumnLayout {
         spacing: Kirigami.Units.smallSpacing
 
         Item {
             id: imgRoot
             Layout.alignment: Qt.AlignTop
             Layout.fillWidth: true
             Layout.topMargin: -delegate.topPadding + delegate.topInset + extraBorder
             Layout.leftMargin: -delegate.leftPadding + delegate.leftInset + extraBorder
             Layout.rightMargin: -delegate.rightPadding + delegate.rightInset + extraBorder
             Layout.preferredHeight: width * 0.5625 + delegate.baseRadius
             property real extraBorder: 0
 
             layer.enabled: true
             layer.effect: OpacityMask {
                 cached: true
                 maskSource: Rectangle {
                     x: imgRoot.x;
                     y: imgRoot.y
                     width: imgRoot.width
                     height: imgRoot.height
                     radius: delegate.baseRadius
                 }
             }
 
             Image {
                 id: img
                 source: modelData.thumbnail
                 anchors {
                     fill: parent
                     // To not round under
                     bottomMargin: delegate.baseRadius
                 }
                 opacity: 1
                 fillMode: Image.PreserveAspectCrop
             }
             
             states: [
                 State {
                     when: delegate.isCurrent
                     PropertyChanges {
                         target: imgRoot
                         extraBorder: delegate.borderSize
                     }
                 },
                 State {
                     when: !delegate.isCurrent
                     PropertyChanges {
                         target: imgRoot
                         extraBorder: 0
                     }
                 }
             ]
             transitions: Transition {
                 onRunningChanged: {
                     // Optimize when animating the thumbnail
                     img.smooth = !running
                 }
                 NumberAnimation {
                     property: "extraBorder"
                     duration: Kirigami.Units.longDuration
                     easing.type: Easing.InOutQuad
                 }
             }
         }
 
         ColumnLayout {
             Layout.fillWidth: true
             Layout.fillHeight: true
             Layout.topMargin: -delegate.baseRadius
             Layout.alignment: Qt.AlignLeft | Qt.AlignTop
             spacing: Kirigami.Units.smallSpacing
 
             Kirigami.Heading {
                 id: videoLabel
                 Layout.fillWidth: true
                 Layout.alignment: Qt.AlignLeft | Qt.AlignTop
                 wrapMode: Text.Wrap
                 level: 3
                 maximumLineCount: 1
                 elide: Text.ElideRight
                 color: PlasmaCore.ColorScope.textColor
                 Component.onCompleted: {
                     text = modelData.title
                 }
             }
         }
     }
 
     onClicked: {
         triggerGuiEvent("aiix.soundcloud-audio-player.playtitle", {playtitle: modelData.title})
     }
 }