templateparser/src/CMakeLists.txt

0001 # SPDX-License-Identifier: CC0-1.0
0002 # SPDX-FileCopyrightText: none
0003
0004 ecm_setup_version(PROJECT VARIABLE_PREFIX TEMPLATEPARSER
0005     VERSION_HEADER "${CMAKE_CURRENT_BINARY_DIR}/templateparser_version.h"
0006     PACKAGE_VERSION_FILE "${CMAKE_CURRENT_BINARY_DIR}/KPim6TemplateParserConfigVersion.cmake"
0007     SOVERSION 6
0008 )
0009
0010 add_definitions(-DTRANSLATION_DOMAIN=\"libtemplateparser6\")
0011 add_library(KPim6TemplateParser)
0012 add_library(KPim6::TemplateParser ALIAS KPim6TemplateParser)
0013
0014
0015 target_sources(KPim6TemplateParser PRIVATE
0016     templateparserjob.cpp
0017     defaulttemplates.cpp
0018     templatesutil.cpp
0019     customtemplates.cpp
0020     customtemplatesmenu.cpp
0021     templatesconfiguration.cpp
0022     templatesinsertcommandpushbutton.cpp
0023     templatescommandmenu.cpp
0024     templatesinsertcommandaction.cpp
0025     templatestextedit.cpp
0026     templatestexteditor.cpp
0027     templateextracttextfrommail.cpp
0028     templatewebenginepage.cpp
0029     templateextracthtmlelementfrommail.cpp
0030     templateparserextracthtmlinfo.cpp
0031     templateparserextracthtmlinforesult.cpp
0032     templateparseremailaddressrequesterbase.cpp
0033     templateparseremailaddressrequesterlineedit.cpp
0034     templateparseremailaddressrequesterinterfacewidget.cpp
0035     templateconvertcommandjob.cpp
0036
0037     templateextracttextfrommail.h
0038     templateparserjob.h
0039     templatestexteditor.h
0040     templateparseremailaddressrequesterbase.h
0041     templateparserextracthtmlinforesult.h
0042     templatescommandmenu.h
0043     templateparserjob_p.h
0044     templatestextedit.h
0045     templateparser_private_export.h
0046     templatesutil_p.h
0047     templatesconfiguration.h
0048     customtemplates.h
0049     templatewebenginepage.h
0050     templatesutil.h
0051     templateparseremailaddressrequesterinterfacewidget.h
0052     templateparserextracthtmlinfo.h
0053     defaulttemplates.h
0054     templatesinsertcommandpushbutton.h
0055     customtemplatesmenu.h
0056     templateconvertcommandjob.h
0057     templatesinsertcommandaction.h
0058     templateextracthtmlelementfrommail.h
0059     templateparseremailaddressrequesterlineedit.h
0060 )
0061 ecm_qt_declare_logging_category(KPim6TemplateParser HEADER templateparser_debug.h IDENTIFIER TEMPLATEPARSER_LOG CATEGORY_NAME org.kde.pim.templateparser
0062     DESCRIPTION "messagelib (templateparser)"
0063     OLD_CATEGORY_NAMES log_templateparser
0064     EXPORT MESSAGELIB
0065 )
0066
0067
0068
0069 kconfig_add_kcfg_files(KPim6TemplateParser settings/templatesconfiguration_kfg.kcfgc)
0070
0071 kconfig_add_kcfg_files(KPim6TemplateParser
0072     settings/customtemplates_kfg.kcfgc
0073     settings/globalsettings_templateparser.kcfgc
0074 )
0075
0076 ki18n_wrap_ui(KPim6TemplateParser
0077     ui/templatesconfiguration_base.ui
0078     ui/customtemplates_base.ui
0079 )
0080
0081 if (COMPILE_WITH_UNITY_CMAKE_SUPPORT)
0082     set_target_properties(KPim6TemplateParser PROPERTIES UNITY_BUILD ON)
0083 endif()
0084
0085 ecm_generate_export_header(KPim6TemplateParser
0086     BASE_NAME templateparser
0087     VERSION ${TEMPLATEPARSER_VERSION}
0088     DEPRECATED_BASE_VERSION 0
0089     USE_VERSION_HEADER
0090 )
0091
0092 target_link_libraries(KPim6TemplateParser
0093     PRIVATE
0094     KPim6::Mime
0095     KPim6::MimeTreeParser
0096     KPim6::IdentityManagementCore
0097     KPim6::MessageCore
0098     KF6::XmlGui
0099     KF6::Completion
0100     KF6::CoreAddons
0101     KF6::I18n
0102     KF6::Codecs
0103     KF6::SonnetUi
0104     KF6::SyntaxHighlighting
0105     Qt::WebEngineWidgets
0106     KPim6::PimTextEdit
0107     Gpgmepp
0108 )
0109
0110 set_target_properties(KPim6TemplateParser PROPERTIES
0111     VERSION ${TEMPLATEPARSER_VERSION}
0112     SOVERSION ${TEMPLATEPARSER_SOVERSION}
0113     EXPORT_NAME TemplateParser
0114 )
0115
0116 target_include_directories(KPim6TemplateParser INTERFACE "$<INSTALL_INTERFACE:${KDE_INSTALL_INCLUDEDIR}/KPim6/TemplateParser/>")
0117
0118 install(FILES
0119     settings/customtemplates_kfg.kcfg
0120     settings/templatesconfiguration_kfg.kcfg
0121     DESTINATION ${KDE_INSTALL_KCFGDIR}
0122 )
0123
0124 ecm_generate_headers(TemplateParser_CamelCase_HEADERS
0125     HEADER_NAMES
0126     CustomTemplates
0127     CustomTemplatesMenu
0128     DefaultTemplates
0129     TemplatesConfiguration
0130     TemplatesTextEdit
0131     TemplatesUtil
0132     TemplatesInsertCommandPushButton
0133     TemplatesCommandMenu
0134     TemplatesInsertCommandAction
0135     TemplateParserJob
0136     TemplateParserExtractHtmlInfoResult
0137     TemplateParserEmailAddressRequesterBase
0138     TemplateConvertCommandJob
0139     REQUIRED_HEADERS TemplateParser_HEADERS
0140     PREFIX TemplateParser
0141 )
0142
0143 install(TARGETS KPim6TemplateParser EXPORT KPim6TemplateParserTargets ${KDE_INSTALL_TARGETS_DEFAULT_ARGS})
0144
0145
0146
0147 install(FILES
0148     ${TemplateParser_CamelCase_HEADERS}
0149     DESTINATION ${KDE_INSTALL_INCLUDEDIR}/KPim6/TemplateParser/TemplateParser
0150     COMPONENT Devel
0151 )
0152
0153 install(FILES
0154     ${TemplateParser_HEADERS}
0155     ${CMAKE_CURRENT_BINARY_DIR}/templateparser_export.h
0156     ${CMAKE_CURRENT_BINARY_DIR}/globalsettings_templateparser.h
0157     ${CMAKE_CURRENT_BINARY_DIR}/customtemplates_kfg.h
0158     ${CMAKE_CURRENT_BINARY_DIR}/ui_templatesconfiguration_base.h
0159     ${CMAKE_CURRENT_BINARY_DIR}/templatesconfiguration_kfg.h
0160     DESTINATION ${KDE_INSTALL_INCLUDEDIR}/KPim6/TemplateParser/templateparser
0161     COMPONENT Devel
0162 )
0163
0164 install(FILES syntax/kmail-template.xml DESTINATION ${KDE_INSTALL_DATADIR}/org.kde.syntax-highlighting/syntax)
0165
0166 set(CMAKECONFIG_INSTALL_DIR "${KDE_INSTALL_CMAKEPACKAGEDIR}/KPim6TemplateParser")
0167
0168
0169 if (BUILD_QCH)
0170     ecm_add_qch(
0171         KPim6TemplateParser_QCH
0172         NAME KPim6TemplateParser
0173         BASE_NAME KPim6TemplateParser
0174         VERSION ${PIM_VERSION}
0175         ORG_DOMAIN org.kde
0176         SOURCES # using only public headers, to cover only public API
0177         ${TemplateParser_HEADERS}
0178         LINK_QCHS
0179         Qt6Core_QCH
0180         Qt6Gui_QCH
0181         Qt6Widgets_QCH
0182         INCLUDE_DIRS
0183         ${CMAKE_CURRENT_BINARY_DIR}
0184         BLANK_MACROS
0185         TEMPLATEPARSER_EXPORT
0186         TAGFILE_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0187         QCH_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0188         COMPONENT Devel
0189     )
0190
0191 ecm_install_qch_export(
0192     TARGETS KPim6TemplateParser_QCH
0193     FILE KPim6TemplateParserQchTargets.cmake
0194     DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0195     COMPONENT Devel
0196 )
0197 set(PACKAGE_INCLUDE_QCHTARGETS "include(\"\${CMAKE_CURRENT_LIST_DIR}/KPim6TemplateParserQchTargets.cmake\")")
0198 endif()
0199
0200
0201 configure_package_config_file(
0202     "${CMAKE_CURRENT_SOURCE_DIR}/KPimTemplateParserConfig.cmake.in"
0203     "${CMAKE_CURRENT_BINARY_DIR}/KPim6TemplateParserConfig.cmake"
0204     INSTALL_DESTINATION  ${CMAKECONFIG_INSTALL_DIR}
0205 )
0206
0207 install(FILES
0208     "${CMAKE_CURRENT_BINARY_DIR}/KPim6TemplateParserConfig.cmake"
0209     "${CMAKE_CURRENT_BINARY_DIR}/KPim6TemplateParserConfigVersion.cmake"
0210     DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0211     COMPONENT Devel
0212 )
0213
0214 install(EXPORT KPim6TemplateParserTargets DESTINATION "${CMAKECONFIG_INSTALL_DIR}" FILE KPim6TemplateParserTargets.cmake NAMESPACE KPim6::)
0215
0216 install(FILES
0217     ${CMAKE_CURRENT_BINARY_DIR}/templateparser_version.h
0218     DESTINATION ${KDE_INSTALL_INCLUDEDIR}/KPim6/TemplateParser COMPONENT Devel
0219 )