mimetreeparser/src/CMakeLists.txt

0001 # SPDX-License-Identifier: CC0-1.0
0002 # SPDX-FileCopyrightText: none
0003 ecm_setup_version(PROJECT VARIABLE_PREFIX MIMETREEPARSER
0004     VERSION_HEADER "${CMAKE_CURRENT_BINARY_DIR}/mimetreeparser_version.h"
0005     PACKAGE_VERSION_FILE "${CMAKE_CURRENT_BINARY_DIR}/KPim6MimeTreeParserConfigVersion.cmake"
0006     SOVERSION 6
0007     )
0008
0009 add_definitions(-DTRANSLATION_DOMAIN=\"libmimetreeparser6\")
0010
0011 # target_include_directories does not handle empty include paths
0012 include_directories(${GPGME_INCLUDES})
0013
0014 add_library(KPim6MimeTreeParser)
0015 add_library(KPim6::MimeTreeParser ALIAS KPim6MimeTreeParser)
0016
0017 target_sources(KPim6MimeTreeParser PRIVATE
0018     bodyformatter/applicationpgpencrypted.cpp
0019     bodyformatter/applicationpkcs7mime.cpp
0020     bodyformatter/encrypted.cpp
0021     bodyformatter/mailman.cpp
0022     bodyformatter/multipartalternative.cpp
0023     bodyformatter/multipartencrypted.cpp
0024     bodyformatter/multipartmixed.cpp
0025     bodyformatter/multipartsigned.cpp
0026     bodyformatter/textplain.cpp
0027     bodyformatter/texthtml.cpp
0028     bodyformatter/utils.cpp
0029     interfaces/bodypartformatter.cpp
0030     interfaces/objecttreesource.cpp
0031     interfaces/bodypart.cpp
0032     job/qgpgmejobexecutor.cpp
0033     utils/util.cpp
0034     bodypartformatter.cpp
0035     bodypartformatterfactory.cpp
0036     cryptohelper.cpp
0037     nodehelper.cpp
0038     objecttreeparser.cpp
0039     messagepart.cpp
0040     partnodebodypart.cpp
0041     simpleobjecttreesource.cpp
0042     memento/compositememento.cpp
0043     memento/cryptobodypartmemento.cpp
0044     memento/decryptverifybodypartmemento.cpp
0045     memento/keycachememento.cpp
0046     memento/verifydetachedbodypartmemento.cpp
0047     memento/verifyopaquebodypartmemento.cpp
0048
0049     temporaryfile/attachmenttemporaryfilesdirs.cpp
0050
0051     job/qgpgmejobexecutor.h
0052     partnodebodypart.h
0053     bodypartformatterfactory.h
0054     utils/util.h
0055     temporaryfile/attachmenttemporaryfilesdirs.h
0056     enums.h
0057     partmetadata.h
0058     cryptohelper.h
0059     bodyformatter/utils.h
0060     bodyformatter/multipartsigned.h
0061     bodyformatter/encrypted.h
0062     bodyformatter/applicationpgpencrypted.h
0063     bodyformatter/texthtml.h
0064     bodyformatter/multipartencrypted.h
0065     bodyformatter/multipartalternative.h
0066     bodyformatter/applicationpkcs7mime.h
0067     bodyformatter/textplain.h
0068     bodyformatter/multipartmixed.h
0069     bodyformatter/mailman.h
0070     memento/compositememento.h
0071     memento/cryptobodypartmemento.h
0072     memento/decryptverifybodypartmemento.h
0073     memento/keycachememento.h
0074     memento/verifydetachedbodypartmemento.h
0075     memento/verifyopaquebodypartmemento.h
0076     interfaces/bodypart.h
0077     interfaces/objecttreesource.h
0078     interfaces/bodypartformatter.h
0079     simpleobjecttreesource.h
0080     messagepart.h
0081     bodypartformatterfactory_p.h
0082     nodehelper.h
0083     objecttreeparser.h
0084     )
0085
0086 ecm_generate_headers(MimeTreeParser_Camelcasemain_HEADERS
0087     HEADER_NAMES
0088     BodyPartFormatterFactory
0089     Enums
0090     MessagePart
0091     NodeHelper
0092     ObjectTreeParser
0093     PartMetaData
0094     PartNodeBodyPart
0095     SimpleObjectTreeSource
0096     REQUIRED_HEADERS MimeTreeParser_main_HEADERS
0097     PREFIX MimeTreeParser
0098     )
0099
0100 ecm_generate_headers(MimeTreeParser_Camelcaseutils_HEADERS
0101     HEADER_NAMES
0102     Util
0103     REQUIRED_HEADERS MimeTreeParser_utils_HEADERS
0104     PREFIX MimeTreeParser
0105     RELATIVE utils
0106     )
0107
0108 ecm_generate_headers(MimeTreeParser_Camelcaseinterfaces_HEADERS
0109     HEADER_NAMES
0110     BodyPartFormatter
0111     BodyPart
0112     ObjectTreeSource
0113     REQUIRED_HEADERS MimeTreeParser_interfaces_HEADERS
0114     PREFIX MimeTreeParser
0115     RELATIVE interfaces
0116     )
0117
0118 ecm_generate_headers(MimeTreeParser_Camelcasetemporaryfile_HEADERS
0119     HEADER_NAMES
0120     AttachmentTemporaryFilesDirs
0121     REQUIRED_HEADERS MimeTreeParser_temporaryfile_HEADERS
0122     PREFIX MimeTreeParser
0123     RELATIVE temporaryfile
0124     )
0125
0126 install(FILES
0127     ${MimeTreeParser_Camelcaseutils_HEADERS}
0128     ${MimeTreeParser_Camelcaseinterfaces_HEADERS}
0129     ${MimeTreeParser_Camelcasemain_HEADERS}
0130     ${MimeTreeParser_Camelcasetemporaryfile_HEADERS}
0131     DESTINATION ${KDE_INSTALL_INCLUDEDIR}/KPim6/MimeTreeParser/MimeTreeParser
0132     COMPONENT Devel
0133     )
0134
0135 install(FILES
0136     ${MimeTreeParser_utils_HEADERS}
0137     ${MimeTreeParser_interfaces_HEADERS}
0138     ${MimeTreeParser_main_HEADERS}
0139     ${MimeTreeParser_temporaryfile_HEADERS}
0140     ${CMAKE_CURRENT_BINARY_DIR}/mimetreeparser_export.h
0141
0142     DESTINATION ${KDE_INSTALL_INCLUDEDIR}/KPim6/MimeTreeParser/mimetreeparser
0143     COMPONENT Devel
0144     )
0145
0146 ecm_qt_declare_logging_category(KPim6MimeTreeParser HEADER mimetreeparser_debug.h IDENTIFIER MIMETREEPARSER_LOG CATEGORY_NAME org.kde.pim.mimetreeparser
0147         DESCRIPTION "messagelib (mimetreeparser)"
0148         OLD_CATEGORY_NAMES log_mimetreeparser
0149         EXPORT MESSAGELIB
0150     )
0151
0152
0153 if (COMPILE_WITH_UNITY_CMAKE_SUPPORT)
0154     set_target_properties(KPim6MimeTreeParser PROPERTIES UNITY_BUILD ON)
0155 endif()
0156
0157 ecm_generate_export_header(KPim6MimeTreeParser
0158     BASE_NAME mimetreeparser
0159     VERSION ${MIMETREEPARSER_VERSION}
0160     DEPRECATED_BASE_VERSION 0
0161     USE_VERSION_HEADER
0162 )
0163
0164
0165 target_link_libraries(KPim6MimeTreeParser
0166     PRIVATE
0167     KF6::Codecs
0168     KF6::I18n
0169     KF6::CoreAddons
0170     KPim6::Libkleo
0171     KPim6::Mime
0172     Qt::Gui
0173     QGpgmeQt6
0174     )
0175
0176 install(TARGETS
0177     KPim6MimeTreeParser
0178     EXPORT KPim6MimeTreeParserTargets ${KDE_INSTALL_TARGETS_DEFAULT_ARGS}
0179     )
0180
0181 set_target_properties(KPim6MimeTreeParser PROPERTIES
0182     VERSION ${MIMETREEPARSER_VERSION}
0183     SOVERSION ${MIMETREEPARSER_SOVERSION}
0184     EXPORT_NAME MimeTreeParser
0185     )
0186
0187 target_include_directories(KPim6MimeTreeParser INTERFACE "$<INSTALL_INTERFACE:${KDE_INSTALL_INCLUDEDIR}/KPim6/MimeTreeParser/>")
0188
0189 set(CMAKECONFIG_INSTALL_DIR "${KDE_INSTALL_CMAKEPACKAGEDIR}/KPim6MimeTreeParser")
0190
0191 if (BUILD_QCH)
0192     ecm_add_qch(
0193         KPim6MimeTreeParser_QCH
0194         NAME KPim6MimeTreeParser
0195         BASE_NAME KPim6MimeTreeParser
0196         VERSION ${PIM_VERSION}
0197         ORG_DOMAIN org.kde
0198         SOURCES # using only public headers, to cover only public API
0199         ${MimeTreeParser_utils_HEADERS}
0200         ${MimeTreeParser_interfaces_HEADERS}
0201         ${MimeTreeParser_main_HEADERS}
0202         ${MimeTreeParser_temporaryfile_HEADERS}
0203         LINK_QCHS
0204             Qt6Core_QCH
0205             Qt6Gui_QCH
0206             Qt6Widgets_QCH
0207         INCLUDE_DIRS
0208             ${CMAKE_CURRENT_BINARY_DIR}
0209         BLANK_MACROS
0210             MIMETREEPARSER_EXPORT
0211         TAGFILE_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0212         QCH_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0213         COMPONENT Devel
0214     )
0215
0216     ecm_install_qch_export(
0217         TARGETS KPim6MimeTreeParser_QCH
0218         FILE KPim6MimeTreeParserQchTargets.cmake
0219         DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0220         COMPONENT Devel
0221     )
0222     set(PACKAGE_INCLUDE_QCHTARGETS "include(\"\${CMAKE_CURRENT_LIST_DIR}/KPim6MimeTreeParserQchTargets.cmake\")")
0223 endif()
0224
0225 configure_package_config_file(
0226     "${CMAKE_CURRENT_SOURCE_DIR}/KPimMimeTreeParserConfig.cmake.in"
0227     "${CMAKE_CURRENT_BINARY_DIR}/KPim6MimeTreeParserConfig.cmake"
0228     INSTALL_DESTINATION  ${CMAKECONFIG_INSTALL_DIR}
0229     )
0230
0231 install(FILES
0232     "${CMAKE_CURRENT_BINARY_DIR}/KPim6MimeTreeParserConfig.cmake"
0233     "${CMAKE_CURRENT_BINARY_DIR}/KPim6MimeTreeParserConfigVersion.cmake"
0234     DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0235     COMPONENT Devel
0236     )
0237
0238 install(EXPORT KPim6MimeTreeParserTargets DESTINATION "${CMAKECONFIG_INSTALL_DIR}" FILE KPim6MimeTreeParserTargets.cmake NAMESPACE KPim6::)
0239
0240 install(FILES
0241     ${CMAKE_CURRENT_BINARY_DIR}/mimetreeparser_version.h
0242     DESTINATION ${KDE_INSTALL_INCLUDEDIR}/KPim6/MimeTreeParser COMPONENT Devel
0243     )