src/mailimporterakonadi/CMakeLists.txt

0001 ########### CMake Config Files ###########
0002 set(CMAKECONFIG_INSTALL_DIR "${KDE_INSTALL_CMAKEPACKAGEDIR}/KPim6MailImporterAkonadi")
0003
0004 ecm_setup_version(PROJECT VARIABLE_PREFIX MAILIMPORTERAKONADI
0005     VERSION_HEADER "${CMAKE_CURRENT_BINARY_DIR}/mailimporterakonadi_version.h"
0006     PACKAGE_VERSION_FILE "${CMAKE_CURRENT_BINARY_DIR}/KPim6MailImporterAkonadiConfigVersion.cmake"
0007     SOVERSION 6
0008     )
0009
0010 add_library(KPim6MailImporterAkonadi)
0011 add_library(KPim6::MailImporterAkonadi ALIAS KPim6MailImporterAkonadi)
0012
0013
0014 target_sources(KPim6MailImporterAkonadi PRIVATE
0015     filterimporterakonadi.cpp
0016     filterimporterakonadi.h
0017     )
0018
0019 ecm_qt_declare_logging_category(KPim6MailImporterAkonadi HEADER mailimporterakonadi_debug.h IDENTIFIER MAILIMPORTERAKONADI_LOG CATEGORY_NAME org.kde.pim.mailimporterakonadi
0020         DESCRIPTION "mailimporterakonadi (mailimporter)"
0021         EXPORT MAILIMPORTER
0022     )
0023
0024
0025
0026 if (COMPILE_WITH_UNITY_CMAKE_SUPPORT)
0027     set_target_properties(KPim6MailImporterAkonadi PROPERTIES UNITY_BUILD ON)
0028 endif()
0029
0030 ecm_generate_export_header(KPim6MailImporterAkonadi
0031     BASE_NAME mailimporterakonadi
0032     VERSION ${MAILIMPORTERAKONADI_VERSION}
0033     DEPRECATED_BASE_VERSION 0
0034     USE_VERSION_HEADER
0035 )
0036
0037 target_include_directories(KPim6MailImporterAkonadi INTERFACE "$<INSTALL_INTERFACE:${KDE_INSTALL_INCLUDEDIR}/KPim6/MailImporterAkonadi/>")
0038 target_include_directories(KPim6MailImporterAkonadi PUBLIC "$<BUILD_INTERFACE:${MailImporter_SOURCE_DIR}/src;${MailImporter_BINARY_DIR}/src;>")
0039
0040
0041 target_link_libraries(KPim6MailImporterAkonadi
0042     PUBLIC
0043     KPim6::MailImporter
0044     KPim6::AkonadiCore
0045     PRIVATE
0046     KPim6::Mime
0047     KPim6::AkonadiMime
0048     KF6::I18n
0049     )
0050
0051 set_target_properties(KPim6MailImporterAkonadi PROPERTIES
0052         VERSION ${MAILIMPORTERAKONADI_VERSION}
0053         SOVERSION ${MAILIMPORTERAKONADI_SOVERSION}
0054     EXPORT_NAME MailImporterAkonadi
0055     )
0056
0057 install(TARGETS
0058     KPim6MailImporterAkonadi
0059     EXPORT KPim6MailImporterAkonadiTargets ${KDE_INSTALL_TARGETS_DEFAULT_ARGS}
0060     )
0061
0062
0063 ecm_generate_headers(MailImporter_AkonadiCamelCase_HEADERS
0064     HEADER_NAMES
0065     FilterImporterAkonadi
0066     REQUIRED_HEADERS MailImporter_Akonadi_HEADERS
0067     PREFIX MailImporterAkonadi
0068     )
0069
0070
0071 install(FILES
0072     ${MailImporter_AkonadiCamelCase_HEADERS}
0073     DESTINATION ${KDE_INSTALL_INCLUDEDIR}/KPim6/MailImporterAkonadi/MailImporterAkonadi
0074     COMPONENT Devel
0075     )
0076
0077 install(FILES
0078     ${CMAKE_CURRENT_BINARY_DIR}/mailimporterakonadi_export.h
0079     ${MailImporter_Akonadi_HEADERS}
0080     DESTINATION ${KDE_INSTALL_INCLUDEDIR}/KPim6/MailImporterAkonadi/mailimporterakonadi
0081     COMPONENT Devel
0082     )
0083
0084 if (BUILD_TESTING)
0085    add_subdirectory(autotests)
0086 endif()
0087
0088
0089 if (BUILD_QCH)
0090     ecm_add_qch(
0091         KPim6MailImporterAkonadi_QCH
0092         NAME KPim6MailImporterAkonadi
0093         BASE_NAME KPim6MailImporterAkonadi
0094         VERSION ${PIM_VERSION}
0095         ORG_DOMAIN org.kde
0096         SOURCES # using only public headers, to cover only public API
0097             ${MailImporter_Akonadi_HEADERS}
0098         #MD_MAINPAGE "${CMAKE_SOURCE_DIR}/README.md"
0099         #IMAGE_DIRS "${CMAKE_SOURCE_DIR}/docs/pics"
0100         LINK_QCHS
0101             Qt6Core_QCH
0102             Qt6Gui_QCH
0103             Qt6Widgets_QCH
0104         INCLUDE_DIRS
0105             ${CMAKE_CURRENT_BINARY_DIR}
0106         BLANK_MACROS
0107             MAILIMPORTERAKONADI_EXPORT
0108         TAGFILE_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0109         QCH_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0110         COMPONENT Devel
0111     )
0112 endif()
0113
0114
0115 if (BUILD_QCH)
0116     ecm_install_qch_export(
0117         TARGETS KPim6MailImporterAkonadi_QCH
0118         FILE KPim6MailImporterAkonadiQchTargets.cmake
0119         DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0120         COMPONENT Devel
0121     )
0122     set(PACKAGE_INCLUDE_QCHTARGETS "include(\"\${CMAKE_CURRENT_LIST_DIR}/KPim6MailImporterAkonadiQchTargets.cmake\")")
0123 endif()
0124 configure_package_config_file(
0125     "${CMAKE_CURRENT_SOURCE_DIR}/KPimMailImporterAkonadiConfig.cmake.in"
0126     "${CMAKE_CURRENT_BINARY_DIR}/KPim6MailImporterAkonadiConfig.cmake"
0127     INSTALL_DESTINATION  ${CMAKECONFIG_INSTALL_DIR}
0128     )
0129
0130
0131
0132 install(FILES
0133     "${CMAKE_CURRENT_BINARY_DIR}/KPim6MailImporterAkonadiConfig.cmake"
0134     "${CMAKE_CURRENT_BINARY_DIR}/KPim6MailImporterAkonadiConfigVersion.cmake"
0135     DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
0136     COMPONENT Devel
0137     )
0138
0139 install(EXPORT KPim6MailImporterAkonadiTargets DESTINATION "${CMAKECONFIG_INSTALL_DIR}" FILE KPim6MailImporterAkonadiTargets.cmake NAMESPACE KPim6::)
0140
0141 install(FILES
0142     ${CMAKE_CURRENT_BINARY_DIR}/mailimporterakonadi_version.h
0143     DESTINATION ${KDE_INSTALL_INCLUDEDIR}/KPim6/MailImporterAkonadi COMPONENT Devel
0144     )