src/tasks/CMakeLists.txt

0001 add_library(KPim6GAPITasks)
0002 add_library(KPim6::GAPITasks ALIAS KPim6GAPITasks)
0003
0004
0005 target_sources(KPim6GAPITasks PRIVATE
0006     ${libkgapi_debug_SRCS}
0007     task.cpp
0008     taskcreatejob.cpp
0009     taskcreatejob.h
0010     taskdeletejob.cpp
0011     taskdeletejob.h
0012     taskfetchjob.cpp
0013     taskfetchjob.h
0014     task.h
0015     tasklist.cpp
0016     tasklistcreatejob.cpp
0017     tasklistcreatejob.h
0018     tasklistdeletejob.cpp
0019     tasklistdeletejob.h
0020     tasklistfetchjob.cpp
0021     tasklistfetchjob.h
0022     tasklist.h
0023     tasklistmodifyjob.cpp
0024     tasklistmodifyjob.h
0025     taskmodifyjob.cpp
0026     taskmodifyjob.h
0027     taskmovejob.cpp
0028     taskmovejob.h
0029     tasksservice.cpp
0030     tasksservice.h
0031 )
0032
0033 ecm_generate_headers(kgapitasks_CamelCase_HEADERS
0034     HEADER_NAMES
0035     Task
0036     TaskCreateJob
0037     TaskDeleteJob
0038     TaskFetchJob
0039     TaskList
0040     TaskListCreateJob
0041     TaskListDeleteJob
0042     TaskListFetchJob
0043     TaskListModifyJob
0044     TaskModifyJob
0045     TaskMoveJob
0046     PREFIX KGAPI/Tasks
0047     REQUIRED_HEADERS kgapitasks_HEADERS
0048 )
0049
0050
0051 if (COMPILE_WITH_UNITY_CMAKE_SUPPORT)
0052     set_target_properties(KPim6GAPITasks PROPERTIES UNITY_BUILD ON)
0053 endif()
0054
0055 generate_export_header(KPim6GAPITasks BASE_NAME kgapitasks)
0056
0057 target_include_directories(KPim6GAPITasks
0058     INTERFACE "$<INSTALL_INTERFACE:${KDE_INSTALL_INCLUDEDIR}/KPim6/KGAPI>"
0059     INTERFACE "$<BUILD_INTERFACE:${CMAKE_SOURCE_DIR}/src>"
0060 )
0061
0062 target_link_libraries(KPim6GAPITasks
0063 PUBLIC
0064     KPim6::GAPICore
0065     KF6::CalendarCore
0066 PRIVATE
0067     Qt::Network
0068 )
0069
0070 set_target_properties(KPim6GAPITasks PROPERTIES
0071     VERSION ${KGAPI_VERSION}
0072     SOVERSION ${KGAPI_SOVERSION}
0073     EXPORT_NAME GAPITasks
0074 )
0075
0076 install(TARGETS
0077     KPim6GAPITasks
0078     EXPORT KPim6GAPITargets ${KDE_INSTALL_TARGETS_DEFAULT_ARGS}
0079 )
0080
0081 install(FILES
0082     ${kgapitasks_CamelCase_HEADERS}
0083     DESTINATION "${KDE_INSTALL_INCLUDEDIR}/KPim6/KGAPI/KGAPI/Tasks"
0084     COMPONENT Devel
0085 )
0086
0087 install(FILES
0088     ${kgapitasks_HEADERS}
0089     "${CMAKE_CURRENT_BINARY_DIR}/kgapitasks_export.h"
0090     DESTINATION "${KDE_INSTALL_INCLUDEDIR}/KPim6/KGAPI/kgapi/tasks"
0091     COMPONENT Devel
0092 )
0093
0094 if (BUILD_QCH)
0095     ecm_add_qch(
0096         KPim6GAPITasks_QCH
0097         NAME KPim6GAPITasks
0098         BASE_NAME KPim6GAPITasks
0099         VERSION ${PIM_VERSION}
0100         ORG_DOMAIN org.kde
0101         SOURCES # using only public headers, to cover only public API
0102         ${kgapitasks_HEADERS}
0103         #MD_MAINPAGE "${CMAKE_SOURCE_DIR}/README.md"
0104         #IMAGE_DIRS "${CMAKE_SOURCE_DIR}/docs/pics"
0105         LINK_QCHS
0106             Qt6Core_QCH
0107             Qt6Gui_QCH
0108             Qt6Widgets_QCH
0109         INCLUDE_DIRS
0110             ${CMAKE_CURRENT_BINARY_DIR}
0111         BLANK_MACROS
0112             KGAPITASKS_EXPORT
0113         TAGFILE_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0114         QCH_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
0115         COMPONENT Devel
0116     )
0117 endif()
0118