messagecomposer/autotests/CMakeLists.txt

0001 # SPDX-License-Identifier: CC0-1.0
0002 # SPDX-FileCopyrightText: none
0003 set(EXECUTABLE_OUTPUT_PATH ${CMAKE_CURRENT_BINARY_DIR})
0004 add_definitions( -DMESSAGECORE_DATA_DIR="${CMAKE_SOURCE_DIR}/messagecore/autotests/data" )
0005 add_definitions( -DMAIL_DATA_DIR="${CMAKE_CURRENT_SOURCE_DIR}/data" )
0006 add_definitions( -DGNUPGHOME="${CMAKE_BINARY_DIR}/messagecore/autotests/gnupg_home")
0007
0008 include( ${CMAKE_SOURCE_DIR}/cmake/modules/kdepim_add_gpg_crypto_test.cmake )
0009
0010 include_directories(${CMAKE_CURRENT_SOURCE_DIR}/../src/part)
0011
0012 # Convenience macro to add messagecomposer unit tests.
0013 macro( add_messagecomposer_test _source )
0014     get_filename_component( _name ${_source} NAME_WE )
0015     ecm_add_test(${ARGV}
0016         TEST_NAME ${_name}
0017         NAME_PREFIX "messagecomposer-"
0018         LINK_LIBRARIES
0019             KF6::I18n
0020             KPim6::MailTransport
0021             KPim6::Mime
0022             KPim6::MessageComposer
0023             KPim6::MessageCore
0024             KPim6::TemplateParser
0025             KPim6::PimTextEdit
0026             Qt::Test
0027             KPim6::IdentityManagementWidgets
0028             KF6::Contacts
0029             KPim6::AkonadiCore
0030             KF6::XmlGui
0031             KPim6::Libkdepim
0032             KF6::IconThemes
0033             KF6::Completion
0034     )
0035 endmacro()
0036
0037 macro( add_messagecomposer_cryptotest _source )
0038     set( _test cryptofunctions.cpp setupenv.cpp ${_source} )
0039     get_filename_component( _name ${_source} NAME_WE )
0040     add_executable( ${_name} ${_test}  ${_name}.h )
0041     target_link_libraries(
0042         ${_name}
0043         KF6::I18n
0044         KPim6::Mime
0045         KPim6::MessageComposer
0046         KPim6::MessageCore
0047         KPim6::Libkleo
0048         KPim6::Libkdepim
0049         KPim6::PimTextEdit
0050         KPim6::AkonadiCore
0051         Qt::Test
0052         KF6::IconThemes
0053         KF6::Completion
0054         KPim6::MailTransport
0055         KF6::Contacts
0056         KPim6::MimeTreeParser
0057         KF6::Service
0058     )
0059     add_gpg_crypto_test(${_name} messagecomposer-${_name})
0060     set_tests_properties(messagecomposer-${_name} PROPERTIES
0061         ENVIRONMENT "LC_ALL=en_US.UTF-8"
0062     )
0063 endmacro()
0064
0065
0066 # Utility stuff.
0067 add_messagecomposer_test( draftstatustest.cpp )
0068 add_messagecomposer_test( utiltest.cpp )
0069 add_messagecomposer_test( messagefactoryngtest.cpp setupenv.cpp)
0070 add_messagecomposer_test( plugineditorcheckbeforesendparamstest.cpp )
0071 add_messagecomposer_test( replystrategytest.cpp )
0072
0073 # Non-content jobs.
0074 add_messagecomposer_test( skeletonmessagejobtest.cpp )
0075
0076 # Basic content jobs.
0077 add_messagecomposer_test( singlepartjobtest.cpp )
0078 add_messagecomposer_test( multipartjobtest.cpp )
0079
0080 # More complex content jobs.
0081 add_messagecomposer_test( attachmentjobtest.cpp )
0082 add_messagecomposer_test( maintextjobtest.cpp )
0083 add_messagecomposer_test( itipjobtest.cpp )
0084
0085 # Composer.
0086 add_messagecomposer_test( composertest.cpp )
0087 add_messagecomposer_cryptotest( cryptocomposertest.cpp )
0088 add_messagecomposer_test( infoparttest.cpp )
0089 add_messagecomposer_test( textparttest.cpp )
0090 add_messagecomposer_test( globalparttest.cpp )
0091 add_messagecomposer_cryptotest( composerviewbasetest.cpp )
0092
0093 add_messagecomposer_test( recipientseditortest.cpp )
0094
0095 # SendLater
0096 add_messagecomposer_test( sendlaterdialogtest.cpp )
0097 add_messagecomposer_test( sendlaterinfotest.cpp )
0098
0099 # Crypto
0100 add_messagecomposer_cryptotest( autocryptheadersjobtest.cpp )
0101 add_messagecomposer_cryptotest( signjobtest.cpp )
0102 add_messagecomposer_cryptotest( encryptjobtest.cpp )
0103 add_messagecomposer_cryptotest( signencrypttest.cpp )
0104 add_messagecomposer_cryptotest( signandencrypttest.cpp )
0105 add_messagecomposer_cryptotest( autocryptresolvercoretest.cpp )
0106 add_messagecomposer_cryptotest( keyresolvertest.cpp )
0107
0108 set(AKONADI_RUN_POSTGRES_ISOLATED_TESTS FALSE)
0109 set(AKONADI_RUN_MYSQL_ISOLATED_TESTS FALSE)
0110
0111 ecm_add_test(followupreminderselectdatedialogtest.cpp
0112     NAME_PREFIX "messagecomposer-"
0113     LINK_LIBRARIES
0114         KPim6::AkonadiCore
0115         KPim6::AkonadiWidgets
0116         KF6::CalendarCore
0117         KPim6::MessageComposer
0118         Qt::Test
0119 )
0120
0121 ecm_add_test(attachmentvcardfromaddressbookjobtest.cpp
0122     NAME_PREFIX "messagecomposer-"
0123     LINK_LIBRARIES
0124         KF6::Contacts
0125         KPim6::MessageComposer
0126         Qt::Test
0127 )